/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr027-cr6b-187
/TITLE,vmr027-cr6b-187,3D TRIAXIAL DISPLACEMENT SECONDARY CREEP
/COM, REFRENCE: TEST 6(B) FROM NAFEMS R0027.

/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANTS !***
*SET,C1,3.125E-14
*SET,C2,5.0
*SET,C3,0.0
*SET,C4,0
C***  TIME PARAMETER
*SET,HOUR,1000
C***   ELASTIC CONSTANT
MP,EX,1,0.2000E+06
MP,EY,1,0.2000E+06
MP,EZ,1,0.2000E+06
MP,GXY,1,0.7692E+05
MP,GYZ,1,0.7692E+05
MP,GXZ,1,0.7692E+05
MP,NUXY,1,0.3000E+00
MP,NUYZ,1,0.3000E+00
MP,NUXZ,1,0.3000E+00
MP,DENS,1,0.0000E+00
TUNIF,HOT
TOFF,OFFS
TB,CREEP,1,,,6
TBDATA,1,C1,C2,C3,C4
SAVE
ET,1,SOLID187
BLOCK,0,100,0,100,0,100,
ESIZE,100,0,
VMESH,ALL
NSEL,ALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,S,LOC,Z,100
D,ALL,UZ
NSEL,S,LOC,X,100
D,ALL,UX,0.3
NSEL,S,LOC,Y,100
D,ALL,UY,0.2
NSEL,S,LOC,Z
D,ALL,UZ,-0.1
NSEL,ALL

*DO,I,1,2,1

*IF,I,EQ,2,THEN
/PREP7
TB,HILL,1
TBDATA,1, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0
*ENDIF

/SOLU
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,0.10,0.099,0.10
TIME, 0.10
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,1.0,0.99,1.0
TIME, 1.0
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,5.0,4.99,5.0
TIME, 5.0
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,10.0,9.99,10.0
TIME, 10.0
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON, ON
DELT,10,1,100
AUTOS,OFF
TIME,1000
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
FINISH

*IF,I,EQ,1,THEN
/POST26
ESOL,2,1,,S,X
/AXLAB,X,TIME
/AXLAB,Y,STRESS
/COLOR,CURVE,RED,1
/YRANGE,1000,1160
PLVAR,2
PRVAR,2
FINISH

/POST1
SET,1,1
*GET,SH1,NODE,1,S,X
R1=SH1/1153.85
SET,2,1
*GET,SH2,NODE,1,S,X
R2=SH2/1076.29
SET,3,1
*GET,SH3,NODE,1,S,X
R3=SH3/1043.42
SET,4,1
*GET,SH4,NODE,1,S,X
R4=SH4/1029.11
SET,,,,,,,5
*GET,SH5,NODE,1,S,X
R5=SH5/1024.45
SET,,,,,,,9
*GET,SH6,NODE,1,S,X
R6=SH6/1016.33
SET,,,,,,,14
*GET,SH7,NODE,1,S,X
R7=SH7/1013.78
SET,,,,,,,54
*GET,SH8,NODE,1,S,X
R8=SH8/1009.20
SET,,,,,,,104
*GET,SH9,NODE,1,S,X
R9=SH9/1007.73
*DIM,VALUE,,9,3
*DIM,LABEL,CHAR,10
LABEL(1) = '0','0.1', '1.0', '5.0', '10.0', '50.0','100.0','500.0','1000.0'
*VFILL,VALUE(1,1),DATA,1153.85,1076.29,1043.42,1029.11,1024.45,1016.33,1013.78,1009.20,1007.73
*VFILL,VALUE(1,2),DATA,SH1,SH2,SH3,SH4,SH5,SH6,SH7,SH8,SH9
*VFILL,VALUE(1,3),DATA,R1,R2,R3,R4,R5,R6,R7,R8,R9
*ENDIF

*IF,I,EQ,2,THEN
/COM,
/COM,  ANISOTROPIC CREEP MODELED AS ISOTROPIC
/COM,

/POST26
ESOL,3,1,,S,X
PRVAR,3
/AXLAB,X,TIME
/AXLAB,Y,STRESS
/COLOR,CURVE,BLUE,1
/YRANGE,1000,1160
PLVAR,3

/POST1
SET,1,1
*GET,SH12,NODE,1,S,X
R12=SH12/1153.85
SET,2,1
*GET,SH13,NODE,1,S,X
R13=SH13/1076.29
SET,3,1
*GET,SH14,NODE,1,S,X
R14=SH14/1043.42
SET,4,1
*GET,SH15,NODE,1,S,X
R15=SH15/1029.11
SET,,,,,,,5
*GET,SH16,NODE,1,S,X
R16=SH16/1024.45
SET,,,,,,,9
*GET,SH17,NODE,1,S,X
R17=SH17/1016.33
SET,,,,,,,14
*GET,SH18,NODE,1,S,X
R18=SH18/1013.78
SET,,,,,,,54
*GET,SH19,NODE,1,S,X
R19=SH19/1009.20
SET,,,,,,,104
*GET,SH20,NODE,1,S,X
R20=SH20/1007.73
*DIM,VALUE2,,9,3
*DIM,LABEL2,CHAR,10
LABEL2(1) = '0','0.1', '1.0', '5.0', '10.0', '50.0','100.0','500.0','1000.0'
*VFILL,VALUE2(1,1),DATA,1153.85,1076.29,1043.42,1029.11,1024.45,1016.33,1013.78,1009.20,1007.73
*VFILL,VALUE2(1,2),DATA,SH12,SH13,SH14,SH15,SH16,SH17,SH18,SH19,SH20
*VFILL,VALUE2(1,3),DATA,R12,R13,R14,R15,R16,R17,R18,R19,R20
*ENDIF
*ENDDO
/COM
/COM,--------- vmr027-cr6b-187 ISOTROPIC RESULTS COMPARISON-----------
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2), VALUE(1,3)
(1X,A8,'   ',F8.3,'   ',F12.3,'   ',1F12.3)
/COM,
/COM,
/COM,--------- vmr027-cr6b-187 ANISOTROPIC RESULTS COMPARISON-----------
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL2(1), VALUE2(1,1), VALUE2(1,2), VALUE2(1,3)
(1X,A8,'   ',F8.3,'   ',F12.3,'   ',1F12.3)
FINISH

/POST26
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ISOCRX ',' ANICRX '
*VFILL,VALUE1(1,1),DATA,SH9,SH20
*VFILL,VALUE1(1,2),DATA,R9,R20
*DIM,LABEL3,CHAR,2
LABEL3(1) = 'vmr027-','cr6b-187'

/OUT,vmr027-cr6b-187,vrt
/COM
/COM,------------------- vmr027-cr6b RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SOLID187
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL3(1),LABEL3(2)
(1X,A8,'      ',F12.3,'      ',F12.4,'     ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL3(1),LABEL3(2)
(1X,A8,'      ',F12.3,'      ',F12.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmr027-cr6b-187,vrt