/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-cr1c-183
/TITLE,vmr049-cr1c-183,CONSTANT-LOAD CREEP BENCHMARK
/COM, REFERENCE: TEST CR-1C FROM NAFEMS R0049.

/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANT !(TIME HARDENING)***
*SET,C1,0.5E-14
*SET,C2,5
*SET,C3,-0.5
*SET,C4,0
*SET,C5,1E-16
*SET,C6,5
*SET,C7,0
C*** TIME PARAMETER
*SET,HOUR,200
C*** ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,HOT
TOFF,1E-10
TB,CREEP,1,,,11
TBDATA,1,C1,C2,C3,C4,C5,C6,C6
SAVE
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
ET,1,183
KEYOPT,1,3,0
E,1,2,3,4,5,6,7,8
NSEL,S,LOC,X,
D,ALL,UX,
NSEL,ALL
NSEL,S,,,8
D,ALL,UY,
NSEL,ALL

/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-100
NSEL,ALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8

SOLVE
RATE, ON, ON
DELT,100,99,101
TIME,1000
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
FINISH

/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
PRVAR,2,3
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
PLVAR,2,3
FINISH

/POST1
SET,,,,,,,1
*GET,S1,NODE,3,EPCR,X
*GET,S1_Y,NODE,3,EPCR,Y
R1=S1/0.100E-7
R7=S1_Y/(-0.500E-8)
SET,,,,,,,3
*GET,S2,NODE,3,EPCR,X
*GET,S2_Y,NODE,3,EPCR,Y
R2=S2/0.1614E-2
R8=S2_Y/(-0.807E-3)
SET,,,,,,,5
*GET,S3,NODE,3,EPCR,X
*GET,S3_Y,NODE,3,EPCR,Y
R3=S3/0.2407E-2
R9=S3_Y/(-0.1203E-2)
SET,,,,,,,7
*GET,S4,NODE,3,EPCR,X
*GET,S4_Y,NODE,3,EPCR,Y
R4=S4/0.3055E-2
R10=S4_Y/(-0.15275E-2)
SET,,,,,,,9
*GET,S5,NODE,3,EPCR,X
*GET,S5_Y,NODE,3,EPCR,Y
R5=S5/0.36339E-2
R11=S5_Y/(-0.18172E-2)
SET,,,,,,,11
*GET,S6,NODE,3,EPCR,X
*GET,S6_Y,NODE,3,EPCR,Y
R6=S6/0.41475E-2
R12=S6_Y/(-0.2074E-2)
*DIM,VALUE,,6,4
*DIM,LABEL,CHAR,10
*DIM,TARGETX,CHAR,10
*DIM,TARGETY,CHAR,10
*DIM,RATIO,,6,4
LABEL(1) = '0','200','400','600','800','1000'
TARGETX(1) = '0.100E-7','0.001614','0.002407','0.003055','0.0036339','0.0041475'
TARGETY(1) = '-0.50E-8','-0.000807','-0.001203','-0.001528','-0.001817','-0.002074'
*VFILL,VALUE(1,1),DATA,S1,S2,S3,S4,S5,S6
*VFILL,VALUE(1,2),DATA,R1,R2,R3,R4,R5,R6
*VFILL,VALUE(1,3),DATA,S1_Y,S2_Y,S3_Y,S4_Y,S5_Y,S6_Y
*VFILL,VALUE(1,4),DATA,R7,R8,R9,R10,R11,R12
/COM
/COM
/COM,--------- vmr049-cr1c-183 RESULTS COMPARISON-----------
/COM,
/COM, vmr049-cr1c-183.jpeg RESULTS SHOULD MATCH R0049 NAFEMS MANUAL
/COM, GRAPH RESULTS ON PAGE 100 ,FIGURE 3.7C. THE RESULTS
/COM, DISPLAYED ARE INCREMENTED FOR THIS PURPOSE
/COM,
/COM,-------- CREEP COMPONENT IN X DIRECTION ---------
/COM,
/COM,| TIME |   TARGET  |    Mechanical APDL   |    RATIO
/COM,
*VWRITE,LABEL(1),TARGETX(1), VALUE(1,1), VALUE(1,2)
(1X,A6,'   ',1X,A8,'   ',F14.5,'   ',F12.3,'   ')
/COM,
/COM,-------- CREEP COMPONENT IN Y DIRECTION ---------
/COM,
/COM,| TIME |   TARGET  |    Mechanical APDL   |    RATIO
/COM,
*VWRITE,LABEL(1),TARGETY(1), VALUE(1,3), VALUE(1,4)
(1X,A6,'   ',1X,A8,'   ',F14.5,'   ',F12.3,'   ')
FINISH

/POST26
/COM,ESOL,2,1,,EPCR,X
/COM,ESOL,3,1,,EPCR,Y
/COM,PRVAR,2,3
/COM,PLVAR,2,3
/COM,*GET,RES1X,VARI,2,RTIME,1000
/COM,*GET,RES1Y,VARI,3,RTIME,1000

*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ECR11X ',' ECR11Y '
*VFILL,VALUE1(1,1),DATA,S6,S6_Y
*VFILL,VALUE1(1,2),DATA,R6,R12
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr049-','cr1c-183'

/OUT,vmr049-cr1c-183,vrt
/COM
/COM,------------------- vmr049-cr1c RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, PLANE183
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT

FINISH
*LIST,vmr049-cr1c-183,vrt