/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr049-cr1a-281
/TITLE,vmr049-cr1a-281,CONSTANT-LOAD CREEP BENCHMARK 
/COM, REFERENCE: TEST CR-1A FROM NAFEMS REPORT 0049.
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANT !(TIME HARDENING)***
*SET,C1,3.125E-14
*SET,C2,5
*SET,C3,0
*SET,C4,0
C*** TIME PARAMETER
*SET,HOUR,200
C*** ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,0
TOFF,1E-10
TB,CREEP,1,,,2
TBDATA,1,C1,C2,C3,C4
SAVE
N,1,0,0,0
N,2,100,0
N,3,100,50
N,4,0,50
N,5,100,100
N,6,0,100
N,7,50,0
N,8,100,25
N,9,50,50
N,10,0,25
N,11,100,75
N,12,50,100
N,13,0,75
ET,1,SHELL281,,,
R,1,1,1,1,1,
E,1,2,3,4,7,8,9,10
E,4,3,5,6,9,11,12,13
NSEL,S,LOC,X,
D,ALL,UX,
NSEL,ALL
NSEL,S,,,4
D,ALL,UY,
NSEL,ALL
D,ALL,ROTX
D,ALL,ROTY
D,9,UZ,0
FINISH
*DO,I,1,2,1
*IF,I,EQ,2,THEN
/PREP7
TB,HILL,1
TBDATA,1, 1.0, 1.0, 1.0, 1.0, 1.0, 1.0
*ENDIF
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NSEL,ALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUTPUT,SCRATCH
OUTRES,ALL,LAST
SOLVE
/OUT
RATE, ON, ON
DELT,100,1,100
AUTOS,OFF
TIME,1000
/OUTPUT,SCRATCH
OUTRES,ALL,ALL
SOLVE
/OUT
FINISH
*IF,I,EQ,1,THEN
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
PRVAR,2,3
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
/COLOR,CURVE,RED,1
/YRANGE,-5,10
PLVAR,2,3
FINISH
/POST1
SET,1,1
*GET,S1,NODE,3,EPCR,X
R1=1.00
SET,2,2
*GET,S2,NODE,3,EPCR,X
R2=S2/2
SET,2,4
*GET,S3,NODE,3,EPCR,X
R3=S3/4
SET,2,6
*GET,S4,NODE,3,EPCR,X
R4=S4/6
SET,2,8
*GET,S5,NODE,3,EPCR,X
R5=S5/8
SET,2,10
*GET,S6,NODE,3,EPCR,X
R6=S6/10
*DIM,VALUE,,6,6
*DIM,LABEL,CHAR,10
LABEL(1) = '0','200','400','600','800','1000'
*VFILL,VALUE(1,1),DATA,0,2,4,6,8,10
*VFILL,VALUE(1,2),DATA,S1,S2,S3,S4,S5,S6
*VFILL,VALUE(1,3),DATA,R1,R2,R3,R4,R5,R6
/POST1
SET,1,1
*GET,S1_Y,NODE,3,EPCR,Y
R7=1.00
SET,2,2
*GET,S2_Y,NODE,3,EPCR,Y
R8=S2_Y/(-1.0)
SET,2,4
*GET,S3_Y,NODE,3,EPCR,Y
R9=S3_Y/(-2.0)
SET,2,6
*GET,S4_Y,NODE,3,EPCR,Y
R10=S4_Y/(-3.0)
SET,2,8
*GET,S5_Y,NODE,3,EPCR,Y
R11=S5_Y/(-4.0)
SET,2,10
*GET,S6_Y,NODE,3,EPCR,Y
R12=S6_Y/(-5.0)
LABEL(1) = '0','200','400','600','800','1000'
*VFILL,VALUE(1,4),DATA,0,-1,-2,-3,-4,-5
*VFILL,VALUE(1,5),DATA,S1_Y,S2_Y,S3_Y,S4_Y,S5_Y,S6_Y
*VFILL,VALUE(1,6),DATA,R7,R8,R9,R10,R11,R12
*ENDIF
*IF,I,EQ,2,THEN
/COM,
/COM,  ANISOTROPIC CREEP MODELED AS ISOTROPIC /COM,
/POST26
ESOL,3,1,,EPCR,X
ESOL,4,1,,EPCR,Y
PRVAR,2
/AXLAB,X,TIME
/AXLAB,Y,ANISOTROPIC CREEP STRAIN
/COLOR,CURVE,BLUE,1
/YRANGE,-5,10
PLVAR,3,4
FINISH
/POST1
SET,1,1
*GET,S11,NODE,3,EPCR,X
R11=1.00
SET,2,2
*GET,S22,NODE,3,EPCR,X
R22=S22/2
SET,2,4
*GET,S33,NODE,3,EPCR,X
R33=S33/4
SET,2,6
*GET,S44,NODE,3,EPCR,X
R44=S44/6
SET,2,8
*GET,S55,NODE,3,EPCR,X
R55=S55/8
SET,2,10
*GET,S66,NODE,3,EPCR,X
R66=S66/10
*DIM,VALUE2,,6,6
*VFILL,VALUE2(1,1),DATA,0,2,4,6,8,10
*VFILL,VALUE2(1,2),DATA,S11,S22,S33,S44,S55,S66
*VFILL,VALUE2(1,3),DATA,R11,R22,R33,R44,R55,R66
SET,1,1
*GET,S11_Y,NODE,3,EPCR,Y
R77=1.00
SET,2,2
*GET,S22_Y,NODE,3,EPCR,Y
R88=S22_Y/(-1.0)
SET,2,4
*GET,S33_Y,NODE,3,EPCR,Y
R99=S33_Y/(-2.0)
SET,2,6
*GET,S44_Y,NODE,3,EPCR,Y
R100=S44_Y/(-3.0)
SET,2,8
*GET,S55_Y,NODE,3,EPCR,Y
R111=S55_Y/(-4.0)
SET,2,10
*GET,S66_Y,NODE,3,EPCR,Y
R122=S66_Y/(-5.0)
LABEL(1) = '0','200','400','600','800','1000'
*VFILL,VALUE2(1,4),DATA,0,-1,-2,-3,-4,-5
*VFILL,VALUE2(1,5),DATA,S11_Y,S22_Y,S33_Y,S44_Y,S55_Y,S66_Y
*VFILL,VALUE2(1,6),DATA,R77,R88,R99,R100,R111,R122
*ENDIF
*ENDDO
/COM,
/COM,
/COM,------------- vmr049-cr1a-281 ISOTROPIC RESULTS COMPARISON -------------- 
/COM, 
/COM, vmr049-cr1a-281.jpeg RESULTS SHOULD MATCH R0049 NAFEMS MANUAL 
/COM, GRAPH RESULTS.  THE RESULTS DISPLAYED ARE INCREMENTED /COM, FOR THIS PURPOSE.
/COM,
/COM,
/COM,|  TIME  |  TARGET X  |  Mechanical APDL  |  RATIO  |  TARGET Y  |  Mechanical APDL  | RATIO 
/COM, 
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2), VALUE(1,3), VALUE(1,4),VALUE(1,5), VALUE(1,6)
(1X,A8,'   ',F8.3,'   ',F8.3,'   ',F14.3,'   ',1F14.3,'   ',F8.3,'   ',F10.3,'   ')
/COM,
/COM,
/COM,------------ vmr049-cr1a-281 ANISOTROPIC RESULTS COMPARISON ------------- 
/COM, 
/COM, 
/COM,|  TIME  |  TARGET X  |  Mechanical APDL  |  RATIO  |  TARGET Y  |  Mechanical APDL  | RATIO 
/COM, 
*VWRITE,LABEL(1), VALUE2(1,1), VALUE2(1,2), VALUE2(1,3), VALUE2(1,4),VALUE2(1,5), VALUE2(1,6)
(1X,A8,'   ',F8.3,'   ',F8.3,'   ',F14.3,'   ',1F14.3,'   ',F8.3,'   ',F10.3,'   ')
FINISH
/POST26
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ECR2X ',' ECR2Y '
*VFILL,VALUE1(1,1),DATA,S6,S6_Y
*VFILL,VALUE1(1,2),DATA,R6,R12
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr049-','cr1a-281'
/OUT,vmr049-cr1a-281,vrt
/COM
/COM,------------------- vmr049-cr1a RESULTS COMPARISON --------------------- 
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SHELL281
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL2(1),LABEL2(2)
(1X,A8,'      ',F14.4,'      ',F9.4,'     ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr049-cr1a-281,vrt
/OUT,SCRATCH