The analysis, based on a solenoid actuator, analyzes the actuator as a 2D axisymmetric model. The example calculates the force on the armature (the moving component of the actuator), inductance of the coil, and the coil current in response to a voltage excitation. Figure 4.2: Diagram of a Solenoid Actuator below shows you the solenoid actuator:

Figure 4.2: Diagram of a Solenoid Actuator

The analysis uses the parameters listed below to model the actuator geometry:

The solenoid actuator model for this transient example is identical to the solenoid example described in 2D Static Magnetic Analysis. Instead of a DC current excitation, the coil is supplied a voltage excitation which varies over time.

The coil is supplied a voltage which ramps from 0 volts to 12 volts over a .01 second time frame. After that, the voltage is held constant and the analysis runs until a time of .06 seconds. The coil requires additional characterization, including cross-section area and fill factor. Resistivity for copper is also provided. The armature is assumed to be solid steel, so it requires the input of electrical resistivity as well.

The purpose of the example analysis is to calculate the coil current, armature force, and coil inductance over time in response to the applied voltage excitation.

The solution uses constant time stepping over three load steps ending at .01, .03, and .06 seconds respectively.

You can perform the example analysis of transient eddy currents using the commands shown below. Any text prefaced by an exclamation point (!) is a comment.

/PREP7
/TITLE, 2D Solenoid Actuator Transient Analysis
/NOPR
ET,1,PLANE233,,,1         ! Define element type, set for axisymmetric run
ET,2,PLANE233,2,,1        ! Axisymmetric, coil option
MP,MURX,1,1               ! Define material permeability (air)
MP,MURX,2,1000            ! Permeability (backiron)
MP,MURX,3,1               ! Permeability (coil)
MP,MURX,4,2000            ! Permeability (armature)
MP,RSVX,3,3e-8            ! Define coil resistivity
MP,RSVX,4,70e-8           ! Define armature resistivity

/com                      ! Set parameter values
n=650
ta=.75
tb=.75
tc=.50
td=.75
wc=1
hc=2
gap=.25
space=.25
ws=wc+2*space
hs=hc+.75
w=ta+ws+tc
hb=tb+hs
h=hb+gap+td
acoil=wc*hc                ! Cross-section of coil (cm**2)

Sc=acoil*.01**2            ! coil cross-sectional area
pi=acos(-1)
Ri=(ta+space)*0.01         ! inner radius
Ro=(ta+space+wc)*0.01      ! outer radius
Rm=(Ri+Ro)/2               ! mean radius 
Vc=pi*(Ro**2-Ri**2)*(hc*0.01)    ! coil volume
Rc=3e-8*(n/Sc)**2*(Vc/0.95) ! coil resistance

R,1,,Sc,n,Rm,1,Rc          ! Coil constants (thick, scaled area, turns, mean rad, dir., resistance)

/PNUM,AREA,1
RECTNG,0,w,0,tb            ! Create rectangular areas
RECTNG,0,w,tb,hb
RECTNG,ta,ta+ws,0,h
RECTNG,ta+space,ta+space+wc,tb+space,tb+space+hc
AOVLAP,ALL
RECTNG,0,w,0,hb+gap
RECTNG,0,w,0,h
AOVLAP,ALL
NUMCMP,AREA                ! Compress out unused area numbers
APLOT

ASEL,S,AREA,,2             ! Assign attributes to coil
AATT,3,1,2,0
ASEL,S,AREA,,1             ! Assign attributes to armature
ASEL,A,AREA,,12,13
AATT,4,1,1
ASEL,S,AREA,,3,5           ! Assign attributes to backiron
ASEL,A,AREA,,7,8
AATT,2,1,1,0
/PNUM,MAT,1
ALLSEL,ALL
APLOT

SMRTSIZE,4                 ! Set SmartSize meshing level
AMESH,ALL                  ! Mesh all areas
ESEL,S,MAT,,4              ! Select armature elements
CM,ARM,ELEM                ! Define armature as a component

ESEL,S,MAT,,3
NSLE,S
CP,1,VOLT,ALL
CP,2,EMF,ALL
NCOIL=NDNEXT(0)
ALLSEL,ALL
ARSCAL,ALL,,,.01,.01,1,,0,1  ! Scale model to MKS (meters)
FINISH

/SOLU
ANTYP,TRANS
NSEL,EXT                   ! Select exterior nodes
D,ALL,AZ,0                 ! Set potentials to zero (flux-parallel)
ALLSEL,ALL
D,NCOIL,VOLT,12            ! voltage load
TIME,.01
DELTIM,.002
OUTRES,ALL,ALL
SOLVE
TIME,.03
NSUBST,1
SOLVE
TIME,.06
DELTIM,.005
NSUBST,1
SOLVE
FINISH

/POST1
*GET,_NSET,ACTIVE,,SET,NSET
*DIM,CURTIME,ARRAY,_NSET
*DIM,FORCEY,ARRAY,_NSET
*DIM,CUR,ARRAY,_NSET
*DIM,IND,ARRAY,_NSET

! sum up forces
CMSEL,S,ARM,ELEM
NSLE
ESLN
*DO,_ISET,1,_NSET
SET,,,,,,,_ISET
EMFT
FORCEY(_ISET)=_FYSUM
*ENDDO
ALLS

*DO,_ISET,1,_NSET
SET,,,,,,,_ISET
! get current
*GET,_CUR,NODE,NCOIL,RF,AMPS ! amps per turn
CUR(_ISET)=_CUR*n
! calculate inductance
ETABLE,_ENER,MENE
SSUM
*GET,ENER,SSUM,,ITEM,_ENER
IND(_ISET)=2*ENER/_CUR**2
*GET,CURTIME(_ISET),ACTIVE,,SET,TIME
*ENDDO

*VWRITE,'TIME','FORCE-Y','CURRENT','INDUCT'
(/4a14)
*VWRITE,'(SEC)',' (N)','(A-turn)','  (H)'
(4a14)
*VWRITE,CURTIME(1),FORCEY(1),CUR(1),IND(1)
(E14.5,1x,E14.5,1x,E14.5,1x,E14.5)
FINISH