/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMC6
/SHOW
/TITLE, VMC6, TWO-DIMENSIONAL HEAT TRANSFER WITH CONVECTION
/COM, SEE "SELECTED FE BENCHMARKS IN STRUCTURAL AND THERMAL
/COM, ANALYSIS", NAFEMS REPT. FEBSTA REV. 1, OCT. 1986
/COM, TEST NO. T4
/OUT,SCRATCH
*DIM,NARAY,TABLE,16,6 ! 2-D NARAY FOR RESULTS INFO
*DO,I,1,16 !LOOP THROUGH ETYPE AND DIFF. MESH PARAMETERS
*IF,I,EQ,1,THEN,
ETYP = 55
ARG1 = 0.2
ARG2 = 0 !MSHAPE = QUAD
ARG3 = 1 !MSHKEY = MAPPED MESHING
!QUADRILATERAL MESH (N1 = 0.2)
*ELSEIF,I,EQ,2,THEN,
ETYP = 55
ARG1 = 0.1
ARG2 = 0
ARG3 = 1
!QUADRILATERAL MESH (N1 = 0.1)
*ELSEIF,I,EQ,3,THEN,
ETYP = 77
ARG1 = 0.2
ARG2 = 0
ARG3 = 1
!QUADRILATERAL MESH (N1 = 0.2)
*ELSEIF,I,EQ,4,THEN,
ETYP = 77
ARG1 = 0.1
ARG2 = 0
ARG3 = 1
!QUADRILATERAL MESH (N1 = 0.1)
*ELSEIF,I,EQ,5,THEN,
ETYP = 35
ARG1 = 0.2
ARG2 = 1 !MSHAPE = TRI
ARG3 = 0 !MSHKEY = UNMAPPED
!TRIANGLE MESH (N1 = 0.2)
*ELSEIF,I,EQ,6,THEN,
ETYP = 35
ARG1 = 0.1
ARG2 = 1
ARG3 = 0
!TRIANGLE MESH (N1 = 0.1)
*ELSEIF,I,EQ,7,THEN,
ETYP = 55
ARG1 = 0.2
ARG2 = 1
ARG3 = 0
!TRIANGLE MESH (N1 = 0.2)
*ELSEIF,I,EQ,8,THEN,
ETYP = 55
ARG1 = 0.1
ARG2 = 1
ARG3 = 0
!TRIANGLE MESH (N1 = 0.1)
*ELSEIF,I,EQ,9,THEN,
ETYP = 77
ARG1 = 0.2
ARG2 = 1
ARG3 = 0
!TRIANGLE MESH (N1 = 0.2)
*ELSEIF,I,EQ,10,THEN,
ETYP = 77
ARG1 = 0.1
ARG2 = 1
ARG3 = 0
!TRIANGLE MESH (N1 = 0.1)
*ELSEIF,I,EQ,11,THEN,
ETYP = 35
ARG1 = 0.2
ARG2 = 1 !MSHAPE = TRI
ARG3 = 1 !MSHKEY = MAPPED
!TRIANGLE MESH (N1 = 0.2)
*ELSEIF,I,EQ,12,THEN,
ETYP = 35
ARG1 = 0.1
ARG2 = 1
ARG3 = 1
!TRIANGLE MESH (N1 = 0.1)
*ELSEIF,I,EQ,13,THEN,
ETYP = 55
ARG1 = 0.2
ARG2 = 1
ARG3 = 1
!TRIANGLE MESH (N1 = 0.2)
*ELSEIF,I,EQ,14,THEN,
ETYP = 55
ARG1 = 0.1
ARG2 = 1
ARG3 = 1
!TRIANGLE MESH (N1 = 0.1)
*ELSEIF,I,EQ,15,THEN,
ETYP = 77
ARG1 = 0.2
ARG2 = 1
ARG3 = 1
!TRIANGLE MESH (N1 = 0.2)
*ELSEIF,I,EQ,16,THEN,
ETYP = 77
ARG1 = 0.1
ARG2 = 1
ARG3 = 1
!TRIANGLE MESH (N1 = 0.1)
*ENDIF
PARSAV,ALL
/clear, nostart
PARRES,CHANGE
/PREP7
SMRT,OFF
!TO SUPPLY TITLES TO THE IMAGES
*IF,I,LE,4,THEN
/TITLE,VMC6 - QUADRILATERAL MESH: (N1 = %ARG1%)
*ELSEIF,I,GT,4,AND,I,LE,10,THEN
/TITLE,VMC6 - TRIANGLE MESH: (N1 = %ARG1%)
*ELSEIF,I,GT,11,THEN
/TITLE,VMC6 - UNIFORM TRIANGLE MESH: (N1 = %ARG1%)
*ENDIF
ANTYPE,STATIC ! THERMAL ANALYSIS
ET,1,ETYP ! DEFINE ELEMENT TYPE PARAMETRICALLY
NARAY(I,1)= ETYP ! STORE ETYPE
MP,KXX,1,52.0 ! DEFINE CONDUCTIVITY
K,1 ! DEFINE KEYPOINTS
K,2,.6
K,3,.6,1.0
K,4,,1.0
A,1,2,3,4
ESIZE,ARG1 ! DEFINE ELEMENT SIZE, & SHAPE PARAMETRICALLY
MSHAPE,ARG2
MSHKEY,ARG3
NARAY(I,2)=ARG1 ! STORE N1 (ELEMENT EDGE LENGTH)
NARAY(I,3)=ARG2 ! STORE N2 (ELEMENT SHAPE)
AMESH,1 ! MESH AREA
*GET,MAXE,ELEM,,NUM,MAX
*GET,MAXN,NODE,,NUM,MAX
NARAY(I,4)=MAXN*1 ! CALCULATE NO. DEGREES OF FREEDOM
T1=NODE(.6,.2,0) ! GET NODE NUMBER OF INTEREST
NSEL,S,LOC,Y,0
D,ALL,TEMP,100. ! SPECIFY EDGE TEMPERATURE
NSEL,S,LOC,X,0.6
SF,ALL,CONV,750.0,0.0 ! SPECIFY CONVECTION SURFACES
NSEL,A,LOC,Y,1.0
SF,ALL,CONV,750.0,0.0
NSEL,ALL
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!! SETUP AND PLOT ELEMENTS FOR DOCUMENTATION !!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
*IF,ETYP,EQ,55,THEN
/AUTO,1
/VIEW,1,,,1
/ANG,1
/DEVICE,VECTOR,1
/DEVICE,DITHER,1
/TYPE,ALL,4
/COLOR,NUM,BLUE,1
/SHOW,PNG,REV
EPLOT
/SHOW,CLOSE
*ENDIF
FINISH
/SOLU
SOLVE
*GET,NTEM,TEMP,T1 ! GET TEMERATURE AT NODE OF INTEREST
NARAY(I,5)=NTEM ! STORE TEMPERATURE
NARAY(I,6)=NTEM/18.3 ! CALCULATE TEMPERATURE RATIO
PARSAV,,PARAM
FINISH
*ENDDO
/OUT,
!*STAT,NARAY ! GET STATUS OF NARAY
*VLEN,4
*VCOL,6
/OUT,vmc6,vrt
/COM,
/COM,------------------- VMC6 RESULTS LISTING ---------------------
/COM
/COM, QUAD MESH
/COM,
/COM,| ETYP | N1 | DOF | TEMP(C) | TEMP RATIO |
/COM,
*VWRITE,NARAY(1,1),NARAY(1,2),NARAY(1,4),NARAY(1,5),NARAY(1,6)
(F5.0,' ',F5.2,' ',F5.0,' ',F5.1,' ',F5.2)
/COM,
/OUT
*VLEN,6
/OUT,vmc6,vrt,,append
/COM, TRIANGLE MESH
/COM,
/COM,| ETYP | N1 | DOF | TEMP(C) | TEMP RATIO |
/COM,
*VWRITE,NARAY(5,1),NARAY(5,2),NARAY(5,4),NARAY(5,5),NARAY(5,6)
(F5.0,' ',F5.2,' ',F5.0,' ',F5.1,' ',F5.2)
/COM,
/COM, UNIFORM TRIANGLE MESH
/COM,
/COM,| ETYP | N1 | DOF | TEMP(C) | TEMP RATIO |
/COM,
*VWRITE,NARAY(11,1),NARAY(11,2),NARAY(11,4),NARAY(11,5),NARAY(11,6)
(F5.0,' ',F5.2,' ',F5.0,' ',F5.1,' ',F5.2)
/COM,
/COM,---------------------------------------------------------------
/OUT
FINISH
*LIST,vmc6,vrt
FINISH
