This example uses two simplified gear teeth stages to create a multistage system and perform a linear perturbation harmonic response analysis. It demonstrates the following key points:
Performing a linear perturbation (LP) harmonic response analysis.
Applying loads to 2 stages.
Applying an engine order load manually by defining the appropriate load to both the base and duplicate sectors.
Applying an engine order load using a table having MSHI as a variable to automatically copy loads to the duplicate sectors (see Harmonic Index-based Tabular Loads).
Postprocessing sector 1 results in /POST26.
The example problem is presented in the following sections:
The multistage system consists of two axially aligned cyclic stages, each with a different number of teeth about the circumference. The two sector stages are shown in Figure 7.30: Multistage Model with Two Gear Teeth Stages. Stage 1 has 24 sectors (blue in the figure) and Stage 2 has 45 sectors (purple in the figure). For the base step of the LP multistage analysis, both HI = 0 stages undergo a rotational velocity and a temperature load. Both stages are then subjected to two different engine order 2 loadings, which are modeled using a single harmonic index (HI = 2).
| Step | Description | Mechanical APDL commands |
| 1. | Read in stage meshes for base and duplicate sectors. | CDREAD,… |
| 2. | Duplicate meshes. | DUPLSTG.mac (macro provided) |
| 3. | Create stage components. | CM,... |
| 4. | Create HI = 0 stages and apply cyclic constraints. |
MSOPT,NEW,,,0 |
| 5. | Apply interstage constraints for all stage connections. | CEIMS,… |
| 6. | Enter the solution processor. | /SOLU |
| 7. | Specify static analysis options. |
ANTYPE,STATIC |
| 8. | Apply rotational load. | OMEGA,… |
| 9. | Specify temperature load. | TREF,… BF,,TEMP |
| 10. | Apply boundary conditions | D,… |
| 11. | Solve the analysis. | SOLVE |
| 11. | Exit and reenter the solution processor. |
FINISH |
| 12. | Perform static LP restart and reform matrices for harmonic response |
ANTYPE,STATIC,RESTART,,,PERTURB PERTURB,MODAL SOLVE,ELFORM |
| 13. | Specify harmonic response options. |
HROPT,FULL HARFRQ,… NSUBST,… |
| 14. | Modify used stages and delete unused stage clones. |
MSOPT,MODIFY |
| 15. | Apply interstage constraints for desired stages and stage clones. | CEIMS |
| 16. | Apply loads. | SF,… |
| 17. | Solve the analysis. | SOLVE |
| 18. | Post process the multistage results for all harmonics. |
MSOPT,EXPA,ALL,… SET,… |
| 19. | Generate contour plot. | PLNSOL,… |
| 20. | Postprocess frequency results | /POST26 NSOL,… PRCPLX,… PLVAR,… |
Download the zipped .cdb file and macro used for this example problem.
/batch
/com, ============================================
/com, ============================================
/com, FULL Harmonic Solve: MS Model
/com, ============================================
/com, ============================================
/filname,msHarmResp
/com, ============================================
/com, MS Model Preparation
/com, ============================================
cdread,db,msHarmStage,cdb
/prep7
csys,1
! duplicate mesh using macro (provided in example package)
DUPLSTG,'stage1'
DUPLSTG,'stage2'
! create cyclic edge CEs
cmsel,s,_stage1_base_nod
nsel,r,loc,y,0
cm,_stage1_cyclow_nod,node
allsel
cmsel,s,_stage1_base_nod
nsel,r,loc,y,alpSec1
cm,_stage1_cychigh_nod,node
allsel
msopt,new,stage1,Nsec1,0
cecycms
cmsel,s,_stage2_base_nod
nsel,r,loc,y,0
cm,_stage2_cyclow_nod,node
allsel
cmsel,s,_stage2_base_nod
nsel,r,loc,y,alpSec2
cm,_stage2_cychigh_nod,node
allsel
msopt,new,stage2,Nsec2,0
cecycms
! create interstage CEs
cmsel,s,_stage1_base_nod
nsel,r,loc,z,0
cm,intf1_stage1_nod,node
allsel
cmsel,s,_stage2_base_nod
nsel,r,loc,z,0
cm,intf1_stage2_nod,node
allsel
ceims,,,stage1,stage2,,,,,,intf1_stage1_nod,intf1_stage2_nod
! components
cmsel,s,load_stage1
cmsel,r,_stage1_base_nod
nsel,r,loc,x,Ro_blad_stage1
nd0=ndnext(0)
allsel
cmsel,s,load_stage2
cmsel,r,_stage2_base_nod
nsel,r,loc,x,Ro_blad_stage2
nd1=ndnext(0)
allsel
finish
/com, ============================================
/com, Static Base Step
/com, ============================================
/solu
antype,static
nlgeom,on
nsubst,2,2,2
! boundary conditions
cmsel,s,_stage1_base_nod
cmsel,a,_stage1_dupl_nod
nsel,r,loc,x,Ri_stage1
d,all,all
allsel
! loading
omega,,,600
tref,0
cmsel,s,_stage1_base_nod
cmsel,a,_stage1_dupl_nod
bf,all,temp,300
allsel
cmsel,s,_stage2_base_nod
cmsel,a,_stage2_dupl_nod
bf,all,temp,100
allsel
solve
finish
/com, ============================================
/com, LP Harmonic Response
/com, ============================================
/SOLU
antype,static,restart,,,perturb
perturb,harmic,,,dzerokeep
solve,elform
hropt,full
Nfrq=40
Fmin=604
Fmax=605.5
harfrq,Fmin,Fmax
nsubst,Nfrq
! update harmonic index
HI1 = 2
HI2 = 2
msopt,modify,stage1,HI1
cecycms
msopt,modify,stage2,HI2
cecycms
ceims,,,stage1,stage2,,,,,,intf1_stage1_nod,intf1_stage2_nod
! Manually apply load to both base and duplicate sectors of stage 1.
! This will result in an engine order excitation equal to
! HI1 (stage 1 harmonic index)
F1real = 1e6
F1imag = 0.25e6
cmsel,s,load_stage1
cmsel,r,_stage1_base_nod
sf,all,pres,F1real,F1imag
allsel
cmsel,s,load_stage1
cmsel,r,_stage1_dupl_nod
sf,all,pres,F1imag,-F1real
allsel
! Apply MSHI-based tabular load to base sector only of stage 2.
! This will result in an engine order 2 excitation.
EO = 2
*dim,press_tab_re,table,1,,,MSHI
press_tab_re(1,0) = EO
press_tab_re(1,1) = 1e6
*dim,press_tab_im,table,1,,,MSHI
press_tab_im(1,0) = EO
press_tab_im(1,1) = 0
cmsel,s,load_stage2
cmsel,r,_stage2_base_nod
sf,all,pres,%press_tab_re%,%press_tab_im%
allsel
kbc,1
! damping
dmpstr,1e-3
solve
finish
/post1
file,,rstp
msopt,expa,all,all
set,1,20
rsys,1
/graphics,power
/view,,1,1,1
/edge,,1
/show,png,rev
plnsol,u,sum
*get,umax,plnsol,,max
plnsol,s,eqv
*get,seqvmax,plnsol,,max
*stat,umax
*stat,seqvmax
finish
/POST26
file,,rstp
numvar,50
nsol,2,nd0,u,x ! base sector results - stage1
nsol,3,nd0,u,y
nsol,4,nd0,u,z
nsol,12,nd1,u,x ! base sector results - stage2
nsol,13,nd1,u,y
nsol,14,nd1,u,z
prcplx,1
lines,100000
/com
/com ------- TIP OF BLADE - STAGE 1 -------
/com
plvar,2,3,4
/com
/com ------- TIP OF BLADE - STAGE 2 -------
/com
plvar,12,13,14
/show,close
FINISH
/exit,nosave
The following figures compare the results of the multistage LP harmonic analysis with those from the reference full 360° LP harmonic analysis. These figures show that the results of the two models are quite similar and verifies the accuracy of the more efficient multistage cyclic symmetry approach.
Figure 7.33: Stage 1 Displacement Frequency Response – Sector 1 for Multistage (A) and Reference Full 360° (B)
Figure 7.34: Stage 2 Displacement Frequency Response – Sector 1 for Multistage (A) and Reference Full 360° (B)
