/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMP09-T15-281
/TITLE,VMP09-T15-281, CLAMPED THIN RHOMBIC PLATE
/COM,REFERENCE NAFEMS FVB MANUAL TEST 15
/PREP7
MP,EX,1,2.000000000E+11,
MP,NUXY,1,0.300000000
MP,DENS,1,8000.00000
LOCAL,11,0,10,0,0,45,0,0,1,1
CSCIR,  11,   0,   0
LOCAL,12,0,0,0,0,45,0,0,1,1
CSCIR,  12,   0,   0
ET,1,281
R,1,0.5E-01
CSYS,12
K,1,0,0,0
K,4,10,0,0
CSYS,11
K,2,0,0,0
K,3,10,0,0
CSYS,0
A,1,2,3,4
LESIZE,ALL,,,12
AMESH,1
D,ALL,UX,0
D,ALL,UY,0
D,ALL,ROTZ,0
NSLL,S,1
D,ALL,ROTX,0
D,ALL,ROTY,0
D,ALL,UZ,0
ALLSEL,ALL
FINISH
/out,scratch
/SOLU
OUTRES,ALL,ALL,
ANTYPE,MODAL
MODOPT,LANB,22
MXPAND,8
SOLVE
FINISH
/out
/POST1
*DIM,FREQ,ARRAY,6
*GET,FREQ(1,1),MODE,1,FREQ
*GET,FREQ(2,1),MODE,2,FREQ
*GET,FREQ(3,1),MODE,3,FREQ
*GET,FREQ(4,1),MODE,4,FREQ
*GET,FREQ(5,1),MODE,5,FREQ
*GET,FREQ(6,1),MODE,6,FREQ
R1=FREQ(1,1)/7.938
R2=FREQ(2,1)/12.835
R3=FREQ(3,1)/17.941
R4=FREQ(4,1)/19.133
R5=FREQ(5,1)/24.009
R6=FREQ(6,1)/27.922
*DIM,VALUE,,6,2
*DIM,LABEL,CHAR,6
*DIM,RATIO,,6,1
LABEL(1) = 'FREQ 1','FREQ 2','FREQ 3','FREQ 4','FREQ 5','FREQ 6'
*VFILL,VALUE(1,1),DATA,7.938,12.835,17.941,19.133,24.009,27.922
*VFILL,VALUE(1,2),DATA,FREQ(1,1),FREQ(2,1),FREQ(3,1),FREQ(4,1),FREQ(5,1),FREQ(6,1)
*VFILL,RATIO(1,1),DATA,R1,R2,R3,R4,R5,R6
/COM,
/COM,------------- VMP09-T15-281 RESULTS COMPARISON -----------------
/COM,
/COM,         |   TARGET   |   Mechanical APDL   |   RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),RATIO(1,1)
(1X,A8,'   ',F10.3,'  ',F14.3,'   ',1F13.3)
FINISH
/POST26
*DIM,LABEL1,CHAR,6
LABEL1(1) = ' MODE1',' MODE2',' MODE3',' MODE4',' MODE5',' MODE6'
*DIM,LABEL2,CHAR,6
*DIM,LABEL3,CHAR,6
LABEL2(1) = 'vmp09-t1','vmp09-t1','vmp09-t1','vmp09-t1','vmp09-t1','vmp09-t1'
LABEL3(1) = '5-281','5-281','5-281','5-281','5-281','5-281'
/OUT,vmp09-t15-281,vrt
/COM
/COM,------------------- VMP09-T15 RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SHELL281
*VWRITE,LABEL1(1),VALUE(1,2),RATIO(1,1),LABEL2(1),LABEL3(1)
(1X,A8,'       ',F13.4,'     ',F9.4,'       ',A8,A5)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmp09-t15-281,vrt