Problem Description

A simplified transient analysis is performed for a rectangular plate fixed at two ends with a hole in the center. A stepped pressure load is applied to the top surface of the plate. SOLID185 elements model the structure. FLUID136 elements model the thin film surface and a FLUID138 element models the hole region. Displacement and pressure time history results are determined at the bottom of the plate on the circumference of the hole.

Command Listing

The input file for this example is shown below.

/PREP7
/title, Simplified Transient Analysis
/com    uMKS units

ET, 1,136,1                   ! 4-node option, High Knudsen Number
keyop,1,3,2                   ! PRES + UZ + UY + UZ DOFs, implicit treatment
et,2,138,1                    ! Hole
ET,3,185,,3                   ! Structural element

s_l=20                        ! Half Plate length (um)
s_w=20                        ! Plate width
s_t=10                        ! Plate thickness
c_r=6                         ! Hole radius
d_el=2                        ! Gap
pamb=.1                       ! Ambient pressure (MPa)
visc=18.3e-12                 ! viscosity kg/(um)(s)
pref=.1                       ! Reference pressure (MPa)
mfp=64e-3                     ! Mean free path (um)
Knud=mfp/d_el                 ! Knudsen number

mp,visc,1,visc                ! Dynamic viscosity gap
mp,visc,2,visc                ! Dynamic viscosity hole
mp,ex,3,79e3                  ! Gold
mp,dens,3,19300e-18
mp,nuxy,3,.1

r,1,d_el,,,pamb               ! Real constants - FLUID136
rmore,pref,mfp

r,2,c_r,,,pamb                ! Real constants - FLUID138
rmore,pref,mfp

block,-s_l,s_l,-s_w,s_w,0,s_t
cyl4,0,0,c_r,,c_r,,s_t
vsbv,1,2
numcmp,all
type,3
mat,3
real,3
mshape,1,3d
esize,,3
vmesh,1                       ! SOLID185 mesh

nsel,s,loc,z,0
esln,s
TYPE, 1
MAT, 1
real,1
esurf                         ! FLUID136 mesh
allsel

!make the nodes/elem for 138
*get,numb,node,,num,max
n,numb+1,0,0,0
n,numb+2,0,0,s_t
type,2
mat,2
real,2
e,numb+1,numb+2               ! FLUID138 mesh

!couple hole pres eq
esel,s,type,,1
nsle,s,1
local,11,1,0,0,0
csys,11
nsel,r,loc,x,c_r
nsel,a,node,,numb+1
cp,1,pres,all
csys,0
allsel

nsel,s,loc,x,-s_l
nsel,a,loc,x,s_l
nsel,a,loc,y,-s_w
nsel,a,loc,y,s_w
nsel,r,loc,z,-1e-9,1e-9
nsel,a,node,,numb+2
d,all,pres                    ! Fix pressure at outer plate boundary
nsel,all
dlist

!esel,s,type,,1
!nsle,s,1
!nsel,u,cp,,1
!cm,FLUN,node
!allsel

nsel,s,loc,x,-s_l             ! Fix two ends of SOLID185 elements
nsel,a,loc,x,s_l
d,all,ux
d,all,uy
d,all,uz
allsel

nsel,s,loc,z,s_t              ! Apply pressure loading on SOLID185 top surface
sf,all,pres,1.e+1
allsel

fini

/solu
antype,trans
kbc,1                         ! Specify a stepped loading
nropt,full
time,180e-6
!time,6e-6
deltim,2e-6                   ! Specify time step size
outres,all,none
outres,nsol,all
outres,esol,all 
cnvtol,pres,,1.e-6            ! Specify convergence values
cnvtol,u   ,,1.e-6
save
solve
fini

/post26
nl=node(c_r,0,0)
nsol,2,nl,uz
nsol,3,nl,pres                ! Print time history results
prvar,2,3
fini
/post1
set,last                      ! Retrieve results at last substep
esel,s,type,,1                ! FLUID136
etable,_gap,nmisc,2
pretab,_gap                   ! Print GAP value
fini