/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMP09-T33-182
/TITLE, VMP09-T33-182, FREE ANNULAR MEMBRANE
/COM,REFERENCE NAFEMS FVB MANUAL TEST 33

/PREP7
ETYP=182
RDIV=3
CDIV=16
ET,1,ETYP
MP,EX,1,200E9
MP,NUXY,1,.3
MP,DENS,1,8000
CSYS,1
K,1,1.8
K,2,6
K,3,6,90
K,4,1.8,90
L,1,2,RDIV
L,2,3,(CDIV/4)
L,3,4,RDIV
L,4,1,(CDIV/4)
ESIZ,,,2
A,1,2,3,4
AMESH,1
CSYS,0
ARSYM,1,1
ARSYM,2,1,2
NUMMRG,ALL
FINISH

/SOLU
ANTYPE,MODAL
MODOPT,SUBSPACE,14
MXPAND,14
RIGID,ALL
/OUT,SCRATCH
SOLVE
FINISH

/POST1
*DIM,FREQ,ARRAY,14
*GET,FREQ(1,1),MODE,1,FREQ
*GET,FREQ(2,1),MODE,2,FREQ
*GET,FREQ(3,1),MODE,3,FREQ
*GET,FREQ(4,1),MODE,4,FREQ
*GET,FREQ(5,1),MODE,5,FREQ
*GET,FREQ(6,1),MODE,6,FREQ
*GET,FREQ(7,1),MODE,7,FREQ
*GET,FREQ(8,1),MODE,8,FREQ
*GET,FREQ(9,1),MODE,9,FREQ
*GET,FREQ(10,1),MODE,10,FREQ
*GET,FREQ(11,1),MODE,11,FREQ
*GET,FREQ(12,1),MODE,12,FREQ
*GET,FREQ(13,1),MODE,13,FREQ
*GET,FREQ(14,1),MODE,14,FREQ
R1=1.00
R2=1.00
R3=1.00
R4=FREQ(4,1)/129.240
R5=FREQ(5,1)/129.240
R6=FREQ(6,1)/226.17
R7=FREQ(7,1)/234.74
R8=FREQ(8,1)/234.74
R9=FREQ(9,1)/264.66
R10=FREQ(10,1)/264.66
R11=FREQ(11,1)/336.61
R12=FREQ(12,1)/336.61
R13=FREQ(13,1)/376.79
R14=FREQ(14,1)/376.79

*DIM,VALUE,,7,4
*DIM,RATIO,,7,2
*DIM,LABEL,CHAR,7
*DIM,LABEL2,CHAR,7
LABEL(1)='FREQ 1','FREQ 2','FREQ 3','FREQ 4','FREQ 5','FREQ 6','FREQ 7'
LABEL2(1)='FREQ 8','FREQ 9','FREQ 10','FREQ 11','FREQ 12','FREQ 13','FREQ 14'
*VFILL,VALUE(1,1),DATA,0,0,0,129.240,129.240,226.170,234.740,
*VFILL,VALUE(1,2),DATA,234.740,264.660,264.660,336.610,336.610,376.790,376.790
*VFILL,VALUE(1,3),DATA,FREQ(1,1),FREQ(2,1),FREQ(3,1),FREQ(4,1),FREQ(5,1),FREQ(6,1),FREQ(7,1)
*VFILL,VALUE(1,4),DATA,FREQ(8,1),FREQ(9,1),FREQ(10,1),FREQ(11,1),FREQ(12,1),FREQ(13,1),FREQ(14,1)
*VFILL,RATIO(1,1),DATA,R1,R2,R3,R4,R5,R6,R7
*VFILL,RATIO(1,2),DATA,R8,R9,R10,R11,R12,R13,R14
/OUT,
/COM,
/COM,
/COM,------------- VMP09-T33-182 RESULTS COMPARISON ---------------------
/COM,
/COM,         |   TARGET   |   Mechanical APDL   |   RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,3),RATIO(1,1)
(1X,A8,'   ',F10.3,'  ',F14.3,'   ',1F14.3)
*VWRITE,LABEL2(1),VALUE(1,2),VALUE(1,4),RATIO(1,2)
(1X,A8,'   ',F10.3,'  ',F14.3,'   ',1F14.3)
FINISH

/POST26
*DIM,LABEL1,CHAR,6
*DIM,LABEL4,CHAR,6
*DIM,VALUE1,,6,2
LABEL1(1) = ' MODE',' MODE',' MODE',' MODE',' MODE',' MODE'
LABEL4(1) = '4,5','6','7,8','9,10','11,12','13,14'
*VFILL,VALUE1(1,1),DATA,FREQ(5,1),FREQ(6,1),FREQ(8,1),FREQ(10,1),FREQ(12,1),FREQ(14,1)
*VFILL,VALUE1(1,2),DATA,R5,R6,R8,R10,R12,R14
*DIM,LABEL3,CHAR,6
*DIM,LABEL5,CHAR,6
LABEL3(1) = 'vmp09-t3','vmp09-t3','vmp09-t3','vmp09-t3','vmp09-t3','vmp09-t3'
LABEL5(1) = '3-182','3-182','3-182','3-182','3-182','3-182',

/OUT,vmp09-t33-182,vrt
/COM
/COM,------------------- VMP09-T33 RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, PLANE182
*VWRITE,LABEL1(1),LABEL4(1),VALUE1(1,1),VALUE1(1,2),LABEL3(1),LABEL5(1)
(1X,A5,A5,'     ',F13.3,'     ',F7.3,'       ',A8,A5)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmp09-t33-182,vrt