This example uses the FLUID220 element to demonstrate the sound transmission between coupled rooms through a partition wall using a diffusion model.

Two rooms with the dimension 5x5x5 m³ are partitioned by a wall. An absorption coefficient of 0.1 is assigned on the surface of the walls, ceiling, and floor. The transmission loss through the partition wall is assumed to be 30 dB. A sound source is located at the point (2,2,2) m with a sound power level of 100 dB (10^-2 W).

The air has mass density = 1.204 kg/m³ and speed of sound = 344 m/s.

The sound pressure levels (SPLs) are monitored along the path (2.5, 2.5, z) m. The SPL difference between the two rooms is calculated based on the averaged SPLs along the path.

The result from the statistical theory solution is 27.00 (dB). [1]

/batch,list
/title, Sound Transmission Between Coupled Rooms Through a Partition Wall
/prep7
!
! Define the room dimensions
lw=5
vol=lw*lw*lw              ! volume of the room
surf=6*lw*lw              ! total wall area
! material parameters
c0 = 343.99               ! speed of sound
rho = 1.204               ! mass density
pref=2.e-5                ! reference power
TL=30                     ! tramission loss of coupled wall (dB)
alpha=0.1                 ! absorption coefficient of wall
mfp=4*vol/surf            ! mean-free path of empty room
roomD=mfp*c0/3.           ! diffusion coefficient of empty room
!
! Define materials
mp,dens,1,rho
mp,sonc,1,c0
tb,afdm,1,,,room          ! diffusion properties for room acoustics
tbdata,1,roomD
h=mfp/5
wall=h                    ! assign thickness to the wall
n=nint(lw/h)
!
! Generate geometry
*dim,a,array,4
*dim,b,array,4
*dim,c,array,3
a(1)=0.
a(2)=2.
a(3)=2.5
a(4)= lw
b(1)=0.
b(2)=2
b(3)=2.5
b(4)=lw
c(1)=0.
c(2)=2
c(3)=lw
*do,i,1,3
  *do,j,1,3
    *do,k,1,2
      block,a(i),a(i+1),b(j),b(j+1),c(k),c(k+1)
    *enddo
  *enddo
*enddo
vglue,all
!
! Generate the mesh
wall=h                    ! assign thickness to the wall
et,1,220,,4               ! define diffusion model
type,1
mat,1
esize,h
vmesh,all
alls
asel,s,loc,z,lw
esize,,1
type,1
vext,all,,,0,0,wall
asel,s,loc,z,lw+wall
esize,,n
type,1
vext,all,,,0,0,lw
alls
nummrg,all,all
!
! Group wall elements
nsel,s,loc,z,lw,lw+wall
esln,s,1
cm,ewall,elem
alls
!
! Apply absorption on room walls, except the coupled wall
cmsel,u,ewall
nsle,s,all
nsel,s,loc,x,a(1)
nsel,a,loc,x,a(4)
nsel,a,loc,y,b(1)
nsel,a,loc,y,b(4)
nsel,a,loc,z,c(1)
nsel,a,loc,z,lw+wall+lw
sf,all,attn,alpha
alls
!
! Apply absorption and transmission loss on room wall
cmsel,s,ewall
nsle,s,all
nsel,s,loc,z,lw
sf,all,attn,alpha,TL
nsel,s,loc,z,lw+wall
sf,all,attn,alpha,TL     
alls
!
! Apply sound source
nsel,s,loc,x,a(2)
nsel,r,loc,y,b(2)
nsel,r,loc,z,c(2)
bf,all,mass,1.e-2
alls
fini
!
! Solve steady-state case
/solve
anty,static
solve
fini
!
! Postprocessing
/post1
set,last
!
! Average acoustic energy density along path in two rooms
*do,i,1,2
nsel,s,loc,x,2.5
nsel,r,loc,y,2.5
*if,i,eq,1,then
  nsel,r,loc,z,0,lw
*else
  nsel,r,loc,z,lw+wall,2*lw+wall
*endif
*get,nd,node,,count
nn=0
toted=0
*do,k,1,nd
  nn=ndnext(nn)
  toted = toted +enke(nn)
*enddo
avg= toted/nd
!
! Calculate the SPL in two rooms
*if,i,eq,1,then
   SPL1=10*log10((avg*rho*c0*c0)/(pref*pref))
*else
   SPL2=10*log10((avg*rho*c0*c0)/(pref*pref))
*endif
alls
*enddo
SPL_Diff = SPL1 - SPL2
/com,
/com,***** Computed SPL difference between two rooms *****
/com,
*vwrite, SPL_Diff
 (1x,'L1 - L2 = ',g14.7, '(dB)')
fini