/COM,ANSYS MEDIA REL. 2026R1 (01/09/2026) REF. VERIF. MANUAL: REL. 2026R1
/VERIFY,VM324
/COM,
/COM,  REF: G. YANG, et al., "PRELIMINARY STUDY ON THE THERMAL-MECHANICAL
/COM,  PERFORMANCE OF THE U3SI2/AL DISPERSION FUEL PLATE UNDER NORMAL CONDITIONS.",
/COM,  NUCLEAR ENGINEERING AND TECHNOLOGY. 2021: VOL 53.
/COM,
/TITLE,VM324,SWELLING STRAIN OF A BLOCK WITH HIGH FLUENCE LOADING

/PREP7
swExp=0.001           ! swelling expansion
deltaFl=160           ! fluence change

block,0,1,0,1,0,1
ET,1,185              ! Element type; 185
keyopt,1,2,0
KEYOPT,1,6,0
MAT,1                 ! Material number for elements
ESIZE,1               ! Element size
VMESH,1               ! Mesh the volume

TB,HYPER,1,,,BOYCE    ! Activate Arruda-Boyce data table
TBDATA,1,50,5,0.001

TB,SWELL,1,,,LINEAR
TBDATA,1,swExp        ! Define swelling expansion

! Displacement constraints
NSEL,S,LOC,Y,0.
D,ALL,Uy,0.           ! Uy=0 on Y=0
NSEL,S,LOC,X,0
D,ALL,Ux,0
nsel,s,loc,z,0
d,all,uz,0
NSEL,S,LOC,Y,1.
D,ALL,Uy,0.           ! Uy=0 on Y=1
ALLSEL
FINISH

/SOLU
ANTYPE,0
NLGEOM,ON
time,1
OUTRES,ALL,LAST
nsubst,10,100,5
kbc,0

BF,ALL,FLUE,deltaFl   ! Define fluence loading

ALLSEL
SOLVE

FINISH

/POST1
SET,LAST
ETABLE,Swell,EPSW
*GET,Swell_ANSYS,ETAB,1,ELEM,1
*DIM,LABEL,CHAR,1,1
*DIM,TARGET,,1,1
*DIM,ANSYS,,1,1
*DIM,RATIO,,1,1
LABEL(1)='Swelling Strain'
ANSYS(1)=Swell_ANSYS
V=1.0*1.0*1.0
delV=(1+160*0.001)*(1+160*0.001)*(1+160*0.001)-V
TARGET(1)=log(1+delV/V)/3
RATIO(1)=ABS(ANSYS(1)/TARGET(1))

/OUT,vm324,vrt
/COM,------------------- VM324 RESULTS COMPARISON -------------------------
/COM,
/COM,                   |  TARGET  |   MAPDL   |  RATIO
/COM,
*VWRITE,LABEL(1,1),TARGET(1),ANSYS(1),RATIO(1)
(1X,A16,'    ',F9.5,'  ',F9.5, '    ',F6.3)
/COM,-----------------------------------------------------------------------
/OUT
*LIST,vm324,vrt
FINISH