/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-cr5-186
/TITLE,vmr049-cr5-186,TORSIONAL CREEP OF SQUARE SHAFT
/COM NAFEMS: R0049 TEST: CR-5
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANT
*SET,C1,1E4
*SET,C2,5
*SET,C3,-0.5
*SET,C4,0
*SET,HOUR,100
ET,1,186
MP,EX,1,10
MP,NUXY,1,0.3
TOFF,1.0E-10
TB,CREEP,1,,,2
TBDATA,1,C1,C2,C3,C4,
BLOCK,0,1,0,1,0,0.2
ESIZE,0.25
VMESH,ALL
NODE10=NODE(1,0,0.2)
CSYS,1
NROTAT,ALL
*DIM,A,ARRAY,155
*DIM,B,ARRAY,155
*DO,I,1,155
A(I)=NX(I)
B(I)=NY(I)*3.1415926/180
*ENDDO
CSYS,0
NROTAT,ALL
NSEL,S,LOC,Z,
D,ALL,UX,0
D,ALL,UY,0
NSEL,ALL
NODE1=NODE(0,0,0)
NODE2=NODE(1,0,0)
NODE3=NODE(0,1,0)
D,NODE1,UZ,0
D,NODE2,UZ,0
D,NODE3,UZ,0
NSEL,ALL
NSEL,S,LOC,X,
NSEL,R,LOC,Z,0.1
NSEL,A,LOC,Y,
NSEL,R,LOC,Z,0.1
CP,131,UZ,ALL
NSEL,ALL
NSEL,S,LOC,X,
NSEL,R,LOC,Z,0.2
NSEL,A,LOC,Y,
NSEL,R,LOC,Z,0.2
CP,66,UZ,ALL
NSEL,ALL
NSEL,S,LOC,X,
NSEL,R,LOC,Z,
NSEL,A,LOC,Y,
NSEL,R,LOC,Z,
CP,2,UZ,ALL
NSEL,ALL
/SOLU
*DO,I,131,155
D,I,UX,-A(I)*0.001*SIN(B(I))
D,I,UY,A(I)*0.001*COS(B(I))
*ENDDO
*DO,I,66,130
D,I,UX,-A(I)*0.002*SIN(B(I))
D,I,UY,A(I)*0.002*COS(B(I))
*ENDDO
/SOLU
RATE, ON
DELT,.0001,.000099,.000101
TIME, .0001
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
RATE, ON
DELT,.001,.00099,.00101
TIME, .001
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
RATE, ON
DELT,.01,.009,.011
TIME, .01
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
RATE, ON
DELT,0.10,0.09,0.11
TIME, 0.10
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
RATE, ON
DELT,1,0.99,1.1
TIME, 1
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
RATE, ON
DELT,10,9.99,10.01
TIME, 10
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
RATE, ON
DELT,100,99.9,100.01
TIME, 100
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
/POST26
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/AXLAB,X,LOGTIME
/AXLAB,Y,SHEAR STRESS(YZ)
/GTHK,AXIS,1
/GRTYP,0
/GROPT,DIG1,5
/GROPT,DIG2,3
/GROPT,LOGX,ON
/GROPT,DIVX,6
/GROPT,DIVY,3
/XRANGE,1E-4,1E2
/YRANGE,0,0.06
ANSOL,2,NODE10,S,YZ
PLVAR,2
PRVAR,2
/GROPT,DIVX,6
/GROPT,DIVY,5
/XRANGE,1E-4,1E2
/YRANGE,0,0.05
ANSOL,3,NODE10,EPEL,YZ
ANSOL,4,NODE10,EPCR,YZ
ADD,5,3,4,,ETOTAL
PLVAR,3,4,5
PRVAR,3,4,5
FINISH
/POST1
*DIM,LABEL,CHAR,10
*DIM,SYZ,ARRAY,7,1
*DIM,TARGET,CHAR,10
*DIM,RATIO,ARRAY,7,1
*DO,JJ,1,7,1
SET,JJ
*GET,SYZ(JJ),NODE,NODE10,S,YZ
*ENDDO
R1=SYZ(1)/0.05000
R2=SYZ(2)/0.04322
R3=SYZ(3)/0.03751
R4=SYZ(4)/0.03081
R5=SYZ(5)/0.02499
R6=SYZ(6)/0.01877
R7=SYZ(7)/0.01427
TARGET(1)='0.0500','0.04322','0.03751','0.03081','0.02499','0.01877','0.01427'
LABEL(1)='-4','-3','-2','-1','0','1','2'
*VFILL,RATIO,DATA,R1,R2,R3,R4,R5,R6,R7
/COM
/COM,--------- vmr049-cr5-186 MIXED FORMULATION COMPARISON-----------
/COM,
/COM, vmr049-cr5-186.jpeg RESULTS SHOULD MATCH R0049 NAFEMS MANUAL
/COM, GRAPH RESULTS ON PAGE 109, FIGURE 3.16(A). THE RESULTS
/COM, DISPLAYED ARE INCREMENTED FOR THIS PURPOSE.
/COM,
/COM,| LOG(TIME) | TARGET | Mechanical APDL | RATIO
/COM,
*VWRITE,LABEL(1),TARGET(1),SYZ(1,1),RATIO(1,1)
(1X,A12,' ',1X,A8,' ',F14.6,' ',1F12.3)
FINISH
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' SYZ2 '
*VFILL,VALUE1(1,1),DATA,SYZ(7)
*VFILL,VALUE1(1,2),DATA,R7
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr049-','cr5-186'
/OUT,vmr049-cr5-186,vrt
/COM
/COM,------------------- vmr049-cr5 RESULTS COMPARISON ---------------------
/COM,
/COM, | Mechanical APDL | RATIO | INPUT |
/COM,
/COM, SOLID186
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,' ',F14.4,' ',F9.4,' ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr049-cr5-186,vrt
