/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-pl3a-186
/TITLE, vmr049-pl3a-186, 3D PLASTICITY BENCHMARK
/COM, REFERENCE: NAFEMS REPORT: R0049, PL-3

/PREP7
R = 2.5E-5
ET,1,186
N, 1, 0.0, 0.0, 0.0
N, 2, 0.0, 0.5, 0.0
N, 3, 0.0, 1.0, 0.0
N, 4, 0.5, 0.0, 0.0
N, 5, 0.5, 1.0, 0.0
N, 6, 1.0, 0.0, 0.0
N, 7, 1.0, 0.5, 0.0
N, 8, 1.0, 1.0, 0.0
N, 9, 0.0, 0.0, 1.0
N,10, 0.0, 0.5, 1.0
N,11, 0.0, 1.0, 1.0
N,12, 0.5, 0.0, 1.0
N,13, 0.5, 1.0, 1.0
N,14, 1.0, 0.0, 1.0
N,15, 1.0, 0.5, 1.0
N,16, 1.0, 1.0, 1.0
N,17, 0.0, 0.0, 0.5
N,18, 1.0, 0.0, 0.5
N,19, 1.0, 1.0, 0.5
N,20, 0.0, 1.0, 0.5
E,1,6,8,3,9,14,16,11
EMORE,4,7,5,2,12,15,13,10
EMORE,17,18,19,20
MP,EX,1,250.0E3
MP,NUXY,1,0.25
TB,PLAS,1,,,BISO
TBDATA,1,5,0
TB,HILL,1		
TBDATA,1,1.0,1.0,1.0,1.0,1.0,1.0
NSEL,S,LOC,X		
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,S,LOC,Y,1.0
D,ALL,UY
NSEL,S,LOC,Z
D,ALL,UZ
NSEL,S,LOC,Z,1.0
D,ALL,UZ
FINISH

/SOLU
NLGEOM,ON  		
NSEL,S,LOC,X,1.0
D,ALL,UX,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
/OUT,SCRATCH
SOLVE
NSEL,S,LOC,X,1.0	
D,ALL,UX,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0	
D,ALL,UY,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0	
D,ALL,UY,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Z,1.0	
D,ALL,UZ,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Z,1.0	
D,ALL,UZ,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,X,1.0	
D,ALL,UX,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,X,1.0	
D,ALL,UX,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0	
D,ALL,UY,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0	
D,ALL,UY,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Z,1.0	
D,ALL,UZ,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Z,1.0	
D,ALL,UZ,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
FINISH

/POST26
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/AXLAB,X,STEP
/AXLAB,Y,STRESS
/GTHK,AXIS,1
/GRTYP,0
/XRANGE,0,13
/YRANGE,-10,30
/OUT,
ESOL,2,1,16,S,X,
ESOL,3,1,16,S,Y,
ESOL,4,1,16,S,Z,
ESOL,5,1,16,S,EQV,
PRVAR,2,3,4,5
PLVAR,2,3,4,5

*DIM,V,ARRAY,24
*DIM,VALUEX,ARRAY,5
*DO,JJ,1.0,24,3
*GET,V(JJ),VARI,2,RTIME,JJ
*ENDDO
*VFILL,VALUEX,DATA,V(1),V(4),V(7),V(10),V(13)
R1=VALUEX(1)/7.499
R2=VALUEX(2)/16.365
R3=VALUEX(3)/17.595
R4=VALUEX(4)/8.710
R5=VALUEX(5)/2.747

*DIM,V2,ARRAY,24
*DIM,VALUEY,ARRAY,5
*DO,JJ,1.0,24,3
*GET,V2(JJ),VARI,3,RTIME,JJ
*ENDDO
*VFILL,VALUEY,DATA,V2(1),V2(4),V2(7),V2(10),V2(13)
R6=VALUEY(1)/2.500
R7=VALUEY(2)/19.692
R8=VALUEY(3)/21.766
R9=VALUEY(4)/5.277
R10=VALUEY(5)/0.262

*DIM,V3,ARRAY,24
*DIM,VALUEZ,ARRAY,5
*DO,JJ,1.0,24,3
*GET,V3(JJ),VARI,4,RTIME,JJ
*ENDDO
*VFILL,VALUEZ,DATA,V3(1),V3(4),V3(7),V3(10),V3(13)
R11=VALUEZ(1)/2.500
R12=VALUEZ(2)/13.942
R13=VALUEZ(3)/23.138
R14=VALUEZ(4)/11.013
R15=VALUEZ(5)/(-3.009)

*DIM,V4,ARRAY,24
*DIM,VALUEEF,ARRAY,5
*DO,JJ,1.0,24,3
*GET,V4(JJ),VARI,5,RTIME,JJ
*ENDDO
*VFILL,VALUEEF,DATA,V4(1),V4(4),V4(7),V4(10),V4(13)
R16=VALUEEF(1)/5.000
R17=VALUEEF(2)/5.000
R18=VALUEEF(3)/5.000
R19=VALUEEF(4)/5.000
R20=VALUEEF(5)/5.000

*DIM,STEP,CHAR,10
*DIM,TARGETX,CHAR,10
*DIM,TARGETY,CHAR,10
*DIM,TARGETZ,CHAR,10
*DIM,TARGETEF,CHAR,10
*DIM,RATIOX,,5,1
*DIM,RATIOY,,5,1
*DIM,RATIOZ,,5,1
*DIM,RATIOEF,,5,1
STEP(1)='1.0','4.0','7.0','10.0','13.0'
TARGETX(1)='7.500','16.365','17.595','8.710','2.747'
TARGETY(1)='2.500','19.692','21.766','5.277','0.262'
TARGETZ(1)='2.500','13.942','23.138','11.013','-3.009'
TARGETEF(1)='5.000','5.000','5.000','5.000','5.000'
*VFILL,RATIOX,DATA,R1,R2,R3,R4,R5
*VFILL,RATIOY,DATA,R6,R7,R8,R9,R10
*VFILL,RATIOZ,DATA,R11,R12,R13,R14,R15
*VFILL,RATIOEF,DATA,R16,R17,R18,R19,R20
/COM,
/COM, ----------- vmr049-pl3a-186 RESULTS COMPARISON --------------
/COM,
/COM, vmr049-pl3a-186.jpeg RESULTS SHOULD MATCH R0049 NAFEMS MANUAL
/COM, GRAPH RESULTS ON PAGE 55, FIGURE 2.17(A).  THE RESULTS
/COM, DISPLAYED ARE INCREMENTED FOR THIS PURPOSE.
/COM,
/COM,
/COM, ------ vmr049-pl3a-186 STRESS RESULTS IN X DIRECTION -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETX(1),VALUEX(1,1),RATIOX(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM, ------ vmr049-pl3a-186 STRESS RESULTS IN Y DIRECTION -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETY(1),VALUEY(1,1),RATIOY(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
/COM, ------ vmr049-pl3a-186 STRESS RESULTS IN Z DIRECTION -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETZ(1),VALUEZ(1,1),RATIOZ(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
/COM, ------ vmr049-pl3a-186 EFFECTIVE STRESS RESULTS -------
/COM,
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO
/COM,
*VWRITE,STEP(1),TARGETEF(1),VALUEEF(1,1),RATIOEF(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
FINISH

*DIM,LABEL1,CHAR,4
*DIM,VALUE1,,4,3
LABEL1(1) = ' SX ',' SY ',' SZ ',' SEFF '
*VFILL,VALUE1(1,1),DATA,VALUEX(5),VALUEY(5),VALUEZ(5),VALUEEF(5)
*VFILL,VALUE1(1,2),DATA,R5,R10,R15,R20
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr049-','pl3a-186'

/OUT,vmr049-pl3a-186,vrt
/COM
/COM,------------------- vmr049-pl3a RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SOLID186
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(3),VALUE1(3,1),VALUE1(3,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(4),VALUE1(4,1),VALUE1(4,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmr049-pl3a-186,vrt