/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-pl1b-183
/TITLE, vmr049-pl1b-183,2D PLANE STRAIN PLASTICITY BENCHMARK
/COM,REFERENCE: NAFEMS REPORT, PL-1, R0049.

/PREP7
R = 2.5E-5
ET,1,183,,,
KEYOPT,1,3,2   	
N,1,,,,
N,2,0.0,0.5,,
N,3,0.0,1.0,,
N,4,0.5,0.0,,
N,5,0.5,1.0,,
N,6,1.0,0.0,,
N,7,1.0,0.5,,
N,8,1.0,1.0,,
E,1,6,8,3,4,7,5,2
MP,EX,1,250E3,
MP,NUXY,1,0.25,
EX=250E3
ET=50E3
EP=EX*ET/(EX-ET)
TB,PLAS,1,,,BISO
TBDATA,1,5,EP
TB,HILL,1	
TBDATA,1,1.0,1.0,1.0,1.0,1.0,1.0
NSEL,S,LOC,X	
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,S,LOC,Y,1.0
D,ALL,UY
FINISH

/SOLU
NLGEOM,ON
NSEL,S,LOC,X,1.0
D,ALL,UX,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
/OUT,SCRATCH
SOLVE
NSEL,S,LOC,X,1.0
D,ALL,UX,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,2*R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,X,1.0
D,ALL,UX,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,X,1.0
D,ALL,UX,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,R
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
NSEL,S,LOC,Y,1.0
D,ALL,UY,0.0
NSEL,ALL
NSUBST,10,10,10,
OUTRES,ALL,5
SOLVE
FINISH

/POST26
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/AXLAB,X,STEP
/AXLAB,Y,STRESS
/GTHK,AXIS,1
/GRTYP,0
/XRANGE,0,8
/YRANGE,-5,25
/OUT,
ESOL,2,1,8,S,X,
ESOL,3,1,8,S,Y,
ESOL,4,1,8,S,Z,
ESOL,5,1,8,S,EQV,
PLVAR,2,3,4,5
PRVAR,2,3,4,5

*DIM,VALUEX,ARRAY,8,1
*DO,JJ,1,8,1
*GET,VALUEX(JJ,1),VARI,2,RTIME,JJ
*ENDDO
R1=VALUEX(1,1)/7.500
R2=VALUEX(2,1)/12.241
R3=VALUEX(3,1)/14.741
R4=VALUEX(4,1)/16.938
R5=VALUEX(5,1)/9.845
R6=VALUEX(6,1)/4.052
R7=VALUEX(7,1)/1.552
R8=VALUEX(8,1)/0.324
*DIM,VALUEY,ARRAY,8,1
*DO,JJ,1,8,1
*GET,VALUEY(JJ,1),VARI,3,RTIME,JJ
*ENDDO
R9=VALUEY(1,1)/2.500
R10=VALUEY(2,1)/6.379
R11=VALUEY(3,1)/13.879
R12=VALUEY(4,1)/20.193
R13=VALUEY(5,1)/16.877
R14=VALUEY(6,1)/12.452
R15=VALUEY(7,1)/4.953
R16=VALUEY(8,1)/1.441
*DIM,VALUEZ,ARRAY,8,1
*DO,JJ,1,8,1
*GET,VALUEZ(JJ,1),VARI,4,RTIME,JJ
*ENDDO
R17=VALUEZ(1,1)/2.500
R18=VALUEZ(2,1)/6.379
R19=VALUEZ(3,1)/8.879
R20=VALUEZ(4,1)/12.867
R21=VALUEZ(5,1)/10.777
R22=VALUEZ(6,1)/8.495
R23=VALUEZ(7,1)/5.995
R24=VALUEZ(8,1)/4.615
*DIM,TIME,CHAR,10
*DIM,TARGETX,CHAR,10
*DIM,TARGETY,CHAR,10
*DIM,TARGETZ,CHAR,10
*DIM,RATIOX,,8,1
*DIM,RATIOY,,8,1
*DIM,RATIOZ,,8,1
TIME(1)='1.0','2.0','3.0','4.0','5.0','6.0','7.0','8.0'
TARGETX(1)='7.500','12.241','14.741','16.938','9.845','4.052','1.552','0.324'
TARGETY(1)='2.500','6.379','13.879','20.193','16.877','12.452','4.953','1.441'
TARGETZ(1)='2.500','6.379','8.879','12.867','10.777','8.495','5.995','4.615'
*VFILL,RATIOX,DATA,R1,R2,R3,R4,R5,R6,R7,R8
*VFILL,RATIOY,DATA,R9,R10,R11,R12,R13,R14,R15,R16
*VFILL,RATIOZ,DATA,R17,R18,R19,R20,R21,R22,R23,R24
/COM,
/COM, ----------- vmr049-pl1b-183 RESULTS COMPARISON -------------- 
/COM, 
/COM, vmr049-pl1b-183.jpeg RESULTS SHOULD MATCH R0049 NAFEMS MANUAL 
/COM, GRAPH RESULTS.  THE RESULTS DISPLAYED ARE INCREMENTED 
/COM, FOR THIS PURPOSE.
/COM,
/COM,
/COM, ------ vmr049-pl1b-183 STRESS RESULTS IN X DIRECTION ------- 
/COM, 
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO 
/COM,
*VWRITE,TIME(1),TARGETX(1),VALUEX(1,1),RATIOX(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM, ------ vmr049-pl1b-183 STRESS RESULTS IN Y DIRECTION ------- 
/COM, 
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO 
/COM,
*VWRITE,TIME(1),TARGETY(1),VALUEY(1,1),RATIOY(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
/COM, ------ vmr049-pl1b-183 STRESS RESULTS IN Z DIRECTION ------- 
/COM, 
/COM, |  STEP  |  TARGET  |  Mechanical APDL  |  RATIO 
/COM,
*VWRITE,TIME(1),TARGETZ(1),VALUEZ(1,1),RATIOZ(1,1)
(1X,A8,'   ',1x,A8,'   ',F14.3,'   ',F12.3,'   ')
/COM,
/COM,
FINISH

*DIM,LABEL1,CHAR,3
*DIM,VALUE1,,3,3
LABEL1(1) = ' SX ',' SY ',' SZ '
*VFILL,VALUE1(1,1),DATA,VALUEX(7,1),VALUEY(7,1),VALUEZ(7,1)
*VFILL,VALUE1(1,2),DATA,R7,R15,R23
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr049-','pl1b-183'

/OUT,vmr049-pl1b-183,vrt
/COM
/COM,------------------- vmr049-pl1b RESULTS COMPARISON --------------------- 
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, PLANE183
/COM, RESULTS REPORTED USING LOAD STEP 7
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(3),VALUE1(3,1),VALUE1(3,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmr049-pl1b-183,vrt