This example problem demonstrates the use of FLUID220 to predict the acoustic radiation wave pattern from two waveguides that have pistons at one end and an infinite baffle at another end.

A sound-absorption material is located at the surfaces of the enclosure, modeled using PML.

For more information see Perfectly Matched Layers (PML) in the Mechanical APDL Theory Reference.

/batch
/prep7
                      ! structure dimensions
pi=3.1415926535
k=8*pi
c0=340
freq=k*c0/(2*pi)
                      ! define elements and material
et,11,200,7
et,1,220,,1           ! acoustic
et,2,220,,1,,1        ! pml
mp,dens,1,1.
mp,sonc,1,c0
d=0.1
l=1.
s=0.5
a=2
dpml=0.25
h=d/2
rect,-l,0,s/2,s/2+d
rect,-l,0,-s/2,-s/2-d
rect,0,a,-a/2,a/2
rect,0,a+dpml,-a/2-dpml,a/2+dpml
asba,4,3,,delete,keep
aglue,all
esize,h
type,11
amesh,all
mshape,0
mshkey,0
asel,all
asel,u,,,5
esla
type,1
mat,1
esize,,1
vext,all,,,0,0,d,
asel,s,,,5
type,2,
mat,1
esize,,1
vext,all,,,0,0,d,
asel,s,loc,z,0
aclear,all
alls
nummrg,all
                      ! define boundary condition
nsel,s,loc,x,a+dpml
nsel,a,loc,y,-a/2-dpml
nsel,a,loc,y,a/2+dpml
d,all,pres,0.
                      ! hard excitation source
nsel,s,loc,x,-l
d,all,pres,1
alls
fini
                      ! perform solution
/solu
eqslv,sparse
antype,harmic
harfrq,freq
solve
fini
/post26
/out
prcplx,0
nsel,s,loc,x,0
nsel,r,loc,y,s/2+d
*get,A1,node,0,num,max
nsel,s,loc,x,0
nsel,r,loc,y,s/2
*get,A2,node,0,num,max
nsel,s,loc,x,0
nsel,r,loc,y,-s/2-d
*get,B1,node,0,num,max
nsel,s,loc,x,0
nsel,r,loc,y,-s/2
*get,B2,node,0,num,max
nsel,s,loc,x,a
nsel,r,loc,y,a/2
*get,C1,node,0,num,max
nsel,s,loc,x,a
nsel,r,loc,y,-a/2
*get,C2,node,0,num,max
allsel
nsol,2,A1,pres,,Input_A1
nsol,3,A2,pres,,Input_A2

nsol,4,B1,pres,,Input_B1
nsol,5,B2,pres,,Input_B2
nsol,6,C1,pres,,Output_C1
nsol,7,C2,pres,,Output_C2
/com ***************Results****************************
prvar,2,4,
prvar,3,5,
prvar,6,7
/com *******************************************************
fini