A static radiation analysis is performed to determine the change in temperature and heat flux due to view factor updates with NLGEOM,ON for 2D concentric cylinders. View factor updates at the substep level are enabled using the VFUP command. An analytical solution to this concentric cylinders problem was derived using the method outlined in example II of "Dynamic View Factors of Radiation and Radiative Heat Transfer Surface Exchange" [1]. Results of the coupled-field structural-thermal analysis are compared to the analytical solution.
The following topics are available:
Two concentric cylinders exchange heat between their facing surfaces and the outer cylinder's radiating surface to its surrounding environment. Figure 5.12: Concentric Cylinders shows the model geometry with the following dimensions:
Inner cylinder: radius = 12 mm, thickness = 1 mm
Outer cylinder: radius = 13 mm, thickness = 1mm
The boundary conditions are:
The inner cylinder is fixed for all degrees of freedom (DOFs) and held at a constant temperature of 1000 °C. A displacement load is applied to the outer cylinder in the radial direction.
Enclosure 1 accounts for radiation between the two cylinders. Radiation boundary conditions are applied on the outer surface of the inner cylinder and the inner surface of the outer cylinder within enclosure 1. For enclosure 1, view factor smoothing is used to adjust the view factor matrix values so that the row sum equals 1.0 and the reciprocity relationship is satisfied by setting
OPT= 2 on the VFSM command.Enclosure 2 accounts for radiation between the outer cylinder and its surroundings. The free-space ambient temperature, 500 °C, is specified by issuing the SPCTEMP command. No view factor smoothing is prescribed for the open system (enclosure 2).
The model is meshed using 2D coupled-field elements (PLANE222) with structural and thermal degrees of freedom (KEYOPT(1) = 11). The structural-thermal static analysis includes large-deflection effects (NLGEOM, ON), and is solved for time = 0 to 50 seconds with 10 sub steps.
The following material properties are specified.
| Material Property | Value |
|---|---|
| Young's modulus | 1e6 MPa |
| Emissivity | 1 |
| Thermal Conductivity | 8 N/(s*K) |
| Density | 50 N*s2/(mm)4 |
| Specific Heat | 3 (mm)2/(s2K) |
The outer cylinder is subjected to a prescribed displacement using a table array parameter. The dependence of the
displacement UX on time t is defined by issuing
D,,UX,%tabname%. See the command
listing for details.
Command snippet for the implicit-1 view factor strategy — For prescribed motion, the Newton-Raphson loop converges in the first pass,
and the structural solution does not change in subsequent passes. To update view
factors at the substep level, the VFUP command is issued
twice: first, to turn enable view factor updating and second, to specify how
often updating occurs. Implicit-1 is an accurate and efficient view factor
updating strategy when motion is completely specified. For this example problem,
view factors are updated every substep by setting the substep frequency to 1
(OPT2 = 1) only in the first pass of the multipass
loop (OP3 = -1), as seen in following command
snippet.
NLGEOM,ON ! Include large deflection effects VFUP,DEFINE,ON VFUP,DEFINE,FRQU,1,-1 ! update view factors every substep in the first pass
For a detailed description on implementing different view factor updating strategies (implicit, implicit-1, and explicit) and related considerations, see Controlling the frequency of view factor updates in the notes of the VFUP command description.
The temperature calculated at the second substep is plotted in the following figure.
The calculated temperature, heat flux, and energy balance of the moving outer cylinder are listed for each substep. Results from an analytical solution derived following the method outlined by Lebedev, et al. [1] are also listed. The similarities of these results verify the accuracy of the procedure to enable view factor updating at the substep level (VFUP).
Comparing Results: MAPDL Simulation and Analytical Solution
The following command listing is used as input for the analysis.
2.6.5.3. Command Listing
/title, View Factor Update with NLGEOM,2D Concentric Cylinder
/com,
/com, Reference:
/com, V. A. Lebedev, V. P. Solovjov and B.W. Webb
/com, “Dynamic View Factors of Radiation and
/com, Radiative Heat Transfer Surface Exchange”
/com, Example II : System of coaxial disks of same radius
/prep7
/nopr
thic = 1.0 ! thickness of cylinder, mm
R1 = 12 ! outer radius of cylinder 1, mm
R2 = 13 ! inner radius of cylinder 2, mm
R0 = R1 - thic ! inner radius of cylinder 1, mm
R3 = R2 + thic ! Outer radius of cylinder 2, mm
Tinf = 500 ! Ambient temperature, C
T1 = 1000
offt = 273 ! Constant for C to K temperature conversion
Dispx = 1000 ! Displacement, mm
ttime = 50 ! Time, s
nts = 10 ! number of substep
SB = 5.67e-8 ! Stefan-Boltzmann constant (W / (m^2 x K^4).
ems = 1 ! Emissivity
et,1,222,11 ! PLANE222 with structural-thermal coupling
cyl4,0,0,R0,0,R1,360
cyl4,0,0,R2,0,R3,360
esize,,0.1
amesh,all
mp,ex,1,1e6 ! Young's modulus, N/mm^2
mp,prxy,1,0 ! Poisson's ratio
mp,kxx,1,8 ! conductivity, N/(s*K)
mp,c,1,3 ! specific heat, mm^2/(s^2 K)
mp,dens,1,50 ! Density
asel,s,area,,1
nsla,s,1
d,all,ux,0
d,all,uy,0
allse
local,12,1,0,0,0,
csys,0
*dim,u1,table,2,1,1,time
u1(1,0)=0, ttime
u1(1,1)=0, Dispx
asel,s,area,,2
nsla,s,1
csys,12
nrotat,all
d,all,ux,%u1%
d,all,uy,00.0
csys,0
allse
asel,s,area,,1
nsla,s,1
d,all,temp,T1
allsel
csys,12
nsel,s,loc,x,R1
sf,all,rdsf,ems,1
nsel,all
csys,0
csys,12
nsel,s,loc,x,R2
sf,all,rdsf,ems,1
nsel,all
csys,0
csys,12
nsel,s,loc,x,R3
sf,all,rdsf,ems,2
nsel,all
csys,0
dlist
!CE for body2 in order to maintain isothermal body
asel,s,area,,2
nsla,s,1
nmas = ndnext(0)
nslav = ndnext(nmas)
*dowhile,nslav
ce,next,0,nmas,temp,1.0,nslav,temp,-1.0
nslav = ndnext(nslav)
*enddo
allsel
celist
toffst,offt
fini
/aux12
stef,SB
spctemp,2,Tinf
vfsm,,1,2,1000,1.e-6
rsurf ! Generate SURF251 element
/prep7
keyopt,2,1,1
/solu
allse
outres,all,all
nlgeom,on ! Large deflection
autots,off
vfup,defi,on
vfup,defi,frqu,1,-1 ! Implicit-1 algorithm
radopt,,1.e-12,2,1000,1.e-12,1.0
cnvtol,temp,,1.e-9
cnvtol,heat,,1.e-9
kbc,1
save
!single loadstep
time,ttime
nsub,nts
solve
fini
/post1
!compare to analytical solution
*dim,t2,array,nts,7
*do,i,1,nts,1
/gopr
set,1,i
!Temp solution for body 2
n1 = node(R3,0,0)
T2mapdl = temp(n1)
ratio = R1/(R2+ux(n1))
F21 = ratio
F22 = 1. - ratio
T2anal = F21*(T1+offt)**4 + (Tinf+offt)**4
T2anal = T2anal / (2. - F22)
T2anal = T2anal**0.25
T2anal = T2anal - offt
t2(i,1) = i
t2(i,2) = T2mapdl
t2(i,3) = T2anal
!heat heat flux for body 2
csys,12
nsel,s,loc,x,R1
esln,s
esel,r,ename,,251
presol,nmisc,7
*get,flux,elem,n1,nmisc,7
q1net = (T1+offt)**4 - (T2anal+offt)**4
q1net = SB*q1net
t2(i,4) = flux
t2(i,5) = q1net
!energy balance prrfor,heat
*get,nodes_count,node,0,count
*dim,t3,array,nodes_count,1,
*do,j,1,nodes_count,1
*get,reaction,NODE,j,RF,Heat
t3(j,1) = reaction
*enddo
*stat,t3
*vscfun,prr,sum,t3
esel,s,ename,,251
etable,rada,nmisc,4
etable,radnf,nmisc,7
smult,radnh,rada,radnf,1.0,1.0
ssum
*GET,rad_sum,SSUM,0,ITEM,radnh
allsel
t2(i,6) = prr
t2(i,7) = rad_sum
*enddo
/out
/com, =======================================================================
/com, Temperature Heat Flux Energy balance
/com, =======================================================================
/com,
/com,Substep T2 MAPDL T2Analy. APDLFlux Analy.FLux Rad_Net Rad_SUM
/com,
*vwrite,t2(1,1),t2(1,2),t2(1,3),t2(1,4),t2(1,5),t2(1,6),t2(1,7)
%5.0f %10.2f %10.2f %10.2f %10.2f %14.2f %14.2f
fini