A sample input for cyclic symmetry CMS analysis is shown below. Only the generation and use passes are shown. The expansion pass is not supported for cyclic CMS.

/batch
/com, ---------------------------------------
/com, Cyclic Superelement Example
/com, ---------------------------------------
!* Create simple cyclic model
/prep7
et,1,185
keyopt,1,2,2
mp,ex,1,1e7
mp,nuxy,1,.3
mp,dens,1,.001
cylind,3,6,0,1,0,15
cylind,3,6,0,1,15,30
esize,,.5
vmesh,all
nummrg,node
csys,1
nsel,s,loc,x,3
d,all,all
nsel,all
nsel,s,loc,y,0
cm,cyclic_m01l,node
nsel,s,loc,y,30
cm,cyclic_m01h,node
allsel,all
cyclic,12,30,1,cyclic,1

!* Set up active/passive DOF
nsel,s,loc,x,6
nsel,u,loc,y,0
nsel,u,loc,y,30
cm,active,node
allsel,all
cmsel,u,active
cm,passive,node
allsel,all
finish

/com, ---------------------------------------
/com, Cyclic Superelement Generation Pass
/com, ---------------------------------------
/filnam,part1
/solu
cmsel,s,active,node
m,all,all
allsel,all
antype,substr
seopt,part1,2
cmsopt,fix,6
solve
finish
/com, ---------------------------------------
/com, Cyclic Superelement Use Pass
/com, ---------------------------------------
/clear,nostart
/filnam,use
!* Loop over all of the harmonic indices modal use pass
*do,i,0,6
   /prep7
   et,1,matrix50
   type,1
   edel,all
   se,part1HI%i%     ! read superelement for each HI
   fini

   /solu
   antype,modal
   modopt,lanb,4
   solve
   finish

!* Show modal frequencies for current harmonic index
   /post1
   set,list
   finish
*enddo

For more information, see the ANTYPE, SEOPT, CMSFILE, CMSOPT, M, ET, SE, and CYCLIC commands.