Solid-model loads are transferred automatically to the finite element model at the beginning of the solution. If you mix solid model loads with finite-element model loads, couplings, or constraint equations, be aware of the following possible conflicts:

Any modification of the finite element mesh invalidates the loads, requiring you to delete the previous loads and re-apply them on the new mesh.

Applying loads by graphical picking is inconvenient, unless only a few nodes or elements are involved.

For structural static and transient analyses, velocities and accelerations can be applied as finite element loads on nodes (D). Velocities can be applied in static or transient analyses; accelerations can only be applied in transient analyses. The labels for these loads are:

Although these are not strictly degree-of-freedom constraints, they are boundary conditions that act upon the translation and rotation degrees of freedom. See the D command for more information.

By default, if you repeat a DOF constraint on the same degree of freedom, the new specification replaces the previous one. You can change this default to add (for accumulation) or ignore with the DCUM command. For example:

NSEL,...          ! Selects a set of nodes
D,ALL,UX,40       ! Sets UX = 40 at all selected nodes
D,ALL,UX,50       ! Changes UX value to 50 (replacement)
DCUM,ADD          ! Subsequent D's to be added
D,ALL,UX,25       ! UX = 50+25 = 75 at all selected nodes
DCUM,IGNORE       ! Subsequent D's to be ignored
D,ALL,UX,1325     ! These UX values are ignored!
DCUM              ! Resets DCUM to default (replacement)

Any DOF constraints set via DCUM remain until another DCUM command is issued. To reset the default setting (replacement), issue the command with no arguments.

You can scale existing DOF constraint values via the DSCALE command.

Both the DSCALE and DCUM commands work on all selected nodes and also on all selected DOF labels. By default, DOF labels that are active are those associated with the element types in the model.

For example, if you want to scale only UX values and not any other DOF label, you can use the following commands:

DOFSEL,S,UX       ! Selects UX label
DSCALE,0.5        ! Scales UX at all selected nodes by 0.5
DOFSEL,ALL        ! Reactivates all DOF labels

DSCALE and DCUM also affect velocity and acceleration loads applied in a structural analysis.

When scaling temperature constraints (TEMP) in a thermal analysis, you can use the TBASE field on the DSCALE command to scale the temperature offset from a base temperature (that is, to scale |TEMP-TBASE|) rather than the actual temperature values.

Figure 3.7: Scaling Temperature Constraints with DSCALE

Be aware of the possibility of conflicting DK, DL, and DA constraint specifications and how the program handles them. The following conflicts can arise:

The program transfers constraints that have been applied to the solid model to the corresponding finite element model in the following sequence:

Accordingly, for conflicting constraints, DK commands overwrite DL commands and DL commands overwrite DA commands. For conflicting constraints, constraints specified for a higher line number or area number overwrite the constraints specified for a lower line number or area number, respectively. The constraint specification issue order does not matter.

Changing the value of DK, DL, or DA constraints between solutions may produce many of these warnings at the second or later solid BC transfer. These can be prevented by deleting the nodal D constraints between solutions using DADELE, DLDELE, and/or DDELE.

By default, if you repeat a force at the same degree of freedom, the new specification replaces the previous one. You can change this default to add (for accumulation) or ignore via the FCUM command.

F,447,FY,3000    ! Applies FY = 3000 at node 447
F,447,FY,2500    ! Changes FY value to 2500 (replacement)
FCUM,ADD         ! Subsequent F's to be added
F,447,FY,-1000   ! FY = 2500-1000 = 1500 at node 447
FCUM,IGNORE      ! Subsequent F's to be ignored
F,25,FZ,350      ! This force is ignored!
FCUM             ! Resets FCUM to default (replacement)

Any force set via FCUM stays set until another FCUM command is issued. To reset the default setting (replacement), issue the command with no arguments.

Issue the FSCALE command to scale existing force values.

FSCALE and FCUM work on all selected nodes and also on all selected force labels. By default, force labels that are active are those associated with the element types in the model. You can select a subset of force labels via the DOFSEL command.

DOFSEL,S,FX       ! Selects FX label
FSCALE,0.5        ! Scales FX at all selected nodes by 0.5
DOFSEL,ALL        ! Reactivates all DOF labels

To transfer forces that have been applied to the solid model to the corresponding finite element model, issue the FTRANcommand.

To transfer all solid model boundary conditions, issue the SBCTRAN command.

To apply pressure loads on the lateral faces and the two ends of beam elements, issue the SFBEAM command.

You can apply lateral pressures, which have units of force per unit length, both in the normal and tangential directions. The pressures may vary linearly along the element length, and can be specified on a portion of the element, as shown in this figure:

Figure 3.8: Example of Beam Surface Loads

You can also reduce the pressure down to a force (point load) at any location on a beam element by setting the JOFFST value to -1. End pressures have units of force.

The SFFUN command specifies a function of node number vs. surface load to be used when applying surface loads on nodes or elements.

Issue the command when you want to apply nodal surface loads calculated elsewhere (by another software package, for instance). First define the function in the form of an array parameter containing the load values. The location of the value in the array parameter implies the node number.

*DIM,ABC,ARRAY,4              ! Declares dimensions of array parameter ABC
ABC(1)=400,587.2,965.6,740    ! Defines values for ABC
SFFUN,HFLUX,ABC(1)            ! ABC to be used as heat flux function
SF,ALL,HFLUX,100              ! Heat flux of 100 on all selected nodes,
                              !  100 + ABC(i) at node i.

The SF command in the example above specifies a heat flux of 100 on all selected nodes. If nodes 1 through 4 are part of the selected set, those nodes are assigned heat fluxes of 100 + ABC(i): 100 + 400 = 500 at node 1, 100 + 587.2 = 687.2 at node 2, and so on.

What you specify with the SFFUN command stays active for all subsequent SF and SFE commands. To remove the specification, issue the command with no arguments.

Issue the SFGRAD command to specify that a gradient (slope) is to be used for subsequently applied surface loads. You can also use the command to apply a linearly varying surface load, such as hydrostatic pressure on a structure immersed in water.

To create the gradient specification, specify the following:

SFGRAD,PRES,0,Y,0,-25   ! Y slope of -25 in global Cartesian
NSEL,...                ! Select nodes for pressure application
SF,ALL,PRES,500         ! Pressure at all selected nodes:
                        !  500 at Y=0, 250 at Y=10, 0 at Y=20

Figure 3.9: Surface Load Gradient

The SFGRAD specification stays active for all subsequent load application commands. To remove the specification, issue SFGRAD without any arguments. Also, if an SFGRAD specification is active when a load step file is read, the program erases the specification before reading the file.

Large-deflection effects can change the node locations significantly. The SFGRAD slope and load value calculations, which are based on node locations, are not updated to account for these changes. If you need this capability, use SURF153 with face 3 loading or SURF154 with face 4 loading.

 

3.5.7.3.1. Specifying the Gradient in a Cylindrical Coordinate System

When specifying the gradient in a cylindrical coordinate system (SLKCN = 1, for example), SLZER is in degrees, and SLOPE is in units of load/degree. Set CSCIR (for controlling the coordinate system singularity location) such that the surface to be loaded does not cross the coordinate system singularity. Choose SLZER to be consistent with the CSCIR setting (that is, SLZER should be between +180° if the singularity is at 180° (CSCIR,KCN,0), and SLZER should be between 0° and 360° if the singularity is at 0° (CSCIR,KCN,1).

Consider a semicircle shell as shown in this figure, located in a local cylindrical system 11:

Figure 3.10: Tapered Load on a Cylindrical Shell

The shell is to be loaded with an external tapered pressure, tapering from 400 at -90° to 580 at +90°. By default, the singularity in the cylindrical system is located at 180°, therefore the θ coordinates of the shell range from -90° to +90°. The following commands apply the desired pressure load:

SFGRAD,PRES,11,Y,-90,1  ! Slope the pressure in the theta direction
                        !   of C.S. 11.  Specified pressure in effect
                        !   at -90°, tapering at 1 unit per degree
SF,ALL,PRES,400         ! Pressure at all selected nodes:
                        !  400 at -90°, 490 at 0°, 580 at +90°.

At -90°, the pressure value is 400 (as specified), increasing as θ increases by a slope of 1 unit per degree, to 490 at 0° and 580 at +90°.

You might think to specify 270° rather than -90° for SLZER, as follows:

SFGRAD,PRES,11,Y,270,1 ! Slope the pressure in the theta direction
                       !   of C.S. 11.  Specified pressure in effect
                       !   at 270°, tapering at 1 unit per degree
SF,ALL,PRES,400        ! Pressure at all selected nodes:
                       !  400 at -90°, 490 at 0°, 580 at +90°

As shown on the left in this figure, however, specifying 270° results in a tapered load much different than the one intended:

Figure 3.11: Violation of Guideline 2 (Left) and Guideline 1 (Right)

This behavior occurs because the singularity is still located at 180° (the θ coordinates still range from -90° to +90°), but SLZER is not between -180° and +180°. As a result, the program uses a load value of 400 at 270°, and a slope of 1 unit per degree to calculate the applied load values of 220 at +90°, 130 at 0°, and 40 at -90°. Avoid this behavior by following the second guideline, that is, specifying SLZER to be a value between ±180° when the singularity is at 180°, and between 0° and 360° when the singularity is at 0°.

Suppose that you change the singularity location to 0°, thereby satisfying the second guideline (270° is then between 0° and 360°). But then the θ coordinates of the nodes range from 0° to +90° for the upper half of the shell, and 270° to 360° for the lower half. The surface to be loaded crosses the singularity:

CSCIR,11,1              ! Change singularity to 0°
SFGRAD,PRES,11,Y,270,1  ! Slope the pressure in the theta direction
                        !   of C.S. 11.  Specified pressure in effect
                        !   at 270°, tapering at 1 unit per degree
SF,ALL,PRES,400         ! Pressure at all selected nodes:
                        !  400 at 270°, 490 at 360°, 220 at +90°
                        !  and 130 at 0°

Again, the program uses a load value of 400 at 270° and a slope of 1 unit per degree to calculate the applied load values of 400 at 270°, 490 at 360°, 220 at 90°, and 130 at 0°. Due to node discretization, the actual load applied does not change as abruptly at the singularity as it is shown in the figure. Instead, the node at 0° has the load value of, in the case shown, 130, while the next node clockwise (say, at 358°) has a value of 488.

By default, if you repeat a surface load at the same surface, the new specification replaces the previous one. You can change the default to add (for accumulation) or ignore via the SFCUM command.

Any surface load you set stays set until you issue another SFCUM command. To reset the default setting (replacement), issue SFCUM without any arguments. The SFSCALE command enables you to scale existing surface load values. Both SFCUM and SFSCALE act only on the selected set of elements. The Lab field enables you to choose the surface load label.

To transfer surface loads that have been applied to the solid model to the corresponding finite element model, issue the SFTRAN command.

To transfer all solid model boundary conditions, use the SBCTRAN command. (See Degree-of-Freedom Constraints for a description of DOF constraints.)

Occasionally, you may need to apply a surface load that the element type you are using does not accept. For example, you may need to apply uniform tangential (or any non-normal or directed) pressures on structural solid elements, radiation specifications on thermal solid elements, etc. In such cases, you can overlay the surface where you want to apply the load with surface effect elements and use them as a "conduit" to apply the desired loads. Currently, the following surface effect elements are available: SURF151 and SURF153 for 2D models and SURF152, SURF154, SURF156, and SURF159 for 3D models.

The BFE command specifies body loads on an element-by-element basis. However, you can specify body loads at several locations on an element, requiring multiple load values for one element. The locations used vary from element type to element type. The defaults (for locations where no body loads are specified) also vary between element types; therefore, refer to the documentation for a given element before specifying body loads on elements.

The BFK command applies body loads at keypoints. When specifying loads at the corner keypoints of an area or a volume, all load values must be equal for the loads to be transferred to the interior nodes of the area or volume. Unequal load values are transferred (with linear interpolation) only to the nodes along the lines that connect the keypoints. Figure 3.15: Transfers to BFK Loads to Nodes illustrates this:

The BFK command can also specify table names at keypoints. When specifying table names at corner keypoints of an area or a volume, all table names must be equal for the loads to be transferred to the interior nodes of the area or volume.

Figure 3.15: Transfers to BFK Loads to Nodes

The BFL, BFA, and BFV commands specify body loads on lines, areas, and volumes of a solid model, respectively. Body loads on lines of a solid model are transferred to the corresponding nodes of the finite element model. Body loads on areas or volumes of a solid model are transferred to the corresponding elements of the finite element model.

The BFUNIF command specifies a uniform body load at all nodes in the model. Most often, you use this command or path to specify a uniform temperature field; that is, a uniform temperature body load in a structural analysis or a uniform starting temperature in a transient or nonlinear thermal analysis. This is also the default temperature at which the program evaluates temperature-dependent material properties.

By default, if you repeat a body load at the same node or same element, the new specification replaces the previous one. You can change this default to ignore via the BFCUM and BFECUM commands.

The settings you specify with either command or its equivalent GUI paths stay set until they are reuse the command or path. To reset the default setting (replacement), issue the commands or choose the paths without any arguments.

To transfer body loads that have been applied to the solid model to the corresponding finite element model, issue the BFTRAN command.

To transfer all solid model boundary conditions, issue the SBCTRAN command. (For more information, see Degree-of-Freedom Constraints.)

You can scale existing body load values via the BFSCALE and BFESCAL commands

BFCUM and BFSCALE act on the selected set of nodes. BFECUM and BFESCAL act on the selected set of elements.

Be aware of the possibility of conflicting BFK, BFL, BFA, and BFV body load specifications and how the program handles them.

BFV, BFA, and BFL specifications transfer to associated volume, area, and line elements, respectively, where they exist. Where elements do not exist, they transfer to the nodes on the volumes, areas, and lines, including nodes on the region boundaries. The possibility of conflicting specifications depends upon how BFV, BFA, BFL and BFK are used as described by the following cases.

Elements not getting a direct BFE transfer from a BFV, BFA, or BFL have their body loads determined by the following (in order of priority, with 1 being the highest):

In "Case C" situations, the following conflicts can arise:

The program transfers body loads that have been applied to the solid model to the corresponding finite element model in the following sequence:

Accordingly, for conflicting solid model body loads in "Case C" situations, BFK commands overwrite BFL commands, BFL commands overwrite BFA commands, and BFA commands overwrite BFV commands. For conflicting body loads, a body load specified for a higher line number, area number, or volume number overwrites the body load specified for a lower line number, area number, or volume number, respectively. The body load specification issue order does not matter.

Any conflict detected during solid model body load transfer generates a warning.

Changing the value of BFK, BFL, BFA, or BFV constraints between solutions may produce many of these warnings at the second or later solid BC transfer. These can be prevented by deleting the nodal BF loads between solutions using BFVDELE, BFADELE, BFLDELE, and/or BFDELE.

To implement inertia relief calculations in a static linear or nonlinear analysis, issue the IRLF,1 command before the SOLVE command as part of the inertia load commands. A typical command sequence is shown in the following example.

/solu
antyp,static
!…apply loads and boundary conditions
irlf,1      ! include inertia relief calculation
nlgeom,on   ! include large-deflection effects for geometrically nonlinear analysis
nsub,x,y,z  ! specify the size of the first time step, x, and max and min number of substeps, y and z
solve

Inertia Relief for Substructures

For substructures, inertia relief calculations (MATRIX50) use the equations described in Inertia Relief in the Theory Reference. Mechanical APDL obtains the mass matrix of a substructure via matrix reduction to condense it to the master nodes (MASTER). The inertia relief calculations in a substructure are therefore consistent with the reduced mass contribution at the master nodes.

The IRLF command has no effect in the generation pass of a substructure. If you intend to perform inertia relief calculations on a substructure, do not apply degree-of-freedom constraints (D) on the substructure during its generation pass; instead, apply them during the use pass. (Otherwise, the substructure reduction logic condenses out the mass associated with the constrained degrees of freedom in the generation pass, and the inertia relief calculations in the use pass of the substructure reflect the condensed mass distribution.)

In the expansion pass, precalculation of masses for summary printout (IRLF,-1) occurs only on elements that are part of the substructure.

To activate automatic inertia relief calculations in a linear static analysis, issue AIRL,NRB,RIGID_CALC before the SOLVE command as part of the inertia load commands.

With no arguments specified, AIRL is equivalent to AIRL,AUTO,0, meaning the program automatically determines the number of rigid body modes using an eigensolver. No supports should be specified when NRB = AUTO. This is the case demonstrated in the sample command input below.

If the model is partially constrained, use AIRL,NRB,0 where NRB is the number of rigid body modes embedded in the model (you must know this number in advance), and RIGID_CALC is set to 0 so that an eigensolver is used to determine the rigid body modes.

/solu
antype,static  
!…apply loads
airl       ! include automatic inertia relief calculation (no supports are specified)
solve

For a static analysis base analysis (linear or nonlinear), you can include inertia relief by issuing IRLF,1 in the base analysis. In the perturbed static analysis, the inertia relief load is recalculated to include the prestressed matrix by default. To exclude this inertia relief load vector and its effects you must issue IRLF,0 in the first phase of the linear perturbation static analysis. If large deformation (NLGEOM,ON) is used in the base analysis, the inertia relief loads will be recalculated from the updated geometry in the perturbation phase. Otherwise, the analysis process is as described in the General Procedure for Linear Perturbation Analysis in the Structural Analysis Guide.

/solu
antyp,static    ! base analysis type must be static
!…apply loads and boundary conditions
irlf,1          ! include inertia relief calculation
solve           ! base analysis
finish
/solu
antype,,restart,,,perturb  ! perform a linear perturbation analysis at restart
perturb,static  ! set perturbed analysis type to static            
irlf,0          ! optional if you want to exclude inertia relief in the perturbed static analysis
solve,elform    ! phase 1 of perturbed analysis
!…apply new loads 
solve           ! phase 2 of perturbed analysis

You can include inertia relief in an eigenvalue buckling analysis following the procedure described in the Flowchart of Linear Perturbation Eigenvalue Buckling Analysis, paying special attention to the inclusion and exclusion of the inertia relief load. For inertia relief, the base analysis type must be static (nonlinear or linear).

By default, inertia relief loads are included in the load vector, which is used to calculate the linearly perturbed stress stiffening matrix, in the perturbed buckling analysis. When the base analysis is nonlinear, you may exclude this inertia relief load vector and its effects by issuing IRLF,0 in the first phase of the perturbed buckling analysis so that the inertia relief loads are included only in the base analysis. When the base analysis is linear, the inertia load should be included in the perturbation phase.

/solu
antyp,static   ! base analysis type must be static
!…apply loads and boundary conditions
irlf,1         ! include inertia relief calculation
solve          ! base analysis
finish
/solu
antype,,restart,,,perturb  ! perform a linear perturbation analysis at restart
perturb,buck    ! set perturbed analysis type to buckling            
irlf,0          ! optional if base analysis is nonlinear
solve,elform    ! phase 1 of perturbed analysis
bucopt,subsp,2
solve           ! phase 2 of perturbed analysis

Use the IRLIST command or the PrintFreq argument on the IRLF command to print the output from inertia relief calculations. This output consists of the translational and rotational accelerations required to balance the applied loads and can be used by other programs to perform kinematics studies. If it is a linear static analysis, the reaction forces at the constraints will be zero because the calculated inertia forces balance the applied forces. If it is a nonlinear analysis, the reaction forces at the constraints may not be zero.

Inertia relief output is stored in the database rather than in the results file (Jobname.rst). When you issue IRLIST, Mechanical APDL retrieves the information from the database, which contains the inertia relief output from the most recent solution (SOLVE).

Specify a sufficient number of constraints to prevent unwanted rigid-body motions, discontinuities, or singularities. For example, for an axisymmetric model of a solid structure such as a solid bar, a lack of UX constraint along the axis of symmetry can potentially allow spurious "voids" to form in a structural analysis.

Figure 3.18: Central Constraint for Solid Axisymmetric Structure

When defining a table array parameter for loading, you can use various primary variables depending on the engineering discipline of your analysis. For a coupled-field analysis, there might be loads from more than one discipline (for example, structural and thermal).

Additional primary variables are available using function boundary conditions. See Using the Function Editor for more information. Primary variables are shown as the valid labels used by the *DIM command. You can apply tabular loads according to a local coordinate system defined via LOCAL, and specified in *DIM.

When defining the tables, the primary variables must be in ascending order in the table indices (as in any table array).

See the *DIM command for more information about defining your labels.

The VELOCITY label refers to the magnitude of the velocity degrees of freedom or the computed fluid velocity in FLUID116 elements.

In addition, some real constants for elements SURF151, SURF152, and FLUID116 can have associated primary variables.

Contact elements (CONTA172, CONTA174, CONTA175, CONTA177, and CONTA178) also support table parameter input for some real constants. For a complete list of these real constants and their associated primary variables, see Real Constants and Corresponding Primary Variables for CONTA172, CONTA174, CONTA175, CONTA177 in the Contact Technology Guide and Real Constants and Corresponding Primary Variables for CONTA178 in the Element Reference.

The following two primary variables are used exclusively with contact element real constants:

If you need to specify a variable other than one of the primary variables listed, you can do so by defining an independent parameter. To specify an independent parameter, you define an additional table for the independent parameter. That table must have the same name as the independent parameter, and can be a function of either a primary variable or another independent parameter. You can define as many independent parameters as necessary, but all independent parameters must relate to a primary variable.

*DIM,SYCNV,TABLE,3,3,,RPM,TEMP
SYCNV(1,0)=0.0,20.0,40.0
SYCNV(0,1)=0.0,10.0,20.0,40.0
SYCNV(0,2)=0.5,15.0,30.0,60.0
SYCNV(0,3)=1.0,20.0,40.0,80.0
*DIM,RPM,TABLE,4,1,1,TIME
RPM(1,0)=0.0,10.0,40.0,60.0
RPM(1,1)=0.0,5.0,20.0,30.0
SF,ALL,CONV,%SYCNV%

When defining the tables, the independent variables must be in ascending order in the table indices (as in any table array).

For convenience, you can multiply table parameters by constants, add one table to another, and add a constant increment for offset. To do so, issue the *TOPER command. The two tables must have the same dimensions and must have the same variable names for the rows and columns. The tables must also have identical index values for rows, columns, etc.

If you use table array parameters to define boundary conditions, you may want to verify that the correct table and the correct values from the table were applied. You can do so in several ways:

An example of how to run a steady-state thermal analysis using tabular boundary conditions is described in Performing a Thermal Analysis Using Tabular Boundary Conditions in the Thermal Analysis Guide.

This example shows how to run an analysis using a 5-D table. Note that 4- and 5-D tables cannot be defined interactively; you must use the command method.

This problem consists of a thermal-stress analysis with a pressure that varies as a function of (x,y,z,time,temp). The table and table values are first defined. The table is applied as a pressure boundary condition to the faces of a rectangular beam. Time and temperature are prescribed for two load steps and solved.

/batch,list
/title, Illustrate use of 5D table for SF command (pressure) loading
!!!!
!!!!
                                 !!!! create 5D table for applied pressure
X1=2                             !!!! X dimensionality
Y1=2                             !!!! Y dimensionality
Z1=10                            !!!! Z dimensionality
D4=5                             !!!! time dimensionality
D5=5                             !!!! temperature dimensionality
len=10                           !!!! cantilever beam length
wid=1                            !!!! cantilever beam width
hth=2                            !!!! cantilever beam height


*dim,xval,array,X1               !!!! create 1D arrays to load 5D table
xval(1)=0,20                     !!!! variations per dimension same
*dim,yval,array,Y1               !!!! but give different values on each
yval(1)=0,20                     !!!! book and shelf
*dim,zval,array,10
zval(1)=10,20,30,40,50,60,70,80,90,100
*dim,tval,array,5
tval(1)=1,.90,.80,.70,.60
*dim,tevl,array,5
tevl(1)=1,1.20,1.30,1.60,1.80

*dim,ccc,tab5,X1,Y1,Z1,D4,D5,X,Y,Z,TIME,TEMP
*taxis,ccc(1,1,1,1,1),1,0,wid			!!! X-Dim
*taxis,ccc(1,1,1,1,1),2,0,hth			!!! Y-Dim
*taxis,ccc(1,1,1,1,1),3,1,2,3,4,5,6,7,8,9,10	!!! Z-Dim
*taxis,ccc(1,1,1,1,1),4,0,10,20,30,40		!!! Time
*taxis,ccc(1,1,1,1,1),5,0,50,100,150,200	!!! Temp
*do,ii,1,2
   *do,jj,1,2
      *do,kk,1,10
         *do,ll,1,5
            *do,mm,1,5
               ccc(ii,jj,kk,ll,mm)=(xval(ii)+yval(jj)+zval(kk))*tval(ll)*tevl(mm)
            *enddo
         *enddo
      *enddo
   *enddo
*enddo

/prep7
block,,wid,,hth,,len            !!!! create beam volume
et,1,5                          !!!! use SOLID5

esize,0.5                       !!!! element size
mshkey,1                        !!!! mapped mesh
vmesh,all

mp,ex,1,1e7                     !!!! material properties
mp,nuxy,1,.3
mp,kxx,1,1

nsel,s,loc,z,0                  !!!! fix end of beam
d,all,all
fini
save                            !!!! save problem for future restart
/solu
antyp,trans
timint,off

asel,u,loc,z,0
sfa,all,1,pres,%ccc%            !!!! apply pressure to all selected areas
alls
time,1e-3                       !!!! first solution at time = "0" 
nsub,1
outres,all,all                  !!!! output everything to results file
d,all,temp,0                    !!!! for first problem, temp = 0
solve

time,30				!!!! second solution, time=30
d,all,temp,150			!!!! second solution, temp=150
solve
finish
/post1
/view,1,1,1,1
/psf,press,norm,3,0,1
/pbc,all,0
set,1,1
/title, Pressure distribution; time=0, temp=0
eplot
set,2,1
/title, Pressure distribution; time=30, temp=150
eplot
finish

The following plots illustrate the pressure distribution for the two load cases.

Figure 3.19: Pressure Distribution for Load Case 1

Figure 3.20: Pressure Distribution for Load Case 2

Notice the difference in the pressure load in the second load case.

Apply loads to portions of the model using a component as follows:

CM,cmp,Entity
SF,cmp,CONV,10

The SF command specifies the film coefficient of 10 on nodes in the component (cmp). All nodes in the component are retrieved regardless of the entity type.

An equivalent method for applying the coefficient uses the CMSEL, ALLSEL, and SF commands, as follows:

CMSEL,S,cmp 
ALLSEL,BELOW,ALL
SF,ALL,CONV, 10

Because an assembly is a group of components, the same principle for loading applies to the assembly, as follows:

SF,assm,CONV,10

In this case, the coefficient is applied to all nodes in each component within the assembly.