/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VM218
/TITLE,VM218, HYPERELASTICITY TEST: BALLOON/CIRCULAR PLATE PROBLEM
/COM          USING SHELL181 ELEMENTS
/GRAPHICS,POWER
/PREP7
TB,HYPER,1,,,MOONEY
TBDATA,1,80.0,20.0
ET,1,SHELL181
SECT,1,SHELL
THICK = 0.5             !SHELL THICKNESS
SECD,THICK,1
CSYS,1
K,1,0,0,0
K,2,7.5,0,0
K,3,7.5,7.5
L,1,2
L,2,3
L,3,1
A,1,2,3
LESIZE,1, , ,10
LESIZE,2, , ,1
LESIZE,3, , ,10
AMESH,1
D,ALL,UY
D,ALL,ROTX
D,ALL,ROTZ
NSEL,S,LOC,X,0
D,ALL,ALL
DDELE,ALL,UZ
NSEL,S,LOC,X,7.5
D,ALL,UX
D,ALL,UY
D,ALL,UZ
ALLSEL,ALL
LOCAL, 11,1, 0.0,0.0,0.0,0,0.0,0.0
NROTAT,ALL
AUTOTS,ON
NSUBST, 400, 1200,25
NLGEOM,ON
NROPT,FULL, ,OFF
OUTRES, ALL, ALL,
SF,ALL,PRES,50.0
NEQITR,20 
FINISH
/SOLUTION
/OUT,SCRATCH
SOLVE
FINISH
/POST1
/NOPR		   !SUPPRESS GRAPHING DATA
/VIEW,1,,-1
/ANG,1
/USER
/FOCUS,1,4,,8,0	   !SET UP CENTER OF GRAPHICS SCREEN FOR DISPLACEMENT PLOT
/DIST,,12	   !SET DISTANCE TO ZOOM OUT
/TRIAD,OFF
SET,FIRST	   !SET DISPLACEMENT DATA FOR FIRST SUBSTEP
PLDISP,0	   !PLOT DISPLACEMENT DATA
/NOERASE	   !SET DISPLAY TO OVERLAY PLOTS
SET,,10
PLDISP,0
SET,,20
PLDISP,0
SET,,25
PLDISP,0
SET,LAST
PLDISP,1	   !PLOT FINAL DISPLACEMENT WITH ORIGINAL POSITION
/ERASE
/TRIAD,ON
/GOPR
/ESHAPE,0
FINISH
/POST26
/XRANGE,0,3.0
/YRANGE,0,1
/AXLAB,X,UZ OF CENTER/R-INITIAL
/AXLAB,Y,THICKNESS/ORIGINAL THICKNESS
NSOL,2,1,U,Z,UZ_1
ESOL,3,1, ,SMIS,17,TH_1
ADD,4,2, , ,UZRATIO, , ,0.13333333,0,0,
ADD,5,3, , ,SH.181, , ,2,0,0,
/COLOR,CURVE,MRED
XVAR,4
PLVAR,5
/ERASE
/NOPR
*DIM,X,TABLE,20,1
*DIM,Y,TABLE,20,1
X(  1,1)= 1.25
Y(  1,1)= 1.25
X(  2,1)= 1.8
Y(  2,1)= 2.5
X(  3,1)= 2.25
Y(  3,1)= 4.0
X(  4,1)= 2.6
Y(  4,1)= 5.9
X(  5,1)= 2.9
Y(  5,1)= 7.8
X(  6,1)= 3.2
Y(  6,1)= 9.8
X(  7,1)= 3.5
Y(  7,1)= 11.6
X(  8,1)= 3.62
Y(  8,1)= 12.6
X(  9,1)= 4.1
Y(  9,1)= 15.3
X( 10,1)= 4.9
Y( 10,1)= 18.8
X( 11,1)= 5.7
Y( 11,1)= 22.1
X( 12,1)= 6.2
Y( 12,1)= 24.0
X( 13,1)= 7.2
Y( 13,1)= 27.9
X( 14,1)= 8.3
Y( 14,1)= 31.2
X( 15,1)= 8.9
Y( 15,1)= 32.9
X( 16,1)= 9.9
Y( 16,1)= 35.8
X( 17,1)= 10.9
Y( 17,1)= 38.0
X( 18,1)= 13.1
Y( 18,1)= 42.9
X( 19,1)= 14.4
Y( 19,1)= 45
X( 20,1)= 15.2
Y( 20,1)= 46
/GOPR
/XRANGE,0,20
/YRANGE,0,60
/AXLAB,X,UZ OF CENTER (IN)
/AXLAB,Y,PRESSURE (LB/SQ IN)
/COLOR,CURVE,YGRE
*VPLOT,X(1,1),Y(1,1)
/NOERASE
NSOL,2,1,U,Z,UZ_1
PROD,7,1, , ,SH.181 , , ,50,0,0,!MULTIPLY SOLUTION BY 50
/COLOR,CURVE,MRED
XVAR,2  		        !SPECIFY X VARIABLE TO BE DISPLAYED
PLVAR,7 		        !DISPLAY SOLUTION IN GRPH FILE
/ERASE
/OUT,
PRVAR,7,2		        !LIST VARIABLE 7 VERSUS VARIABLE 2
FINISH
/OUT,SCRATCH
/POST1
/NOPR
SET,NEAR,,,,0.08		!SELECT UZ VALUE FOR NODE 1 AT T=0.08
*GET,VR1,NODE,1,U,Z
SET,NEAR,,,,0.48		!UZ VALUE FOR NODE 1 AT T=0.48
*GET,VR2,NODE,1,U,Z
SET,NEAR,,,,0.76		!UZ VALUE FOR NODE 1 AT T=0.76
*GET,VR3,NODE,1,U,Z
PRES1 = (0.08*50)		!SOLVE FOR PRES IN RESULTS TABLE
PRES2 = (0.48*50)
PRES3 = (0.76*50)
*DIM,LABEL,,3		        !SETUP RESULTS TABLE DATA
*DIM,VALUE,,3,3
LABEL(1) = PRES1,PRES2,PRES3
*VFILL,VALUE(1,1),DATA,2.25,6.2,10.9
*VFILL,VALUE(1,2),DATA,VR1,VR2,VR3
*VFILL,VALUE(1,3),DATA,(VR1/2.25),(VR2/6.2),(VR3/10.9)
FINISH
SAVE,TABLE_1
/CLEAR,NOSTART
/TITLE,VM218, HYPERELASTICITY TEST: BALLOON/CIRCULAR PLATE PROBLEM
/COM,         USING SHELL208 ELEMENTS

/PREP7
ET1 = 208
ET,1,SHELL208           ! 2 NODE ELEMENT, KEYOPT(3) = 0
THICK = 0.5             !SHELL THICKNESS
SECT,1,SHELL
SECD,THICK
TB,HYPER,1,,,MOONEY
TBDATA,1,80.0,20.0
N  ,     1 ,        0.,         0.
N  ,     2 ,   0.17143,         0.
N  ,     3 ,   0.47143,         0.
N  ,     4 ,   0.90000,         0.
N  ,     5 ,    1.4571,         0.
N  ,     6 ,    2.1429,         0.
N  ,     7 ,    2.9571,         0.
N  ,     8 ,    3.9000,         0.
N  ,     9 ,    4.9714,         0.
N  ,    10 ,    6.1714,         0.
N  ,    11 ,    7.5000,         0.
E,    1,       2
E,    2,       3
E,    3,       4
E,    4,       5
E,    5,       6
E,    6,       7
E,    7,       8
E,    8,       9
E,    9,      10
E,   10,      11
FINISH
*CREATE,SOLVEIT,MAC
/PREP7
NSEL,S,LOC,X, 0.0		!CONSTRAINTS AT X =0
D, ALL, UX
D, ALL, ROTZ
NSEL,ALL
NSEL,S,LOC,X,7.5
D, ALL,UX
D, ALL,UY
NSEL,ALL
AUTOTS,ON
NSUBST, 400, 1200,25
NLGEOM,ON
NROPT,FULL, ,OFF
OUTRES, ALL, ALL,
SF,ALL,PRES,-50.0
NEQITR,20
/AUTO,1
/VIEW,1,1,1,1
/ANG,1
/ESHAPE,1
EPLOT
FINISH
/SOLUTION
/OUT,SCRATCH
SOLVE
FINISH
*END
SOLVEIT
*CREATE,PLOTS,MAC
/POST1
/NOPR		   !SUPPRESS GRAPHING DATA
/VIEW,1,,,1
/ANG,1
/USER
/FOCUS,1,4,8,,0	   !SET UP CENTER OF GRAPHICS SCREEN FOR DISPLACEMENT PLOT
/DIST,,12	   !SET DISTANCE TO ZOOM OUT
/TRIAD,OFF
SET,FIRST	   !SET DISPLACEMENT DATA FOR FIRST SUBSTEP
PLDISP,0	   !PLOT DISPLACEMENT DATA
/NOERASE	   !SET DISPLAY TO OVERLAY PLOTS
SET,,10
PLDISP,0
SET,,20
PLDISP,0
SET,,25
PLDISP,0
SET,LAST
PLDISP,1	   !PLOT FINAL DISPLACEMENT WITH ORIGINAL POSITION
/ERASE
/TRIAD,ON
/GOPR
/ESHAPE,0
FINISH
/POST26
/XRANGE,0,3.0
/YRANGE,0,1
/AXLAB,X,UY OF CENTER/R-INITIAL
/AXLAB,Y,THICKNESS/ORIGINAL THICKNESS
NSOL,2,1,U,Y,UY_1
ESOL,3,1, ,SMIS,13,TH_1
ADD,4,2, , ,UZRATIO, , ,0.13333333,0,0,
ADD,5,3, , ,SH.%ET1%, , ,2,0,0,
/COLOR,CURVE,MRED
XVAR,4
PLVAR,5
/ERASE
/NOPR
*DIM,X,TABLE,20,1
*DIM,Y,TABLE,20,1
X(  1,1)= 1.25
Y(  1,1)= 1.25
X(  2,1)= 1.8
Y(  2,1)= 2.5
X(  3,1)= 2.25
Y(  3,1)= 4.0
X(  4,1)= 2.6
Y(  4,1)= 5.9
X(  5,1)= 2.9
Y(  5,1)= 7.8
X(  6,1)= 3.2
Y(  6,1)= 9.8
X(  7,1)= 3.5
Y(  7,1)= 11.6
X(  8,1)= 3.62
Y(  8,1)= 12.6
X(  9,1)= 4.1
Y(  9,1)= 15.3
X( 10,1)= 4.9
Y( 10,1)= 18.8
X( 11,1)= 5.7
Y( 11,1)= 22.1
X( 12,1)= 6.2
Y( 12,1)= 24.0
X( 13,1)= 7.2
Y( 13,1)= 27.9
X( 14,1)= 8.3
Y( 14,1)= 31.2
X( 15,1)= 8.9
Y( 15,1)= 32.9
X( 16,1)= 9.9
Y( 16,1)= 35.8
X( 17,1)= 10.9
Y( 17,1)= 38.0
X( 18,1)= 13.1
Y( 18,1)= 42.9
X( 19,1)= 14.4
Y( 19,1)= 45
X( 20,1)= 15.2
Y( 20,1)= 46
/GOPR
/XRANGE,0,20
/YRANGE,0,60
/AXLAB,X,UY OF CENTER (IN)
/AXLAB,Y,PRESSURE (LB/SQ IN)
/COLOR,CURVE,YGRE
*VPLOT,X(1,1),Y(1,1)
/NOERASE
NSOL,2,1,U,Y,UY_1
PROD,7,1, , ,SH.%ET1%, , ,50,0,0,!MULTIPLY SOLUTION BY 50
/COLOR,CURVE,MRED
XVAR,2  		         !SPECIFY X VARIABLE TO BE DISPLAYED
PLVAR,7 		         !DISPLAY SOLUTION IN GRPH FILE
/ERASE
/OUT,
PRVAR,7,2		         !LIST VARIABLE 7 VERSUS VARIABLE 2
/OUT,SCRATCH
FINISH
/POST1
/NOPR
SET,NEAR,,,,0.08		 !SELECT UZ VALUE FOR NODE 1 AT T=0.08
*GET,VR1,NODE,1,U,Y
SET,NEAR,,,,0.48		 !UZ VALUE FOR NODE 1 AT T=0.48
*GET,VR2,NODE,1,U,Y
SET,NEAR,,,,0.76		 !UZ VALUE FOR NODE 1 AT T=0.76
*GET,VR3,NODE,1,U,Y
PRES1 = (0.08*50)		 !SOLVE FOR PRES IN RESULTS TABLE
PRES2 = (0.48*50)
PRES3 = (0.76*50)
*DIM,LABEL,,3			 !SETUP RESULTS TABLE DATA
*DIM,VALUE,,3,3
LABEL(1) = PRES1,PRES2,PRES3
*VFILL,VALUE(1,1),DATA,2.25,6.2,10.9
*VFILL,VALUE(1,2),DATA,VR1,VR2,VR3
*VFILL,VALUE(1,3),DATA,(VR1/2.25),(VR2/6.2),(VR3/10.9)
FINISH
*END
PLOTS
SAVE,TABLE_2
/CLEAR,NOSTART
/TITLE,VM218, HYPERELASTICITY TEST: BALLOON/CIRCULAR PLATE PROBLEM
/COM,         USING SHELL208 ELEMENTS
/PREP7
ET1 = 209
ET,1,SHELL209
THICK = 0.5
SECT,1,SHELL
SECD,THICK
TB,HYPER,1,,,MOONEY
TBDATA,1,80.0,20.0
N  ,     1 ,        0.,         0.
N  ,     2 ,   0.17143,         0.
N  ,     3 ,   0.47143,         0.
N  ,     4 ,   0.90000,         0.
N  ,     5 ,    1.4571,         0.
N  ,     6 ,    2.1429,         0.
N  ,     7 ,    2.9571,         0.
N  ,     8 ,    3.9000,         0.
N  ,     9 ,    4.9714,         0.
N  ,    10 ,    6.1714,         0.
N  ,    11 ,    7.5000,         0.
E,    1,       2
E,    2,       3
E,    3,       4
E,    4,       5
E,    5,       6
E,    6,       7
E,    7,       8
E,    8,       9
E,    9,      10
E,   10,      11
/OUT,SCRATCH
EMID,ADD  ! ADD MIDSIDE NODES FOR SHELL209
FINISH
SOLVEIT
PLOTS
SAVE,TABLE_3
/CLEAR,NOSTART
/TITLE,VM218, HYPERELASTICITY TEST: BALLOON/CIRCULAR PLATE PROBLEM
/COM,         USING SHELL281 ELEMENTS
/PREP7
TB,HYPER,1,,,MOONEY
TBDATA,1,80.0,20.0
ET,1,SHELL281
R,1,0.5,
CSYS,1
K,1,0,0,0
K,2,7.5,0,0
K,3,7.5,7.5
L,1,2
L,2,3
L,3,1
A,1,2,3
LESIZE,1, , ,20
LESIZE,2, , ,1
LESIZE,3, , ,20
AMESH,1
D,ALL,UY
D,ALL,ROTX
D,ALL,ROTZ
NSEL,S,LOC,X,0
D,ALL,ALL
DDELE,ALL,UZ
NSEL,S,LOC,X,7.5
D,ALL,UX
D,ALL,UY
D,ALL,UZ
ALLSEL,ALL
LOCAL, 11,1, 0.0,0.0,0.0,0,0.0,0.0
NROTAT,ALL
AUTOTS,ON
NSUBST, 400, 1200,25
NLGEOM,ON
NROPT,FULL, ,OFF
OUTRES, ALL, ALL,
SF,ALL,PRES,50.0
NEQITR,20
FINISH
/SOLUTION
/OUT,SCRATCH
SOLVE
FINISH
/POST1
/NOPR		   !SUPPRESS GRAPHING DATA
/VIEW,1,,-1
/ANG,1
/USER
/FOCUS,1,4,,8,0	   !SET UP CENTER OF GRAPHICS SCREEN FOR DISPLACEMENT PLOT
/DIST,,12	   !SET DISTANCE TO ZOOM OUT
/TRIAD,OFF
SET,FIRST	   !SET DISPLACEMENT DATA FOR FIRST SUBSTEP
PLDISP,0	   !PLOT DISPLACEMENT DATA
/NOERASE	   !SET DISPLAY TO OVERLAY PLOTS
SET,,10
PLDISP,0
SET,,20
PLDISP,0
SET,,25
PLDISP,0
SET,LAST
PLDISP,1	   !PLOT FINAL DISPLACEMENT WITH ORIGINAL POSITION
/ERASE
/TRIAD,ON
/GOPR
/ESHAPE,0
FINISH
/POST26
/XRANGE,0,3.0
/YRANGE,0,1
/AXLAB,X,UZ OF CENTER/R-INITIAL
/AXLAB,Y,THICKNESS/ORIGINAL THICKNESS
NSOL,2,1,U,Z,UZ_1
ESOL,3,1, ,SMIS,17,TH_1
ADD,4,2, , ,UZRATIO, , ,0.13333333,0,0,
ADD,5,3, , ,SH.281, , ,2,0,0,
/COLOR,CURVE,MRED
XVAR,4
PLVAR,5
/ERASE
/NOPR
*DIM,X,TABLE,20,1
*DIM,Y,TABLE,20,1
X(  1,1)= 1.25
Y(  1,1)= 1.25
X(  2,1)= 1.8
Y(  2,1)= 2.5
X(  3,1)= 2.25
Y(  3,1)= 4.0
X(  4,1)= 2.6
Y(  4,1)= 5.9
X(  5,1)= 2.9
Y(  5,1)= 7.8
X(  6,1)= 3.2
Y(  6,1)= 9.8
X(  7,1)= 3.5
Y(  7,1)= 11.6
X(  8,1)= 3.62
Y(  8,1)= 12.6
X(  9,1)= 4.1
Y(  9,1)= 15.3
X( 10,1)= 4.9
Y( 10,1)= 18.8
X( 11,1)= 5.7
Y( 11,1)= 22.1
X( 12,1)= 6.2
Y( 12,1)= 24.0
X( 13,1)= 7.2
Y( 13,1)= 27.9
X( 14,1)= 8.3
Y( 14,1)= 31.2
X( 15,1)= 8.9
Y( 15,1)= 32.9
X( 16,1)= 9.9
Y( 16,1)= 35.8
X( 17,1)= 10.9
Y( 17,1)= 38.0
X( 18,1)= 13.1
Y( 18,1)= 42.9
X( 19,1)= 14.4
Y( 19,1)= 45
X( 20,1)= 15.2
Y( 20,1)= 46
/GOPR
/XRANGE,0,20
/YRANGE,0,60
/AXLAB,X,UZ OF CENTER (IN)
/AXLAB,Y,PRESSURE (LB/SQ IN)
/COLOR,CURVE,YGRE
*VPLOT,X(1,1),Y(1,1)
/NOERASE
NSOL,2,1,U,Z,UZ_1
PROD,7,1, , ,SH.281 , , ,50,0,0,!MULTIPLY SOLUTION BY 50
/COLOR,CURVE,MRED
XVAR,2  		        !SPECIFY X VARIABLE TO BE DISPLAYED
PLVAR,7 		        !DISPLAY SOLUTION IN GRPH FILE
/ERASE
/OUT,
PRVAR,7,2		        !LIST VARIABLE 7 VERSUS VARIABLE 2
FINISH
/OUT,SCRATCH
/POST1
/NOPR
SET,NEAR,,,,0.08		!SELECT UZ VALUE FOR NODE 1 AT T=0.08
*GET,VR1,NODE,1,U,Z
SET,NEAR,,,,0.48		!UZ VALUE FOR NODE 1 AT T=0.48
*GET,VR2,NODE,1,U,Z
SET,NEAR,,,,0.76		!UZ VALUE FOR NODE 1 AT T=0.76
*GET,VR3,NODE,1,U,Z
PRES1 = (0.08*50)		!SOLVE FOR PRES IN RESULTS TABLE
PRES2 = (0.48*50)
PRES3 = (0.76*50)
*DIM,LABEL,,3			!SETUP RESULTS TABLE DATA
*DIM,VALUE,,3,3
LABEL(1) = PRES1,PRES2,PRES3
*VFILL,VALUE(1,1),DATA,2.25,6.2,10.9
*VFILL,VALUE(1,2),DATA,VR1,VR2,VR3
*VFILL,VALUE(1,3),DATA,(VR1/2.25),(VR2/6.2),(VR3/10.9)
FINISH
SAVE,TABLE_4
/COM
/OUT,vm218,vrt
RESUME,TABLE_1
/COM,============= VM218 RESULTS COMPARISON =============
/COM,
/COM,          |   TARGET   |   Mechanical APDL   |   RATIO
/COM,RESULTS USING SHELL181:
/COM,PRES = 
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,F8.1,'   ',F10.3,'  ',F14.3,'   ',1F15.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,RESULTS USING SHELL208:
/COM,PRES = 
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,F8.1,'   ',F10.3,'  ',F14.3,'   ',1F15.3)
/COM,
/NOPR
RESUME,TABLE_3
/GOPR
/COM,RESULTS USING SHELL209:
/COM,PRES = 
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,F8.1,'   ',F10.3,'  ',F14.3,'   ',1F15.3)
/COM,
/NOPR
RESUME,TABLE_4
/GOPR
/COM,RESULTS USING SHELL281:
/COM,PRES = 
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,F8.1,'   ',F10.3,'  ',F14.3,'   ',1F15.3)
/COM,
/COM,***VERIFIED RESULTS TABLE BASED ON GRAPHICAL DATA.
/COM,====================================================
/OUT
FINISH
*LIST,vm218,vrt
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
/DELETE,SOLVEIT,MAC
/DELETE,PLOTS,MAC