/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMR029-T9-190
/TITLE,VMR029-T9-190,LARGE ELASTIC DEFLECTION OF A PINCHED HEMISPHERICAL SHELL
/COM, REF. NAFEMS ASSEMBLY BENCHMARK TESTS FOR 3D BEAMS AND SHELLS TEST 3DNLG-9
/PREP7
RM=10.02
T=0.04
THETA=18
F=100.0
ET,1,190
MP,EX,1,6.825E7
MP,NUXY,1,0.3
K,1,
K,2,,RM+2*T
PCIRC,RM+T/2,RM-T/2,0,90-THETA,
VROTAT,ALL, , , , , ,1,2,-90, ,
LESIZE,ALL,,,32
LESIZE,2,,,1
LESIZE,4,,,1
LESIZE,6,,,1
LESIZE,8,,,1
VEORIENT,1,THIN
VMESH,ALL
NSEL,S,LOC,Z,RM+T/2,RM+T
NSEL,R,LOC,X,0
NSEL,R,LOC,Y,0
D,ALL,UY,0.0
CSYS,2
NSEL,S,LOC,X,RM+T/2,RM+T
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,0
F,ALL,FX,F
NSEL,S,LOC,X,RM+T/2,RM+T
NSEL,R,LOC,Y,0
NSEL,R,LOC,Z,90
NROTAT,ALL
F,ALL,FX,-1*F
NSEL,S,LOC,Z,0
NSEL,R,LOC,Y,0,90
DSYM,SYMM,Z,2
NSEL,S,LOC,Y,90
NSEL,R,LOC,Z,0,91
DSYM,SYMM,Y,2
NSEL,S,LOC,Y,0
NSEL,R,LOC,Z,90
DSYM,SYMM,Z,2
ALLSEL,ALL
ESEL,S,,,1
ESEL,A,,,120
ESEL,A,,,1024
CM,ELESOL,ELEM
ALLSEL,ALL
FINISH
/SOLU
NLGEOM,ON
AUTOTS,ON
NSUBST,100,100000,40
OUTRES,ALL,ALL
/OUT,SCRATCH
SOLVE
FINISH
/SHOW,,jpeg
/POST26
*DIM,XA,TABLE,11,1
*DIM,YA,TABLE,11,1
XA( 1,1)= 0
YA( 1,1)= 0
XA( 2,1)= 10
YA( 2,1)= 1.0
XA( 3,1)= 20
YA( 3,1)= 1.75
XA( 4,1)= 30
YA( 4,1)= 2.625
XA( 5,1)= 40
YA( 5,1)= 3.23
XA( 6,1)= 50
YA( 6,1)= 3.875
XA( 7,1)= 60
YA( 7,1)= 4.29
XA( 8,1)= 70
YA( 8,1)= 4.815
XA( 9,1)= 80
YA( 9,1)= 5.185
XA( 10,1)= 90
YA( 10,1)= 5.52
XA( 11,1)= 100
YA( 11,1)= 5.875
/XRANGE,0,100
/YRANGE,0,6
/AXLAB,X,LOAD
/AXLAB,Y,RADIAL DISPLACEMENT
/COLOR,CURVE,YGRE
/GCOLUMN,1,REF,
*VPLOT,XA(1,1),YA(1,1)
/NOERASE
/OUT,
NSOL,2,2,U,X,UR_A
PROD,3,2, , ,' URATA', , ,-1.0,0,0,
PROD,7,1, , ,LOAD, , ,100.0,0,0,
/COLOR,CURVE,MRED
XVAR,7
PLVAR,3
/NOERASE
*DIM,XB,TABLE,11,1
*DIM,YB,TABLE,11,1
XB( 1,1)= 0
YB( 1,1)= 0
XB( 2,1)= 10
YB( 2,1)= 0.88
XB( 3,1)= 20
YB( 3,1)= 1.5
XB( 4,1)= 30
YB( 4,1)= 2
XB( 5,1)= 40
YB( 5,1)= 2.30
XB( 6,1)= 50
YB( 6,1)= 2.63
XB( 7,1)= 60
YB( 7,1)= 2.82
XB( 8,1)= 70
YB( 8,1)= 3
XB( 9,1)= 80
YB( 9,1)= 3.16
XB( 10,1)= 90
YB( 10,1)= 3.30
XB( 11,1)= 100
YB( 11,1)= 3.42
/COLOR,CURVE,YGRE
/GCOLUMN,1,REF,
*VPLOT,XB(1,1),YB(1,1)
/NOERASE
NSOL,5,1,U,X,' URATB'
/COLOR,CURVE,MRED
XVAR,7
PLVAR,5
FINISH
/POST1
RSYS,2
SET, , ,1, ,0.4, ,
*GET,UB_4,NODE,1,U,X
*GET,UA_4,NODE,2,U,X
SET, , ,1, ,0.6, ,
*GET,UB_6,NODE,1,U,X
*GET,UA_6,NODE,2,U,X
SET, , ,1, ,0.9, ,
*GET,UB_9,NODE,1,U,X
*GET,UA_9,NODE,2,U,X
SET, , ,1, ,1.0, ,
*GET,UB_10,NODE,1,U,X
*GET,UA_10,NODE,2,U,X
*DIM,LABEL1,CHAR,1,4
LABEL1(1,1) = '40'
LABEL1(1,2) = '60'
LABEL1(1,3) = '90'
LABEL1(1,4) = '100'
*DIM,VALUE1,CHAR,1,4
VALUE1(1,1) = '-3.28'
VALUE1(1,2) = '-4.36'
VALUE1(1,3) = '-5.61'
VALUE1(1,4) = '-5.9 '
*DIM,VALUE2,CHAR,1,4
VALUE2(1,1) = '-3.23'
VALUE2(1,2) = '-4.29'
VALUE2(1,3) = '-5.52'
VALUE2(1,4) = ' '
*DIM,ERROR1,,1,4
*VFILL,ERROR1(1,1),DATA,UA_4
*VFILL,ERROR1(1,2),DATA,UA_6
*VFILL,ERROR1(1,3),DATA,UA_9
*VFILL,ERROR1(1,4),DATA,UA_10
/COM,
/COM, ------ RADIAL DISPLACEMENT UNDER LOAD (NODE A(2)) ------
/COM,
/COM, | NAFEMS TEST | Mechanical APDL |
/COM, | LOAD | REF. | NUM.RES. | SOL.190 |
/COM,
*VWRITE,LABEL1(1,1),VALUE2(1,1),VALUE1(1,1),ERROR1(1,1)
(1X,' ',A3,' ',A5,' ',A5,' ',F10.5)
*VWRITE,LABEL1(1,2),VALUE2(1,2),VALUE1(1,2),ERROR1(1,2)
(1X,' ',A3,' ',A5,' ',A5,' ',F10.5)
*VWRITE,LABEL1(1,3),VALUE2(1,3),VALUE1(1,3),ERROR1(1,3)
(1X,' ',A3,' ',A5,' ',A5,' ',F10.5)
*VWRITE,LABEL1(1,4),VALUE2(1,4),VALUE1(1,4),ERROR1(1,4)
(1X,' ',A3,' ',A5,' ',A5,' ',F10.5)
/COM,
/COM, ----------------------------------------------------------
*DIM,LABELB,CHAR,1,4
LABELB(1,1) = '40'
LABELB(1,2) = '60'
LABELB(1,3) = '90'
LABELB(1,4) = '100'
*DIM,VALUEB,CHAR,1,4
VALUEB(1,1) = '2.33'
VALUEB(1,2) = '2.83'
VALUEB(1,3) = '3.31'
VALUEB(1,4) = '3.42'
*DIM,VALUEB1,CHAR,1,4
VALUEB1(1,1) = '2.30'
VALUEB1(1,2) = '2.82'
VALUEB1(1,3) = '3.30'
VALUEB1(1,4) = ' '
*DIM,ERRORB,,1,4
*VFILL,ERRORB(1,1),DATA,UB_4
*VFILL,ERRORB(1,2),DATA,UB_6
*VFILL,ERRORB(1,3),DATA,UB_9
*VFILL,ERRORB(1,4),DATA,UB_10
/OUT,
/COM,
/COM, ------ RADIAL DISPLACEMENT UNDER LOAD (NODE B(1)) ------
/COM,
/COM, | NAFEMS TEST | Mechanical APDL |
/COM, | LOAD | REF. | NUM.RES. | SOL.190 |
/COM,
*VWRITE,LABELB(1,1),VALUEB1(1,1),VALUEB(1,1),ERRORB(1,1)
(1X,' ',A3,' ',A4,' ',A4,' ',F12.5)
*VWRITE,LABELB(1,2),VALUEB1(1,2),VALUEB(1,2),ERRORB(1,2)
(1X,' ',A3,' ',A4,' ',A4,' ',F12.5)
*VWRITE,LABELB(1,3),VALUEB1(1,3),VALUEB(1,3),ERRORB(1,3)
(1X,' ',A3,' ',A4,' ',A4,' ',F12.5)
*VWRITE,LABELB(1,4),VALUEB1(1,4),VALUEB(1,4),ERRORB(1,4)
(1X,' ',A3,' ',A4,' ',A4,' ',F12.5)
/COM,
/COM, ----------------------------------------------------------
ESEL,,,,ELESOL
NSLE
ESEL,ALL
PRNSOL,S,COMP
PRNSOL,EPTO,COMP
FINISH
/POST1
NSEL,ALL
SET,LAST
*GET,UB,NODE,1,U,X
*GET,UA,NODE,2,U,X
RA=UA/(-5.9)
RB=UB/3.42
*DIM,VALUE3,,2,2
*DIM,LABEL2,CHAR,2
*DIM,LABEL4,CHAR,2
*DIM,LABEL5,CHAR,2
LABEL2(1) = 'NODE A','NODE B',
LABEL4(1) = 'vmr029-','vmr029-'
LABEL5(1) = 't9-190','t9-190'
*VFILL,VALUE3(1,1),DATA,UA,UB
*VFILL,VALUE3(1,2),DATA,RA,RB
/OUT,vmr029-t9-190,vrt
/COM
/COM,-------------- VMR029-T9 RESULTS COMPARISON ---------------
/COM,
/COM, | Mechanical APDL | RATIO | INPUT |
/COM,
/COM,SOLSH190
*VWRITE,LABEL2(1),VALUE3(1,1),VALUE3(1,2),LABEL4(1),LABEL5(1)
(1X,A6,' ',F12.4,' ',F13.4,' ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr029-t9-190,vrt
