A sample input for single stage cyclic CMS analysis is shown below. Superelements for all harmonic indices are generated. Each one is then imported in a modal analysis use pass.

/batch
/title, Single Stage Cyclic Superelement
/prep7
et,1,185
keyopt,1,2,2
mp,ex,1,1e7
mp,nuxy,1,.3
mp,dens,1,.001
cylind,3,6,0,1,0,15
cylind,3,6,0,1,15,30
esize,,.5
vmesh,all
nummrg,node
csys,1
nsel,s,loc,x,3
d,all,all
nsel,all
!* Set up active/passive DOF
nsel,s,loc,x,6
nsel,u,loc,y,0
nsel,u,loc,y,30
cm,active,node
allsel,all
cmsel,u,active
cm,passive,node
allsel,all

!* Create stage components
cm,_stage_base_elm,elem
cm,_stage_base_nod,node

!* Duplicate the sector
MSDUPL,'stage'

!* Create stage for HI=0
cmsel,s,_stage_base_nod
nsel,r,loc,y,0
cm,_stage_cyclow_nod,node
allsel
cmsel,s,_stage_base_nod
nsel,r,loc,y,30
cm,_stage_cychigh_nod,node
allsel
msopt,new,stage,12,0
cecycms
msopt,list,all,1
finish

/com, --------------------------------------------------
/com, Single Stage Cyclic Superelement Generation Passes
/com, --------------------------------------------------
*do,i,0,6
   /filnam,stage_HI%i%
   /solu
   cmsel,s,active,node
   m,all,all
   allsel,all
   antype,substr
   seopt,stage_HI%i%,2
   cmsopt,fix,6
   *if,i,eq,0,or,i,eq,6,then
     cmsel,s,_stage_base_nod
     cmsel,s,_stage_base_elm
   *endif
   msopt,modify,stage,i
   cecycms
   solve
   finish
*enddo

/com, -------------------------------------------
/com, Single Stage Cyclic Superelement Use Passes
/com, -------------------------------------------
/clear,nostart
/filnam,use
*do,i,0,6
   /prep7
   et,1,matrix50
   type,1
   *if,i,gt,0,then
      edel,all
      msopt,reset
   *endif   
   se,stage_HI%i%     ! read superelement for each HI
   fini

   /solu
   antype,modal
   modopt,lanb,4
   solve
   finish

!* Show modal frequencies for current harmonic index
   /post1
   /gopr
   msopt,list,all
   /nopr
   set,list
   finish
*enddo