This example problem demonstrates the use of FLUID220 to predict the acoustic radiation from a dipole.
The dipole is located inside of the model at point (0,0,0). The dipole length is defined as the half of the mesh, and the dipole axis is along the x-direction.
Because of the symmetry exhibited by the dipole radiation pattern, only 1/8 of the radiation space is modeled.
The Y-Z plane is a sound-soft plane. The other two coordinate planes are sound-hard planes.
PML is used to terminate the open radiation space.
For details about near- and far-field calculation, see the PLFAR, PRFAR, PLNEAR, and PRNEAR commands.
/batch,list
/title,Radiation from a Dipole
/nopr
/prep7
! define material properties
rho=1.2041 ! mass density
soundv=343.26 ! sound speed
freq=1.e3 ! working frequency
wavel=soundv/freq ! wavelength
omega=2.*3.1415926535*freq ! angular frequency
p0=0.5*freq ! amplitude of pressure
! set model dimensions
*dim,a,array,4
a(1)=0
a(2)=a(1)+0.1*wavel
a(3)=a(2)+0.1*wavel
a(4)=a(3)+0.1*wavel
*do,i,1,3
*do,j,1,3
rect,a(i),a(i+1),a(j),a(j+1)
*enddo
*enddo
aglue,all
! define elements and material
et,11,200,7 ! temporary element
et,1,220,0,1 ! normal element
et,2,220,0,1,,1 ! PML element
mp,dens,1,rho
mp,sonc,1,soundv
! create 2d mesh
h=(a(2)-a(1))/6
nz1=(a(3)-a(1))/h
local,11 ! set up local coordinate system
wpcsys,,11
type,11
mshape,0
esize,h
amesh,all ! meshing 2d model
! create 3d mesh
asel,s,loc,x,0,a(3)
asel,r,loc,y,0,a(3)
cm,aa,area
esys,11 ! set up element coordinate system
type,1 ! normal element region
mat,1
esize,,nz1
vext,all,,,0,0,a(3)-a(1)
asel,s,loc,z,0
asel,u,,,aa
type,2 ! meshing PML region
mat,1
esize,,nz1
vext,all,,,0,0,a(3)-a(1)
nz2=(a(4)-a(3))/h
esize,,nz2
asel,s,loc,z,a(3)
vext,all,,,0,0,a(4)-a(3)
allsel,all,all
nummrg,all ! merge nodes
asel,s,loc,z,0 ! delete 2d element
aclear,all
etdel,11
alls
! constrains on PML exterior surface
nsel,s,loc,x,a(4)
nsel,a,loc,y,a(4)
nsel,a,loc,z,a(4)
d,all,pres,0.
! constrains on x=0 symmetric plane
nsel,s,loc,x,a(1)
d,all,pres,0.
alls
! analytic incident dipole inside of model
awave,1,dipo,pres,int,p0,0,0,0,0,rho,soundv,,h/2,1,0,0
finish
! perform a solution
/solu
antype,harmic ! harmonic analysis
harfrq,freq ! frequency for analysis
asol,scat,on ! scattered formulation
ascres,total ! output total pressure field
solve
finish
! post-processing
/post1
/show,png
set,1,1
hfsym,,ssb,shb,shb ! symmetric plane for far field
/com,
/com, ********************************************
/com, * near/far analytic solution |p| *
/com, ********************************************
/com, (x,y,z) |p|
/com, (1,0,0) 26.176
/com, (5,0,0) 5.235
/com, (10,0,0) 2.618
/com, (20,0,0) 1.309
/com,
/com, ********************************************
/com, * near/far Mechanical APDL solution |p| *
/com, ********************************************
/com,
prnear,point,psum,,1,0,0
prnear,point,psum,,5,0,0
prnear,point,psum,,10,0,0
prnear,point,psum,,20,0,0,
prfar,pres,sumc,0,0,1,90,90,1,20
prfar,pres,splc,0,0,1,90,90,1,20,2.e-5
prfar,pres,pwl,0,0,0,0,0,0,0,1.e-12
plfar,pres,sump,0,0,1,0,360,180,10
plfar,pres,splp,0,0,1,0,360,180,10,2.e-5
plfar,pres,dgpl,0,0,1,0,180,90
/view,,1,1,1
!
!*** spl contour plot on plane x=[-10,10], y=[-10,10], z=10 (m)
plfar,pres,splc,-10,10,20,-10,10,20,10,,,,,1,1,,,plyz
!
!*** pressure contour plot on r=10 (m) sphere
/view,,-1,1,1
plfar,pres,splc,0,360,180,0,180,90,10,,,,,1,1,,,sphr
!
/show,close
fini