The following example [Ruffini et al.] describes a modal analysis of the cyclically-symmetric bladed disk shown in Figure 5.24: Bladed Disk Geometry and Mesh. It is subjected to various rotational velocities (OMEGA). The prestress due to the centrifugal forces and the Coriolis forces are accounted for through the two-step linear perturbation analysis (PERTURB). Coriolis effects are activated (CORIOLIS). A modal analysis is then performed with the DAMP eigensolver (MODOPT).

Figure 5.24: Bladed Disk Geometry and Mesh

The structure is a disk composed of 8 blades and is clamped along its inner radius. It is cyclically symmetric and can be divided into 8 sectors. Only one sector, shown in Figure 5.25: Sector Mesh, is defined and meshed.

Figure 5.25: Sector Mesh

The Coriolis effects modify the natural frequencies when the rotational velocity increases from 0 to 500 RPM. In particular, the typical cyclic structure mode pairs undergo a frequency split: one frequency increases with rotational velocity (forward mode) while the other decreases (backward mode).

Reference

Ruffini, V., Schwingshackl, C., Green, J. Experimental and Analytical Study of Coriolis Effects in Bladed Disk. ASME. 2015.

The problem specifications are as follows:

Disk Dimensions

Blade Dimensions

Material Properties

The geometry, material, and mesh for the sector illustrated in Figure 5.25: Sector Mesh have been specified and saved in the input file, meshSector45.inp, which can be downloaded here. You can use this input file with the following input listing to model the example problem described.

/out,scratch
/filname,cyclicCoriolis

/prep7

!============================
! Input the mesh and material
!============================
/input,meshSector45,inp

!====================
! Boundary conditions 
!====================
cmsel,s,_FIXEDSU
d,all,all
nsel,all

!================
! Cyclic symmetry 
!================
cyclic

!=====================
! Create spin velocity 
!=====================
pi       = acos(-1)
rpmToRad = pi/30

*DIM,spin,,3
spin(1) = 0
spin(2) = 250*rpmToRad
spin(3) = 500*rpmToRad

*DIM,freqCyc,,8,3

*DIM,stepIndI,,8
stepIndI(1) =  1, 2, 2, 3, 3, 4, 4, 5

*DIM,stepIndJ,,8
stepIndJ(1) =  1, 1, 3, 1, 3, 1, 3, 1

finish

allsel
*DO,I,1,3
!===================================================
! 1. Static analysis (prestress/linear perturbation) 
!===================================================
/solu
antype,static
coriolis,on
omega,0,spin(I),0
rescontrol,linear,all,1
cycopt,msup,no	
solve
finish

!==================
! 2. Modal analysis 
!==================
/solu
antype,static,restart,,,perturb
perturb,modal
solve,elform
	
modopt,damp,16
mxpand,all	
solve
finish

/post1	
file,cyclicCoriolis,rstp
*DO,J,1,8
indI = stepIndI(J)
indJ = stepIndJ(J)
set,indI,indJ,,imag
*get,freqCyc(J,I),active,,set,freq
*ENDDO	
finish
*ENDDO	

/out,
/com =============================
/com = Results for cyclic analysis
/com =============================
/com
/com Campbell diagram: natural frequencies vs. rotational velocities
/com
/com Velocity (RPM): 0         ; 250         ; 500 
/com ND0:            %freqCyc(1,1)% ; %freqCyc(1,2)% ; %freqCyc(1,3)%
/com ND1 backward:   %freqCyc(2,1)% ; %freqCyc(2,2)% ; %freqCyc(2,3)%
/com ND1 forward:    %freqCyc(3,1)% ; %freqCyc(3,2)% ; %freqCyc(3,3)%
/com ND2 backward:   %freqCyc(4,1)% ; %freqCyc(4,2)% ; %freqCyc(4,3)%
/com ND2 forward:    %freqCyc(5,1)% ; %freqCyc(5,2)% ; %freqCyc(5,3)%
/com ND3 backward:   %freqCyc(6,1)% ; %freqCyc(6,2)% ; %freqCyc(6,3)%
/com ND3 forward:    %freqCyc(7,1)% ; %freqCyc(7,2)% ; %freqCyc(7,3)%
/com ND4:            %freqCyc(8,1)% ; %freqCyc(8,2)% ; %freqCyc(8,3)%
/com 
/com =================================================================

/exit,nosave 

The results of your analysis should match those shown below.