/COM,ANSYS MEDIA REL. 2025R1 (11/08/2024) REF. VERIF. MANUAL: REL. 2025R1
/VERIFY,VM322
/COM, BARBIERI ETTORE, FEDERICA ONGARO, AND NICOLA MARIA PUGNO. "A J-INTEGRAL-BASED ARC-LENGTH
/COM, SOLVER FOR BRITTLE AND DUCTILE CRACK PROPAGATION IN FINITE DEFORMATION-FINITE STRAIN
/COM, HYPERELASTIC SOLIDS WITH AN APPLICATION TO GRAPHENE KIRIGAMI."
/COM, COMPUTER METHODS IN APPLIED MECHANICS AND ENGINEERING, 315 (2017): 713-743.
/COM,
/TITLE,VM322,J-INTEGRAL CALCULATION FOR CRACK IN FINITE DEFORMATION-FINITE STRAIN HYPERELASTIC SOLID
/COM,
/COM, PARAMETER FOR CREATING THE CDB FILES TO STORE GEOMETRY AND MESH DATA
/COM,
_GEOMGEN = 0 ! SET TO 1 TO WRITE CDB FILES IF ANY INPUT FILE MODIFICATIONS
PARSAV
C*** USING PLANE182 (FULL MODEL)
H0 = 25
LENGTH = 40*H0 ! LENGTH OF THE PLATE/STRIP (IN mm)
HEIGHT = 2*H0 ! HEIGHT OF THE PLATE/STRIP (IN mm)
CRKLEN = LENGTH/2 ! INITIAL CRACK LENGTH (IN mm)
/OUT,vm322_scratch
/PREP7
*IF,_GEOMGEN,EQ,1,THEN
ET,1,PLANE182 ! PLANE182
KEYOPT,1,3,3 ! PLANE STRESS WITH THICKNESS
R,1,1
TB,HYPER,1,,,NEO !ACTIVATE NEO-HOOKEAN DATA TABLE
TBDATA,1,0.4225 !DEFINE MU SHEAR MODULUS
TBDATA,2,7.0E-5 !DEFINE INCOMPRESSIBILITY PARAMETER
!(AS 2/K, K IS THE BULK MODULUS)
!---CREATE GEOMETRY
!---CREATE KEYPOINTS
K,1,0
K,2,-LENGTH/2,0
K,3,-LENGTH/2,HEIGHT/2
K,4,0,HEIGHT/2
K,5,LENGTH/2,HEIGHT/2
K,6,LENGTH/2,0
K,7,LENGTH/2,-HEIGHT/2
K,8,0,-HEIGHT/2
K,9,-LENGTH/2,-HEIGHT/2
K,10,-LENGTH/2,0
!---CREATE AREAS USING KEYPOINTS
A,1,2,3,4,
A,4,5,6,1
A,1,6,7,8
A,1,10,9,8
ALLSEL
!---CREATE MESH
ESIZE,1
AMESH,ALL
ALLSEL,ALL
!---SELECT CRACK TIP NODE
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0
CM,CRKTIP,NODES ! DEFINE THE CRACK TIP NODE COMPONENT
ALLSEL
! DEFINING CRACK-EXTENSION DIRECTION CALCULATION-ASSIST NODE
KSEL,S,,,2
NSLK,s
*GET,CASSIST,NODE,0,NUM,MAX
ALLSEL,ALL
cdwrite,db,vm322-1,cdb
FINISH
*ELSE
cdread,db,vm322-1,cdb
*ENDIF
FINISH
/SOLUTION
ANTYPE,STATIC !---SET ANALYSIS TYPE TO STATIC.
NLGEOM,ON !--- INCLUDES LARGE-DEFLECTION (LARGE ROTATION) EFFECTS OR LARGE STRAIN EFFECTS
NSUB,8,8,8
TIME,1
OUTRES,ALL,ALL
!---ASSIGN FIXED BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UX,0
ALLSEL
!---ASSIGN FIXED BC TO THE NODES AT BOTTOM FACE
NSEL,S,LOC,Y,-HEIGHT/2
D,ALL,UX,0
ALLSEL
!---ASSIGN DISPLACEMENT BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UY,20
ALLSEL
!---ASSIGN DISPLACEMENT BC TO THE NODES AT BOTTOM FACE
NSEL,S,LOC,Y,-HEIGHT/2
D,ALL,UY,-20
ALLSEL
!--- DEFINE CRACK ID 1 TO CALCULATE JINT
CINT,NEW,1 !---INITIATE CRACK ID 1.
CINT,TYPE,JINT !---COMPUTE J-INTEGRAL FOR CRACK ID 1.
CINT,CTNC,CRKTIP,CASSIST !---CASSIST IS THE CRACK TIP GUIDE NODE FOR THIS CRACK ID.
CINT,NORM,0,2 !---SET CRACK SURFACE NORMAL COORDINATE TO Y DIRECTION.
CINT,NCON,6 !---DEFINE 6 CONTOURS FOR CRACK TIP CALCULATIONS.
ALLSEL,ALL
SOLVE !---SOLVE THE MODEL.
FINISH
/POST1
! GET THE AVERAGE J-INT FOR ALL THE SUBSTEPS
*GET,NSET,ACTIVE,0,SET,NSET
*DIM,JINT_182,ARRAY,NSET,2
*DIM,STRETCH,ARRAY,NSET,1
*DO,II,1,NSET,1
SET,,,,,,,II
CRKNOD=NODE(0,0,0)
JINTS1=0
*DO,I,2,5
*GET,JINT1,CINT,1,CTIP,CRKNOD,CONTOUR,I,DTYPE,JINT
JINTS1=JINTS1+JINT1
*ENDDO
JINTS1=JINTS1/4
JINT_182(II,2) = JINTS1
*ENDDO
JINT_182(1,1) = 0.37
JINT_182(2,1) = 1.40
JINT_182(3,1) = 2.97
JINT_182(4,1) = 4.99
JINT_182(5,1) = 7.35
JINT_182(6,1) = 10.06
JINT_182(7,1) = 13.18
JINT_182(8,1) = 16.40
STRETCH(1,1) = 1.1
STRETCH(2,1) = 1.2
STRETCH(3,1) = 1.3
STRETCH(4,1) = 1.4
STRETCH(5,1) = 1.5
STRETCH(6,1) = 1.6
STRETCH(7,1) = 1.7
STRETCH(8,1) = 1.8
/OUT
/com, COMPARISON OF RESULTS AT DIFFERENT DISPLACEMENTS/STRETCH VALUES
/com, =========================================
/com, STRETCH JINT_REF JINT_MECHANICAL APDL
/com, =========================================
*vwrite,STRETCH(1,1),JINT_182(1,1),JINT_182(1,2)
(F10.2, ' ' F10.2, ' ' F10.2)
/com, =========================================
/OUT,vm322_scratch,,,APPEND
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1)='PLANE182'
*VFILL,VALUE(1,1),DATA,JINT_182(8,1)
*VFILL,VALUE(1,2),DATA,JINT_182(8,2)
*VFILL,VALUE(1,3),DATA,JINT_182(8,1)/JINT_182(8,2)
SAVE,TABLE_1
FINISH
/CLEAR,NOSTART
/OUT,
C*** USING PLANE183 (SYMMETRIC MODEL)
H0 = 25
LENGTH = 40*H0 ! LENGTH OF THE PLATE/STRIP
HEIGHT = 2*H0 ! HEIGHT OF THE PLATE/STRIP
CRKLEN = LENGTH/2 ! CRACK LENGTH
/OUT,vm322_scratch,,,APPEND
PARRES,CHANGE
/PREP7
*IF,_GEOMGEN,EQ,1,THEN
ET,1,PLANE183 ! PLANE183
KEYOPT,1,3,3 ! PLANE STRESS WITH THICKNESS
R,1,1
TB,HYPER,1,,,NEO !ACTIVATE NEO-HOOKEAN DATA TABLE
TBDATA,1,0.4225 !DEFINE MU SHEAR MODULUS
TBDATA,2,7.0E-5 !DEFINE INCOMPRESSIBILITY PARAMETER
!(AS 2/K, K IS THE BULK MODULUS)
!---CREATE GEOMETRY
!---CREATE KEYPOINTS
K,1,0
K,2,-LENGTH/2,0
K,3,-LENGTH/2,HEIGHT/2
K,4,0,HEIGHT/2
K,5,LENGTH/2,HEIGHT/2
K,6,LENGTH/2,0
!---CREATE AREAS USING KEYPOINTS
A,1,2,3,4,
A,4,5,6,1
ALLSEL
!---CREATE MESH
ESIZE,1
AMESH,ALL
ALLSEL,ALL
!---SELECT CRACK TIP NODE
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0
CM,CRKTIP,NODES ! DEFINE THE CRACK TIP NODE COMPONENT
ALLSEL
! DEFINING CRACK-EXTENSION DIRECTION CALCULATION-ASSIST NODE
KSEL,S,,,2
NSLK,s
*GET,CASSIST,NODE,0,NUM,MAX
ALLSEL,ALL
cdwrite,db,vm322-2,cdb
FINISH
*ELSE
cdread,db,vm322-2,cdb
*ENDIF
FINISH
/SOLUTION
ANTYPE,STATIC !---SET ANALYSIS TYPE TO STATIC.
NLGEOM,ON
NSUB,8,8,8
TIME,1
OUTRES,ALL,ALL
!---ASSIGN FIXED BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UX,0
ALLSEL
!---ASSIGN SYMMETRIC BC
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0,LENGTH/2
D,ALL,UY,0
ALLSEL
!---ASSIGN DISPLACEMENT BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UY,20
ALLSEL
!--- DEFINE CRACK ID 1 TO CALCULATE JINT
CINT,NEW,1 !---INITIATE CRACK ID 1.
CINT,TYPE,JINT !---COMPUTE J-INTEGRAL FOR CRACK ID 1.
CINT,CTNC,CRKTIP,CASSIST !---CASSIST IS THE CRACK TIP GUIDE NODE FOR THIS CRACK ID.
CINT,SYMM,ON !---SYMMETRIC ABOUT THE CRACK LINE/PLANE.
CINT,NORM,0,2 !---SET CRACK SURFACE NORMAL COORDINATE TO Y DIRECTION.
CINT,NCON,6 !---DEFINE 6 CONTOURS FOR CRACK TIP CALCULATIONS.
ALLSEL,ALL
SOLVE !---SOLVE THE MODEL.
FINISH
/POST1
! GET THE AVERAGE J-INT FOR ALL THE SUBSTEPS
*GET,NSET,ACTIVE,0,SET,NSET
*DIM,JINT_183,ARRAY,NSET,2
*DIM,STRETCH,ARRAY,NSET,1
*DO,II,1,NSET,1
SET,,,,,,,II
CRKNOD=NODE(0,0,0)
JINTS1=0
*DO,I,2,5
*GET,JINT1,CINT,1,CTIP,CRKNOD,CONTOUR,I,DTYPE,JINT
JINTS1=JINTS1+JINT1
*ENDDO
JINTS1=JINTS1/4
JINT_183(II,2) = JINTS1
*ENDDO
JINT_183(1,1) = 0.37
JINT_183(2,1) = 1.40
JINT_183(3,1) = 2.97
JINT_183(4,1) = 4.99
JINT_183(5,1) = 7.35
JINT_183(6,1) = 10.06
JINT_183(7,1) = 13.18
JINT_183(8,1) = 16.40
STRETCH(1,1) = 1.1
STRETCH(2,1) = 1.2
STRETCH(3,1) = 1.3
STRETCH(4,1) = 1.4
STRETCH(5,1) = 1.5
STRETCH(6,1) = 1.6
STRETCH(7,1) = 1.7
STRETCH(8,1) = 1.8
/out
/com, COMPARISON OF RESULTS AT DIFFERENT DISPLACEMENTS/STRETCH VALUES
/com, =========================================
/com, STRETCH JINT_REF JINT_MECHANICAL APDL
/com, =========================================
*vwrite,STRETCH(1,1),JINT_183(1,1),JINT_183(1,2)
(F10.2, ' ' F10.2, ' ' F10.2)
/com, =========================================
/OUT,vm322_scratch,,,APPEND
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1)='PLANE183'
*VFILL,VALUE(1,1),DATA,JINT_183(8,1)
*VFILL,VALUE(1,2),DATA,JINT_183(8,2)
*VFILL,VALUE(1,3),DATA,JINT_183(8,1)/JINT_183(8,2)
SAVE,TABLE_2
FINISH
/CLEAR,NOSTART
/OUT,
C*** USING SOLID185 (SYMMETRIC MODEL)
H0 = 25
LENGTH = 40*H0 ! LENGTH OF THE PLATE/STRIP
HEIGHT = 2*H0 ! HEIGHT OF THE PLATE/STRIP
CRKLEN = LENGTH/2 ! CRACK LENGTH
THICK = 1 ! THICKNESS
/OUT,vm322_scratch,,,APPEND
PARRES,CHANGE
/PREP7
*IF,_GEOMGEN,EQ,1,THEN
ET,1,SOLID185 ! SOLID185
KEYOPT,1,6,1 ! USE MIXED U-P FORMULATION
TB,HYPER,1,,,NEO !ACTIVATE NEO-HOOKEAN DATA TABLE
TBDATA,1,0.4225 !DEFINE MU SHEAR MODULUS
TBDATA,2,7.0E-5 !DEFINE INCOMPRESSIBILITY PARAMETER
!(AS 2/K, K IS THE BULK MODULUS)
!---CREATE GEOMETRY
!---CREATE KEYPOINTS
K,1,0
K,2,-LENGTH/2,0
K,3,-LENGTH/2,HEIGHT/2
K,4,0,HEIGHT/2
K,5,LENGTH/2,HEIGHT/2
K,6,LENGTH/2,0
!---CREATE AREAS USING KEYPOINTS
A,1,2,3,4,
A,4,5,6,1
ALLSEL
VEXT,ALL,,,,,THICK !---EXTRUDE AREAS TO CREATE VOLUME.
!---CREATE MESH
ESIZE,1
VSWEEP,ALL
ALLSEL,ALL
!---SELECT CRACK TIP NODE
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0
CM,CRKTIP,NODES ! DEFINE THE CRACK TIP NODE COMPONENT
ALLSEL
! DEFINING CRACK-EXTENSION DIRECTION CALCULATION-ASSIST NODE
KSEL,S,,,2
NSLK,s
*GET,CASSIST,NODE,0,NUM,MAX
ALLSEL,ALL
cdwrite,db,vm322-3,cdb
FINISH
*ELSE
cdread,db,vm322-3,cdb
*ENDIF
FINISH
/SOLUTION
ANTYPE,STATIC !---SET ANALYSIS TYPE TO STATIC.
NLGEOM,ON
NSUB,8,1000,8
TIME,1
OUTRES,ALL,ALL
!---ASSIGN FIXED BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UX,0
D,ALL,UZ,0
ALLSEL
!---ASSIGN SYMMETRIC BC
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0,LENGTH/2
D,ALL,UY,0
ALLSEL
!---ASSIGN DISPLACEMENT BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UY,20
ALLSEL
!--- DEFINE CRACK ID 1 TO CALCULATE JINT
CINT,NEW,1 !---INITIATE CRACK ID 1.
CINT,TYPE,JINT !---COMPUTE J-INTEGRAL FOR CRACK ID 1.
CINT,CTNC,CRKTIP,CASSIST !---CASSIST IS THE CRACK TIP GUIDE NODE FOR THIS CRACK ID.
CINT,SYMM,ON !---SYMMETRIC ABOUT THE CRACK LINE/PLANE.
CINT,NORM,0,2 !---SET CRACK SURFACE NORMAL COORDINATE TO Y DIRECTION.
CINT,NCON,6 !---DEFINE 6 CONTOURS FOR CRACK TIP CALCULATIONS.
ALLSEL,ALL
SOLVE !---SOLVE THE MODEL.
FINISH
/POST1
! GET THE AVERAGE J-INT FOR ALL THE SUBSTEPS
*GET,NSET,ACTIVE,0,SET,NSET
*DIM,JINT_185,ARRAY,NSET,2
*DIM,STRETCH,ARRAY,NSET,1
*DO,II,1,NSET,1
SET,,,,,,,II
CRKNOD=NODE(0,0,0)
JINTS1=0
*DO,I,2,5
*GET,JINT1,CINT,1,CTIP,CRKNOD,CONTOUR,I,DTYPE,JINT
JINTS1=JINTS1+JINT1
*ENDDO
JINTS1=JINTS1/4
JINT_185(II,2) = JINTS1
*ENDDO
JINT_185(1,1) = 0.37
JINT_185(2,1) = 1.40
JINT_185(3,1) = 2.97
JINT_185(4,1) = 4.99
JINT_185(5,1) = 7.35
JINT_185(6,1) = 10.06
JINT_185(7,1) = 13.18
JINT_185(8,1) = 16.40
STRETCH(1,1) = 1.1
STRETCH(2,1) = 1.2
STRETCH(3,1) = 1.3
STRETCH(4,1) = 1.4
STRETCH(5,1) = 1.5
STRETCH(6,1) = 1.6
STRETCH(7,1) = 1.7
STRETCH(8,1) = 1.8
/out
/com, COMPARISON OF RESULTS AT DIFFERENT DISPLACEMENTS/STRETCH VALUES
/com, ==========================================
/com, STRETCH JINT_REF JINT_MECHANICAL APDL
/com, ==========================================
*vwrite,STRETCH(1,1),JINT_185(1,1),JINT_185(1,2)
(F10.2, ' ' F10.2, ' ' F10.2)
/com, ==========================================
/OUT,vm322_scratch,,,APPEND
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1)='SOLID185'
*VFILL,VALUE(1,1),DATA,JINT_185(8,1)
*VFILL,VALUE(1,2),DATA,JINT_185(8,2)
*VFILL,VALUE(1,3),DATA,JINT_185(8,1)/JINT_185(8,2)
SAVE,TABLE_3
FINISH
/CLEAR,NOSTART
/OUT,
C*** USING SOLID186 (SYMMETRIC MODEL)
H0 = 25
LENGTH = 40*H0 ! LENGTH OF THE PLATE/STRIP
HEIGHT = 2*H0 ! HEIGHT OF THE PLATE/STRIP
CRKLEN = LENGTH/2 ! CRACK LENGTH
THICK = 1 ! THICKNESS
/OUT,vm322_scratch,,,APPEND
PARRES,CHANGE
/PREP7
*IF,_GEOMGEN,EQ,1,THEN
ET,1,SOLID186 ! SOLID186
KEYOPT,1,6,1 ! USE MIXED U-P FORMULATION
TB,HYPER,1,,,NEO !ACTIVATE NEO-HOOKEAN DATA TABLE
TBDATA,1,0.4225 !DEFINE MU SHEAR MODULUS
TBDATA,2,7.0E-5 !DEFINE INCOMPRESSIBILITY PARAMETER
!(AS 2/K, K IS THE BULK MODULUS)
!---CREATE GEOMETRY
!---CREATE KEYPOINTS
K,1,0
K,2,-LENGTH/2,0
K,3,-LENGTH/2,HEIGHT/2
K,4,0,HEIGHT/2
K,5,LENGTH/2,HEIGHT/2
K,6,LENGTH/2,0
!---CREATE AREAS USING KEYPOINTS
A,1,2,3,4,
A,4,5,6,1
ALLSEL
VEXT,ALL,,,,,THICK !---EXTRUDE AREAS TO CREATE VOLUME.
!---CREATE MESH
ESIZE,1
VSWEEP,ALL
ALLSEL,ALL
!---SELECT CRACK TIP NODE
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0
CM,CRKTIP,NODES ! DEFINE THE CRACK TIP NODE COMPONENT
ALLSEL
! DEFINING CRACK-EXTENSION DIRECTION CALCULATION-ASSIST NODE
KSEL,S,,,2
NSLK,s
*GET,CASSIST,NODE,0,NUM,MAX
ALLSEL,ALL
cdwrite,db,vm322-4,cdb
FINISH
*ELSE
cdread,db,vm322-4,cdb
*ENDIF
FINISH
/SOLUTION
ANTYPE,STATIC !---SET ANALYSIS TYPE TO STATIC.
NLGEOM,ON
NSUB,8,1000,8
TIME,1
OUTRES,ALL,ALL
!---ASSIGN FIXED BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UX,0
D,ALL,UZ,0
ALLSEL
!---ASSIGN SYMMETRIC BC
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,0,LENGTH/2
D,ALL,UY,0
ALLSEL
!---ASSIGN DISPLACEMENT BC TO THE NODES AT TOP FACE
NSEL,S,LOC,Y,HEIGHT/2
D,ALL,UY,20
ALLSEL
!--- DEFINE CRACK ID 1 TO CALCULATE JINT
CINT,NEW,1 !---INITIATE CRACK ID 1.
CINT,TYPE,JINT !---COMPUTE J-INTEGRAL FOR CRACK ID 1.
CINT,CTNC,CRKTIP,CASSIST !---CASSIST IS THE CRACK TIP GUIDE NODE FOR THIS CRACK ID.
CINT,SYMM,ON !---SYMMETRIC ABOUT THE CRACK LINE/PLANE.
CINT,NORM,0,2 !---SET CRACK SURFACE NORMAL COORDINATE TO Y DIRECTION.
CINT,NCON,6 !---DEFINE 6 CONTOURS FOR CRACK TIP CALCULATIONS.
ALLSEL,ALL
SOLVE !---SOLVE THE MODEL.
FINISH
/POST1
! GET THE AVERAGE J-INT FOR ALL THE SUBSTEPS
*GET,NSET,ACTIVE,0,SET,NSET
*DIM,JINT_186,ARRAY,NSET,2
*DIM,STRETCH,ARRAY,NSET,1
*DO,II,1,NSET,1
SET,,,,,,,II
CRKNOD=NODE(0,0,THICK/2)
JINTS1=0
*DO,I,2,5
*GET,JINT1,CINT,1,CTIP,CRKNOD,CONTOUR,I,DTYPE,JINT
JINTS1=JINTS1+JINT1
*ENDDO
JINTS1=JINTS1/4
JINT_186(II,2) = JINTS1
*ENDDO
JINT_186(1,1) = 0.37
JINT_186(2,1) = 1.40
JINT_186(3,1) = 2.97
JINT_186(4,1) = 4.99
JINT_186(5,1) = 7.35
JINT_186(6,1) = 10.06
JINT_186(7,1) = 13.18
JINT_186(8,1) = 16.40
STRETCH(1,1) = 1.1
STRETCH(2,1) = 1.2
STRETCH(3,1) = 1.3
STRETCH(4,1) = 1.4
STRETCH(5,1) = 1.5
STRETCH(6,1) = 1.6
STRETCH(7,1) = 1.7
STRETCH(8,1) = 1.8
/out
/com, COMPARISON OF RESULTS AT DIFFERENT DISPLACEMENTS/STRETCH VALUES
/com, =========================================
/com, STRETCH JINT_REF JINT_MECHANICAL APDL
/com, =========================================
*vwrite,STRETCH(1,1),JINT_186(1,1),JINT_186(1,2)
(F10.2, ' ' F10.2, ' ' F10.2)
/com, ==========================================
/OUT,vm322_scratch,,,APPEND
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1)='SOLID186'
*VFILL,VALUE(1,1),DATA,JINT_186(8,1)
*VFILL,VALUE(1,2),DATA,JINT_186(8,2)
*VFILL,VALUE(1,3),DATA,JINT_186(8,1)/JINT_186(8,2)
SAVE,TABLE_4
FINISH
RESUME,TABLE_1
/out,vm322,vrt
/COM,=============================================================================
/COM, ---------------------------VM322 RESULTS COMPARISON ------------------------
/COM,=============================================================================
/COM,
/COM, | TARGET | Mechanical APDL | RATIO
/COM,
/COM, USING PLANE182 ELEMENTS (FULL MODEL)
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A14,' ',F10.2,' ',F10.2,' ',F10.3)
/COM,
/COM,
/NOPR,
RESUME,TABLE_2
/GOPR,
/COM,
/COM,
/COM, USING PLANE183 ELEMENTS (SYMMETRIC MODEL)
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A14,' ',F10.2,' ',F10.2,' ',F10.3)
/COM,
/COM,
/NOPR,
RESUME,TABLE_3
/GOPR,
/COM,
/COM,
/COM, USING SOLID185 ELEMENTS (SYMMETRIC MODEL)
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A14,' ',F10.2,' ',F10.2,' ',F10.3)
/COM,
/COM,
/NOPR,
RESUME,TABLE_4
/GOPR,
/COM,
/COM,
/COM, USING SOLID186 ELEMENTS (SYMMETRIC MODEL)
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A14,' ',F10.2,' ',F10.2,' ',F10.3)
/COM,
/COM,
/out,
*list,vm322,vrt
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
