/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMR029-T7-281
/TITLE,VMR029-T7-281,LARGE DISPLACEMENT ELASTIC RESPONSE OF A HINGED SPHERICAL SHELL UNDER UNIFORM PRESSURE LOADING
/COM, REF. 'NAFEMS ASSEMBLY BENCHMARK TESTS FOR 3D BEAMS AND SHELLS
/COM,       TEST 3DNLG-7
/PREP7
L=1570
T=100
P=0.1
ET,1,281
R,1,100,100,100,100
RMODIF,1,7,30000,30000
MP,EX,1,69
MP,NUXY,1,0.3
K,1,
K,6,5*L/8,,0.00020285*((5*L/8)*(3*L/8))
K,9,L,,0
LARC,       1,       9,       6
K,15,,3*L/4,0.00020285*((3*L/4)*(L/4))
K,17,,L,0
LARC,       1,      17,      15
ADRAG,1, , , , , ,2
KWPAVE,2
WPRO,,90.000000,
ASBW,1
ADELE,2, , ,1
LSLA,S,1
LESIZE,ALL,,,16
AMESH,ALL
DL,ALL, ,UX,
DL,ALL, ,UY,
DL,ALL, ,UZ,
SFE,ALL,2,PRES,,P
ALLSEL,ALL
FINISH
/SOLVE
NLGEOM,ON
NSUBST,200,2000,25
OUTRES,ALL,ALL
ARCLEN,1,,
AUTOTS,-1
/OUT,SCRATCH
SOLVE
FINISH
/OUT
/POST26
*DIM,X,TABLE,11,1
*DIM,Y,TABLE,11,1
X(  1,1)= 0
Y(  1,1)= 0
X(  2,1)= 30
Y(  2,1)= 0.042
X(  3,1)= 60
Y(  3,1)= 0.06
X(  4,1)= 90
Y(  4,1)= 0.063
X(  5,1)= 120
Y(  5,1)= 0.056
X(  6,1)= 150
Y(  6,1)= 0.048
X(  7,1)= 180
Y(  7,1)= 0.037
X(  8,1)= 210
Y(  8,1)= 0.031
X(  9,1)= 240
Y(  9,1)= 0.03
X( 10,1)= 270
Y( 10,1)= 0.05
X( 11,1)= 300
Y( 11,1)= 0.096
/XRANGE,0,330
/YRANGE,0,0.1
/AXLAB,X,CENTRAL DEFLECTION
/AXLAB,Y,APPLIED PRESSURE
/GROPT,DIVX,11
/COLOR,CURVE,YGRE
*VPLOT,X(1,1),Y(1,1)
/NOERASE
NSOL,2,481,U,Z,DISP.          ! CENTER NODE
PROD,3,2, , ,DISP., , ,-1,0,0,
PROD,7,1, , ,LOAD, , ,0.1,0,0,
/COLOR,CURVE,MRED
XVAR,3
PLVAR,7
PRVAR,1,3,7
FINISH
/POST1
NSEL,S,NODE,,481             ! CENTER NODE
PRNSOL,U,COMP
SET,LAST
*GET,VAL8,NODE,481,U,Z
*SET,UA_8,-1*VAL8
*DIM,LABEL1,CHAR,1,2
LABEL1(1,1) = '0.1012'
LABEL1(1,2) = '      '
*DIM,VALUE1,CHAR,1,2
VALUE1(1,1) = '303.1'
*DIM,LABEL2,CHAR,1,3
LABEL2(1,1) = '481'
*DIM,ERROR1,,1,3
*VFILL,ERROR1(1,1),DATA,UA_8
/OUT,
/COM,
/COM,  -------------      CENTRAL DISPLACEMENT      -------------
/COM,
/COM,                  |   NAFEMS   |       Mechanical APDL         |
/COM,         |  LOAD  |  NUM.RES.  |  NODE  	|	  SHL.281  |
/COM,
*VWRITE,LABEL1(1,1),VALUE1(1,1),LABEL2(1,1),ERROR1(1,1)
(1X,'           ',A6,'     ',A5,'       ',A4,'    ',F12.3)
/COM,
/COM,  ----------------------------------------------------------
SET,LIST
SET,1,15
*GET,PRES1,TIME
SET,1,26
*GET,PRES2,TIME
V1=PRES1*0.1
V2=PRES2*0.1
R1=V1/0.06495
R2=V2/0.03084
*DIM,VALUE,,2,2
*DIM,LABEL3,CHAR,2
*DIM,LABEL,CHAR,2
*DIM,LABEL4,CHAR,2
*VFILL,VALUE(1,1),DATA,V1,V2
*VFILL,VALUE(1,2),DATA,R1,R2
LABEL3(1) = 'LIMIT1','LIMIT2'
LABEL(1) = 'vmr029-','vmr029-'
LABEL4(1) = 't7-281','t7-281'
/OUT,vmr029-t7-281,vrt
/COM
/COM,-------------- VMR029-T7  RESULTS COMPARISON ---------------
/COM,
/COM,          |    Mechanical APDL    |   RATIO   |      INPUT      |
/COM,
/COM,SHELL281
*VWRITE,LABEL3(1),VALUE(1,1),VALUE(1,2),LABEL(1),LABEL4(1)
(1X,A6,'        ',F12.5,'      ',F13.5,'      ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr029-t7-281,vrt