/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr027-cr10c-281
/TITLE,vmr027-cr10c-281,2D PLANE STRESS-BIAXIAL STEPPED LOAD PRIMARY CREEP
/COM, REFERENCE: TEST 10(C) FROM NAFEMS R0027.
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANT !(TIME HARDENING)***
*SET,C1,1.5625E-14
*SET,C2,5
*SET,C3,-0.5
*SET,C4,0
C*** TIME PARAMETER
*SET,HOUR,200
C*** ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,HOT
TOFF,1E-10
TB,CREEP,1,,,2
TBDATA,1,C1,C2,C3,C4
C*** PARAMETRIC INPUT FOR CREEP CONSTANT !(STRAIN HARDENING)***
*SET,C1,1.5625E-14
*SET,C2,5
*SET,C3,-0.5
*SET,C4,0
C*** ELASTIC CONSTANT
MP,EX,2,200E3
MP,NUXY,2,0.3
TB,CREEP,2,,,7
TBDATA,1,C1,C2,C3,C4
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
N,9,50,50
N,10,25,0,0
N,11,75,0,0
N,12,0,25,0
N,13,50,25,0
N,14,100,25,0
N,15,25,50,0
N,16,75,50,0
N,17,0,75,0
N,18,50,75,0
N,19,100,75,0
N,20,25,100,0
N,21,75,100,0
ET,1,SHELL281,,,
R,1,1,1,1,1,
E,1,5,9,8,10,13,15,12
E,5,2,6,9,11,14,16,13
E,9,6,3,7,16,19,21,18
E,8,9,7,4,15,18,20,17
NSEL,S,LOC,X,
D,ALL,UX,
NSEL,ALL
NSEL,S,LOC,Y,
D,ALL,UY,
NSEL,ALL
D,ALL,UZ
D,ALL,ROTX
D,ALL,ROTY
*DO,I,1,2
*STATUS,I
/PREP7
*IF,I,EQ,1,THEN
MAT,1
*ELSEIF,I,EQ,2,THEN
MPCHG,2,ALL
*ENDIF
FINI
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NSEL,ALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NSEL,ALL
RATE,ON,ON
TIME,1E-8
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE,ON,ON
NSUBST,20,20,20
TIME,1.0
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE,ON,ON
NSUBST,20,20,20
TIME,10.0
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE,ON,ON
NSUBST,20,20,20
TIME,50.0
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE,ON,ON
NSUBST,50,50,50
TIME,100.0
/OUTPUT,SCRATCH
SOLVE
/OUT
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-250
NSEL,ALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,250
NSEL,ALL
RATE,ON,ON
NSUBST,50,50,50
TIME,110.0
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE,ON,ON
NSUBST,50,50,50
TIME,120.0
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE,ON,ON
NSUBST,50,50,50
TIME,150.0
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON, ON
NSUBST,50,50,50
TIME,200
/OUTPUT,SCRATCH
SOLVE
/OUT
FINISH
/POST1
*IF,I,EQ,1,THEN
SET,,,,,,,1
*GET,S1,NODE,1,EPCR,X
R1=1.00
SET,,,,,,,2
*GET,S2,NODE,1,EPCR,X
R2=S2/0.135
SET,,,,,,,3
*GET,S3,NODE,1,EPCR,X
R3=S3/0.4269
SET,,,,,,,4
*GET,S4,NODE,1,EPCR,X
R4=S4/0.9546
SET,,,,,,,5
*GET,S5,NODE,1,EPCR,X
R5=S5/1.35
SET,,,,,,,6
*GET,S6,NODE,1,EPCR,X
R6=S6/1.5511
SET,,,,,,,7
*GET,S7,NODE,1,EPCR,X
R7=S7/1.7433
SET,,,,,,,8
*GET,S8,NODE,1,EPCR,X
R8=S8/2.276
SET,,,,,,,9
*GET,S9,NODE,1,EPCR,X
R9=S9/3.0565
*DIM,VALUE,,9,3
*DIM,LABEL,CHAR,10
LABEL(1) = '0','1.0', '10.0', '50.0', '100.0', '110.0','120.0','150.0','200.0'
*VFILL,VALUE(1,1),DATA,0.0000,0.1350,0.4269,0.9546,1.3500,1.5511,1.7433,2.2760,3.0565
*VFILL,VALUE(1,2),DATA,S1,S2,S3,S4,S5,S6,S7,S8,S9
*VFILL,VALUE(1,3),DATA,R1,R2,R3,R4,R5,R6,R7,R8,R9
*ELSEIF,I,EQ,2,THEN
SET,,,,,,,1
*GET,SH1,NODE,1,EPCR,X
R10=1.00
SET,,,,,,,2
*GET,SH2,NODE,1,EPCR,X
R11=SH2/0.135
SET,,,,,,,3
*GET,SH3,NODE,1,EPCR,X
R12=SH3/0.4269
SET,,,,,,,4
*GET,SH4,NODE,1,EPCR,X
R13=SH4/0.9546
SET,,,,,,,5
*GET,SH5,NODE,1,EPCR,X
R14=SH5/1.35
SET,,,,,,,6
*GET,SH6,NODE,1,EPCR,X
R15=SH6/1.8762
SET,,,,,,,7
*GET,SH7,NODE,1,EPCR,X
R16=SH7/2.2842
SET,,,,,,,8
*GET,SH8,NODE,1,EPCR,X
R17=SH8/3.2108
SET,,,,,,,9
*GET,SH9,NODE,1,EPCR,X
R18=SH9/4.3354
*DIM,VALUE2,,9,3
*DIM,LABEL2,CHAR,10
LABEL2(1) = '0','1.0', '10.0', '50.0', '100.0', '110.0','120.0','150.0','200.0'
*VFILL,VALUE2(1,1),DATA,0.0000,0.1350,0.4269,0.9546,1.3500,1.8762,2.2842,3.2108,4.3354
*VFILL,VALUE2(1,2),DATA,SH1,SH2,SH3,SH4,SH5,SH6,SH7,SH8,SH9
*VFILL,VALUE2(1,3),DATA,R10,R11,R12,R13,R14,R15,R16,R17,R18
*ENDIF
/POST26
*IF,I,EQ,1,THEN
ESOL,2,1,,EPCR,X,TIMEHARD
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
/XRANGE,0,200
/YRANGE,0,5
/COLOR,CURVE,BLUE,1
PLVAR,2
/NOERASE
*ELSEIF,I,EQ,2,THEN
ESOL,3,1,,EPCR,X,STRAINHA
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
/COLOR,CURVE,RED,1
/XRANGE,0,200
/YRANGE,0,5
PLVAR,3
*ENDIF
*ENDDO
/COM
/COM
/COM,----------- vmr027-cr10c-281 TIME HARDENING RESULTS COMPARISON -------------
/COM,
/COM, vmr027-cr10c-281.jpeg RESULTS SHOULD MATCH R0027 NAFEMS MANUAL
/COM, GRAPH RESULTS OF TEST 10(C).
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2), VALUE(1,3)
(1X,A8,'   ',F8.3,'   ',F13.3,'   ',1F13.3,'   ')
/COM,
/COM,
/COM,----------- vmr027-cr10c-281 STRAIN HARDENING RESULTS COMPARISON -------------
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL2(1), VALUE2(1,1), VALUE2(1,2), VALUE2(1,3)
(1X,A8,'   ',F8.3,'   ',F13.3,'   ',1F13.3,'   ')
FINISH
/POST26
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' S2 ',' S7 '
*VFILL,VALUE1(1,1),DATA,S9,SH9
*VFILL,VALUE1(1,2),DATA,R9,R18
*DIM,LABEL3,CHAR,3
LABEL3(1) = 'vmr027-','cr10c-28','1'
/OUT,vmr027-cr10c-281,vrt
/COM
/COM,------------------- vmr027-cr10c RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SHELL281
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL3(1),LABEL3(2),LABEL3(3)
(1X,A8,'      ',F13.3,'      ',F9.4,'     ',A7,A8,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL3(1),LABEL3(2),LABEL3(3)
(1X,A8,'      ',F13.3,'      ',F9.4,'     ',A7,A8,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr027-cr10c-281,vrt