/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-pl2b-182
/TITLE, vmr049-pl2b-182,  2D PLANE STRESS PLASTICITY BENCHMARK
/COM, REFERENCE: NAFEMS REPORT: R0049

/PREP7
R = 2.5E-5
ET,1,182,,,
KEYOPT,1,3,0    
N, 1, 0.0, 0.0
N, 2, 0.0, 1.0
N, 3, 1.0, 0.0
N, 4, 1.0, 1.0
E, 1,3,4,2
MP,EX  ,1,250E3,
MP,NUXY,1,0.25,
EX=250E3
ET=50E3
EP=EX*ET/(EX-ET)
TB,PLAS,1,,,BISO
TBDATA,1,5,EP
TB,HILL,1	
TBDATA,1,1.0,1.0,1.0,1.0,1.0,1.0
NSEL,S,LOC,X	
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,S,LOC,Y,1.0
D,ALL,UY

/SOLU
NLGEOM,ON
NSEL,S,LOC,X,1.0
D,ALL,UX,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
/OUT,SCRATCH
SOLVE
NSEL,S,LOC,X,1.0
D,ALL,UX,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,X,1.0
D,ALL,UX,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,X,1.0
D,ALL,UX,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
FINISH

/POST26
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/GTHK,AXIS,1
/GRTYP,0
/XRANGE,0,8
/YRANGE,-10,10
/AXLAB,X,STEP
/AXLAB,Y,STRESS
/OUT,
ESOL,2,1,4,S,X,
ESOL,3,1,4,S,Y,
ESOL,4,1,4,S,EQV,
PRVAR,2,3,4
PLVAR,2,3,4
*DIM,VALUEX,ARRAY,8,1
*DO,JJ,1,8,1
*GET,VALUEX(JJ,1),VARI,2,RTIME,JJ
*ENDDO
R1=VALUEX(1,1)/5.845
R2=VALUEX(2,1)/7.484
R3=VALUEX(3,1)/6.838
R4=VALUEX(4,1)/6.136
R5=VALUEX(5,1)/(-0.530)
R6=VALUEX(6,1)/(-5.822)
R7=VALUEX(7,1)/(-7.489)
R8=VALUEX(8,1)/(-9.155)
*DIM,VALUEY,ARRAY,8,1
*DO,JJ,1,8,1
*GET,VALUEY(JJ,1),VARI,3,RTIME,JJ
*ENDDO
R9=VALUEY(1,1)/1.673
R10=VALUEY(2,1)/2.944
R11=VALUEY(3,1)/7.742
R12=VALUEY(4,1)/9.925
R13=VALUEY(5,1)/8.259
R14=VALUEY(6,1)/4.842
R15=VALUEY(7,1)/(-1.824)
R16=VALUEY(8,1)/(-8.491)
*DIM,VALUEEF,ARRAY,8,1
*DO,JJ,1,8,1
*GET,VALUEEF(JJ,1),VARI,4,RTIME,JJ
*ENDDO
R17=VALUEEF(1,1)/5.214
R18=VALUEEF(2,1)/6.531
R19=VALUEEF(3,1)/7.332
R20=VALUEEF(4,1)/8.675
R21=VALUEEF(5,1)/8.536
R22=VALUEEF(6,1)/9.248
R23=VALUEEF(7,1)/6.764
R24=VALUEEF(8,1)/8.842
*DIM,STEP,CHAR,10
*DIM,TARGETX,CHAR,10
*DIM,TARGETY,CHAR,10
*DIM,TARGETEF,CHAR,10
*DIM,RATIOX,,8,1
*DIM,RATIOY,,8,1
*DIM,RATIOEF,,8,1
STEP(1)='1.0','2.0','3.0','4.0','5.0','6.0','7.0','8.0'
TARGETX(1)='5.845','7.484','6.838','6.136','-0.530','-5.822','-7.489','-9.155'
TARGETY(1)='1.673','2.944','7.742','9.925','8.259','4.842','-1.824','-8.491'
TARGETEF(1)='5.214','6.531','7.332','8.675','8.536','9.248','6.764','8.842'
*VFILL,RATIOX,DATA,R1,R2,R3,R4,R5,R6,R7,R8
*VFILL,RATIOY,DATA,R9,R10,R11,R12,R13,R14,R15,R16
*VFILL,RATIOEF,DATA,R17,R18,R19,R20,R21,R22,R23,R24
/COM,
/COM, ----------- vmr049-pl2b-182 RESULTS COMPARISON --------------
/COM,
/COM, vmr049-pl2b-182.jpeg RESULTS SHOULD MATCH R0049 NAFEMS MANUAL
/COM, GRAPH RESULTS ON PAGE 52, FIGURE 2.14(B).  THE RESULTS
/COM, DISPLAYED ARE INCREMENTED FOR THIS PURPOSE.
/COM,
/COM,
/COM, ------ vmr049-pl2b-182 STRESS RESULTS IN X DIRECTION -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETX(1),VALUEX(1,1),RATIOX(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM, ------ vmr049-pl2b-182 STRESS RESULTS IN Y DIRECTION -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETY(1),VALUEY(1,1),RATIOY(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
/COM, ------ vmr049-pl2b-182 EFFECTIVE STRESS RESULTS -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETEF(1),VALUEEF(1,1),RATIOEF(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
FINISH

/POST26
*DIM,LABEL1,CHAR,3
*DIM,VALUE1,,3,3
LABEL1(1) = ' SX ',' SY ',' SEFF '
*VFILL,VALUE1(1,1),DATA,VALUEX(8,1),VALUEY(8,1),VALUEEF(8,1)
*VFILL,VALUE1(1,2),DATA,R8,R16,R24
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr049-','pl2b-182'

/OUT,vmr049-pl2b-182,vrt
/COM
/COM,------------------- vmr049-pl2b RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, PLANE182
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(3),VALUE1(3,1),VALUE1(3,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmr049-pl2b-182,vrt