This sample problem demonstrates the use of FLUID220 to predict the sound wave reflection due to the existence of an unsymmetric 2×2 admittance matrix. The transfer admittance matrix is defined as:

Both ports of the 2 x 2 network are connected to the fluid.

The sound wave characteristic impedance is Z₀ = 417.45 N⋅s/m³.

In terms of the network theory, the reflection coefficients are 0.15 and 0.20 at port 1 and port 2, respectively.

/batch,list
/title, Transfer Admittance Matrix in the Fluid
/nopr
/prep7
pi=acos(-1)
k=8*pi                        ! wave number
rho0 = 1.21                   ! mass density
c0 = 345                      ! sound speed
freq = k*344/(2*pi)           ! working frequency
wavelen = 2*pi/k              ! wavelength

                              ! structure dimensions
h = wavelen/12                ! mesh size
d = 2*h
l = 0.75*wavelen
z1 = l/2
z2 = z1+0.05*h
z3 = z2+l/2

                              ! define elements and material
et,1,220,,1
mp,dens,1,rho0
mp,sonc,1,c0
mp,dens,2,rho0
mp,sonc,2,c0
                              ! set transfer admittance matrix parameters
y11r=0.634852E-02             ! Re(Y11)
y11i=0.                       ! Im(Y11)
y12r=-0.437959E-02            ! Re(Y12)
y12i=0.437959E-02             ! Im(Y12)
y21r=-0.437959E-02            ! Re(Y21)
y21i=-0.437959E-02            ! Im(Y21)
y22r=0.598419E-02             ! Re(Y22)
y22i=0.                       ! Im(Y22)
                              ! define transfer admittance matrix
tbdel,perf,2
tb,perf,2,,,YMAT
tbdata,1,y11r,y11i,y12r,y12i,y21r,y21i
tbdata,7,y22r,y22i
tblist,perf,2
                              ! define normal velocity
pa=1
z0=rho0*c0
un=-pa/z0
                              ! create model
block,-d/2,0,-d/2,d/2,0,z1
block,-d/2,0,-d/2,d/2,z1,z2
block,-d/2,0,-d/2,d/2,z2,z3
vglue,all
mshape,0,3d
esize,h
type,1
mat,1
vsel,s,loc,z,0,z1
vsel,a,loc,z,z2,z3
vmesh,all                     ! mesh with normal material
type,1
mat,2
vsel,s,loc,z,z1,z2
vmesh,all                     ! mesh with admittance matrix

                              ! define ports for admittance matrix
esel,s,mat,,2
nsle,s
nsel,s,loc,z,z1
sf,all,port,1                 ! port 1 of 2-port network
nsel,s,loc,z,z2
sf,all,port,2                 ! port 2 of 2-port network
alls

                              ! define boundary condition
nsel,s,loc,z,z3
sf,all,impd,z0                ! matched outlet

                              ! excitation at transparent port
nsel,s,loc,z,0 
sf,all,shld,un                ! normal velocity excitation
sf,all,impd,z0                ! matched inlet
sf,all,port,10                ! transparent port
alls
fini

                              ! perform solution
/solu
antype,harmic
hropt,auto
harfrq,freq
solve
fini
                              ! post-processing
/post1
nsel,s,loc,z,0
nsel,r,loc,x,0
nsel,r,loc,y,-d/2
nod=0
node=ndnext(nod)

set,,,,,,,1                   ! real solution
*get,frq,active,0,set,freq
pr=pres(node)
set,,,,,,,2                   ! imaginary solution
pi=pres(node)
ref=sqrt((pa-pr)**2+pi**2)/pa
/com,
/com,***** Computed Reflection Coefficient *****
/com,
*vwrite,
 ('  Frequency           Computed |R|')
*vwrite,frq,ref
 (1x,e14.7,6x,e14.7)
fini