The shaft is allowed to rotate by 360 degrees. Revolute joints are defined at the ends of the shaft with MPC184joint elements, as shown in Figure 7.6: Revolute Joints and Surface-to-Surface Contact Pair. The joints in the shaft allow rotational loading on the shaft to be applied uniformly.

The following example input shows how to create the joint elements:

!  Creating joint elements 

ET,3,184                      ! Defines MPC184 element
KEYOPT,3,1,6                  ! Selects revolute joint type
KEYOPT,3,4,1                  ! Selects Z axis as revolute axis
LOCAL,11,x1,y1,z1...          ! Creates local coordinate system at one end of the shaft 
                              ! such that axis of shaft becomes the local z axis
N,99,X1,Y1,Z1                 ! Creates node at the centre of the cross section of the shaft at one end.
ET,4,175                      ! Defines CONTACT175 element
ET,5,170                      ! Defines TARGET170 element
KEYOPT,4,12,5                 ! Bonded Contact
KEYOPT,4,4,2                  ! Rigid CERIG style load
KEYOPT,4,2,2                  ! MPC style contact
KEYOPT,5,2,1                  ! Don't fix the pilot node
KEYOPT,5,4,0                  ! Activates all DOF's due to CERIG style
CMSEL,S,SHAFT_NODES           ! Selects all nodes at one end of the shaft.
TYPE,4,
REAL,4

!  Creating bonded contact pairs for defining joints

NN=0
*GET,NUMN,NODE,,COUNT
*DO,I,1,NUMN
  NN=NDNEXT(NN)
  E,NN                    
*ENDDO
ALLSEL,ALL
TYPE,5
REAL,4
TSHAP,PILOT
EN,999,99                     ! Creates target element with pilot node
TSHAP
CSYS,11
NROT,99
CSYS,0     
ALLSEL,ALL
SECTYPE,3,JOINT,REVO,         ! Creates section type for joint elements
SECJOINT,,11,11               ! Defines local coordinate systems at joint element nodes
REAL,3
TYPE,3
SECNUM,3
EN,888,,99                    ! Defines body to ground joint (revolute joint)

After the joints are defined at both ends of the shaft, loading (360-degree rotation) is applied on the revolute joint at one end of the shaft (via the DJ command), as follows:

ESEL,S,TYPE,,3				! Selects joint elements
DJ,ALL,ROTZ,%LOAD%			! Applies load on joint elements

When the shaft rotates, the cams attached to the shaft also rotate. The cam in contact with the valve ball (via the surface-to-surface contact pair) pushes the valve along its axial direction.

The valve moves along its axial direction only and, due to the spring force, it returns to its original position when the cam does not push it further.

To control the movement of the valve, all valve nodes are constrained so that it moves along its axial direction only. To do so, a local coordinate system is defined at the valve such that the local z axis is along the valve axis.