This example problem demonstrates the use of FLUID220 to predict the sound pressure level at the closed end of a rigid walled waveguide.

The waveguide is terminated by a rigid wall at one end (z = L_z) and driven by a plane piston at another end (z = 0).

The square cross section of waveguide is L_x = L_y = 15 mm, and the length L_z is 170 mm.

The analytic value of the pressure at z = L_z is given by:

where:

For more information about viscous-thermal parameters, see Viscous-Thermal Materials in the Mechanical APDL Theory Reference

/batch,list
/title,BLI model for waveguide with visco-thermal fluid
/nopr
/prep7
freq1 = 880                ! beginning frequency
freq2 = 1100               ! ending frequency
rho = 1.29                 ! mass density
c0 = 340                   ! sound speed
kx = 0.0241                ! thermal conductivity
visc = 1.71e-5             ! dynamic viscosity
cv = 654.1376              ! Cv heat coefficient 
cp = 915.7926              ! Cp heat coefficient
bvis=0.6*visc              ! bulk viscosity
wavelen=c0/freq2           ! wavelength
v0=2.45e-3                 ! normal velocity
                           ! viscous-thermal material 
tb,afdm,1,,,mat
tbdata,1,rho,c0,visc,kx,cp,cv,
tbdata,7,bvis
                           ! create geometry
d=0.005
l=0.170
block,-d/2,d/2,-d/2,d/2,0,l
                           ! create mesh
h=wavelen/20
et,1,220,,1
esize,h
type,1
mat,1
vmesh,all
                           ! define BLI boundary on rigid walls
nsel,s,loc,z,l
nsel,a,loc,x,-d/2
nsel,a,loc,x,d/2
nsel,a,loc,y,-d/2
nsel,a,loc,y,d/2
sf,all,bli
                           ! define normal velocity on piston
nsel,s,loc,z,0
sf,all,shld,v0
alls
fini
                           ! perform a solution
/solu
eqslv,sparse
antype,harmic
harfrq,freq1,freq2
nsub,11
solve
fini
                           ! post-processing
/post26
nsel,s,loc,x,-d/2
nsel,r,loc,y,-d/2
nsel,r,loc,z,l
nod=0
node=ndnext(nod)
nsol,2,node,spl
fini