/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-cr2-182
/TITLE,vmr049-cr2-182,CONSTANT-DISPLACEMENT CREEP BENCHMARK
/COM TEST CASE REFERENCED FROM ROO49 NAFEMS MANUAL,
/COM TEST CR-2:  CONSTANT-DISPLACEMENT CREEP BENCHMARK

/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANTS (TIME HARDENING)!***
*SET,C1,1.5625E-14
*SET,C2,5.0
*SET,C3,-0.5
*SET,C4,0
C***  TIME PARAMETER
*SET,HOUR,1000
C***   ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,HOT
TOFF,OFFS
TB,CREEP,1,,,6
TBDATA,1,C1,C2,C3,C4
C*** PARAMETRIC INPUT FOR CREEP CONSTANTS (STRAIN HARDENING)!***
*SET,C1,1.5625E-14
*SET,C2,5
*SET,C3,-0.5
MP,EX,2,200E3
MP,NUXY,2,0.3
TB,CREEP,2,,,7
TBDATA,1,C1,C2,C3
N,1
N,2,100
N,3,100,100
N,4,0,100
ET,1,182,1,,
E,1,2,3,4
NSEL,ALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,S,LOC,X,100
D,ALL,UX,0.1
NSEL,S,LOC,Y,100
D,ALL,UY,0.1
NSEL,ALL
*DO,I,1,2
*STATUS,I
/PREP7
*IF,I,EQ,1,THEN
MAT,1
*ELSEIF,I,EQ,2,THEN
MPCHG,2,ALL
*ENDIF
FINISH

/SOLU
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUTPUT,SCRATCH
OUTRES,ALL,LAST
SOLVE
/OUT
RATE, ON
DELT,0.10,0.099,0.10
TIME, 0.10
/OUTPUT,SCRATCH
OUTRES,ALL,LAST
SOLVE
/OUT
RATE, ON
DELT,1.0,0.99,1.0
TIME, 1.0
/OUTPUT,SCRATCH
OUTRES,ALL,LAST
SOLVE
/OUT
RATE, ON
DELT,5.0,4.99,5.0
TIME, 5.0
/OUTPUT,SCRATCH
OUTRES,ALL,LAST
SOLVE
/OUT
RATE, ON
DELT,10.0,9.99,10.0
TIME, 10.0
/OUTPUT,SCRATCH
OUTRES,ALL,LAST
SOLVE
/OUT
RATE, ON, ON
DELT,10,1,100
AUTOS,OFF
TIME,1000
/OUTPUT,SCRATCH
OUTRES,ALL,ALL
SOLVE
/OUT
FINISH

/POST26

*IF,I,EQ,1,THEN
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/GTHK,AXIS,1
/GRTYP,0
/GROPT,DIG1,5
/GROPT,DIG2,3
/GROPT,DIVX,5
/GROPT,DIVY,6
/XRANGE,0,1000
/YRANGE,0,300
ESOL,2,1,,S,EQV,TIMEHARD
PRVAR,2
/COLOR,CURVE,BMAG,1
/AXLAB,X,TIME
/AXLAB,Y,STRESS
PLVAR,2

/POST1
SET,1,1
*GET,SH1,NODE,3,S,X
R1=SH1/285.714
SET,6,19
*GET,SH2,NODE,3,S,X
R2=SH2/46.612
SET,6,39
*GET,SH3,NODE,3,S,X
R3=SH3/42.206
SET,6,59
*GET,SH4,NODE,3,S,X
R4=SH4/39.893
SET,6,79
*GET,SH5,NODE,3,S,X
R5=SH5/38.353
SET,6,99
*GET,SH6,NODE,3,S,X
R6=SH6/37.211
*DIM,VALUE1,,6,3
*DIM,VALUE2,,6,3
*DIM,LABEL,CHAR,10
*DIM,TARGET,CHAR,10
LABEL(1) = '0','200', '400', '600', '800', '1000'
TARGET(1) = '285.714','46.612','42.206','39.353','38.353','37.211'
*VFILL,VALUE1(1,1),DATA,SH1,SH2,SH3,SH4,SH5,SH6
*VFILL,VALUE2(1,1),DATA,R1,R2,R3,R4,R5,R6

*ELSEIF,I,EQ,2,THEN
/NOERASE
/GROPT,DIVX,5
/GROPT,DIVY,6
/XRANGE,0,1000
/YRANGE,0,300
ESOL,3,1,,S,EQV,STRAINHARDENING
PRVAR,3
/COLOR,CURVE,GREE,1
/AXLAB,X,TIME
/AXLAB,Y,STRESS
PLVAR,3

/POST1
SET,1,1
*GET,S1,NODE,3,S,X
R10=S1/285.714
SET,6,19
*GET,S2,NODE,3,S,X
R11=S2/62.014
SET,6,39
*GET,S3,NODE,3,S,X
R12=S3/57.251
SET,6,59
*GET,S4,NODE,3,S,X
R13=S4/54.690
SET,6,79
*GET,S5,NODE,3,S,X
R14=S5/52.959
SET,6,99
*GET,S6,NODE,3,S,X
R15=S6/51.661
*DIM,VALUE3,,6,3
*DIM,VALUE4,,6,3
*DIM,LABEL2,CHAR,10
*DIM,TARGET2,CHAR,10
LABEL2(1) = '0','200', '400', '600', '800', '1000'
TARGET2(1) = '285.714','62.014','57.251','54.690','52.959','51.661'
*VFILL,VALUE3(1,1),DATA,S1,S2,S3,S4,S5,S6
*VFILL,VALUE4(1,1),DATA,R10,R11,R12,R13,R14,R15
/COM
/COM
/COM,--------- vmr049-cr2-182 TIME HARDENING COMPARISON -----------
/COM,
/COM COMPARE NUMERICAL VALUES LISTED
/COM BELOW WITH GRAPH OF FIGURE
/COM 3.10A ON PAGE 103 AS NO NUMERICAL
/COM RESULTS ARE PRESENTED.
/COM,
/COM,|   TIME   |  TARGET |  Mechanical APDL  |  RATIO |
/COM,
*VWRITE,LABEL(1),TARGET(1),VALUE1(1,1),VALUE2(1,1)
(1X,A8,'   ',1X,A8,'   ',F14.3,'   ',1F12.3,'   ')
/COM,
/COM,
/COM,--------- vmr049-cr2-182 STRAIN HARDENING COMPARISON ---------
/COM,
/COM,|   TIME   |  TARGET |  Mechanical APDL  |  RATIO |
/COM,
*VWRITE,LABEL2(1),TARGET2(1), VALUE3(1,1), VALUE4(1,1)
(1X,A8,'   ',1X,A8,'   ',F14.3,'   ',1F12.3,'   ')
*ENDIF
*ENDDO
FINISH

/POST26
*DIM,LABEL3,CHAR,2
*DIM,VALUE5,,2,3
LABEL3(1) = ' S6 ',' S7 '
*VFILL,VALUE5(1,1),DATA,SH6,S6
*VFILL,VALUE5(1,2),DATA,R6,R15
*DIM,LABEL4,CHAR,2
LABEL4(1) = 'vmr049-','cr2-182'

/OUT,vmr049-cr2-182,vrt
/COM
/COM,------------------- vmr049-cr2 RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, PLANE182
*VWRITE,LABEL3(1),VALUE5(1,1),VALUE5(1,2),LABEL4(1),LABEL4(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL3(2),VALUE5(2,1),VALUE5(2,2),LABEL4(1),LABEL4(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmr049-cr2-182,vrt