/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMR029-T5-188
/TITLE,VMR029-T5-188,LARGE DEFLECTION OF A CURVED ELASTIC CANTILEVER UNDER TRANSVERSE END LOAD
/COM, REFERENCE: NAFEMS BENCHMARK TEST FOR BEAMS AND SHELLS TEST 3DNLG-5

/PREP7
CSYS,1
T = 45/8.0
N,1,100.0,0.0
N,2,100.0,-T
N,3,100.0,-2*T
N,4,100.0,-3*T
N,5,100.0,-4*T
N,6,100.0,-5*T
N,7,100.0,-6*T
N,8,100.0,-7*T
N,9,100.0,-8*T
ET,1,188
SECN,1
N,101,0.0,
CSYS,0
E,1,2,101
E,2,3,101
E,3,4,101
E,4,5,101
E,5,6,101
E,6,7,101
E,7,8,101
E,8,9,101
SECT,1,BEAM,RECT
SECD,1,1
MP,EX,1,1E7
MP,GXY,1,0.5E7
MP,NUXY,1,0.0
D,1,ALL

/SOLU
NLGEOM,ON
OUTRES,ALL,ALL
F,9,FZ,3000
NSUBST,40,200
/OUT,SCRATCH
SOLVE
FINISH
/SHOW,,jpeg

/POST26
*DIM,XUX,TABLE,11,1
*DIM,YUX,TABLE,11,1
XUX(1,1)= 0
YUX(1,1)= 0
XUX(2,1)= 300
YUX(2,1)= -7.14
XUX(3,1)= 600
YUX(3,1)= -13.68
XUX(4,1)= 900
YUX(4,1)= -18
XUX(5,1)= 1200
YUX(5,1)= -20.5
XUX(6,1)= 1500
YUX(6,1)= -21.5
XUX(7,1)= 1800
YUX(7,1)= -22.8
XUX(8,1)= 2100
YUX(8,1)= -23.7
XUX(9,1)= 2400
YUX(9,1)= -24.4
XUX(10,1)= 2700
YUX(10,1)= -24.6
XUX(11,1)= 3000
YUX(11,1)= -25

/XRANGE,0,3000
/YRANGE,-60,90
/AXLAB,X,LOAD
/AXLAB,Y,TIP DISPLACEMENT
/COLOR,CURVE,YGRE
/GCOLUMN,1,'  REF_UX'
*VPLOT,XUX(1,1),YUX(1,1)
/NOERASE
/OUT,
NSOL,2,9,U,Z,UZ
PROD,7,1, , ,LOAD, , ,3000.0,0,0,
/COLOR,CURVE,MRED
XVAR,7
PLVAR,2
/NOERASE
*DIM,XUY,TABLE,11,1
*DIM,YUY,TABLE,11,1
XUY(1,1)= 0
YUY(1,1)= 0
XUY(2,1)= 300
YUY(2,1)= -12.18
XUY(3,1)= 600
YUY(3,1)= -23.87
XUY(4,1)= 900
YUY(4,1)= -30
XUY(5,1)= 1200
YUY(5,1)= -33.5
XUY(6,1)= 1500
YUY(6,1)= -38
XUY(7,1)= 1800
YUY(7,1)= -40
XUY(8,1)= 2100
YUY(8,1)= -42.5
XUY(9,1)= 2400
YUY(9,1)= -44
XUY(10,1)= 2700
YUY(10,1)= -45
XUY(11,1)= 3000
YUY(11,1)= -47.31

/COLOR,CURVE,YGRE
/GCOLUMN,1,'  REF_UY'
*VPLOT,XUY(1,1),YUY(1,1)
/NOERASE
NSOL,3,9,U,X,UX
PROD,5,3,,,UX,,,-1
/COLOR,CURVE,MRED
XVAR,7
PLVAR,5
/NOERASE
*DIM,XUZ,TABLE,11,1
*DIM,YUZ,TABLE,11,1
XUZ(1,1)= 0
YUZ(1,1)= 0
XUZ(2,1)= 300
YUZ(2,1)= 40.53
XUZ(3,1)= 600
YUZ(3,1)= 53.71
XUZ(4,1)= 900
YUZ(4,1)= 60
XUZ(5,1)= 1200
YUZ(5,1)= 62
XUZ(6,1)= 1500
YUZ(6,1)= 63
XUZ(7,1)= 1800
YUZ(7,1)= 64.5
XUZ(8,1)= 2100
YUZ(8,1)= 65.5
XUZ(9,1)= 2400
YUZ(9,1)= 66
XUZ(10,1)= 2700
YUZ(10,1)= 67
XUZ(11,1)= 3000
YUZ(11,1)= 68.09

/COLOR,CURVE,YGRE
/GCOLUMN,1,'  REF_UZ'
*VPLOT,XUZ(1,1),YUZ(1,1)
/NOERASE
NSOL,4,9,U,Y,UY
PROD,6,4,,,UY,,,-1
/COLOR,CURVE,MRED
XVAR,7
PLVAR,6
FINISH

/POST1
SET,LAST
PRNSOL,DOF
*GET,UX1,NODE,9,U,X
*GET,UY1,NODE,9,U,Y
*GET,UZ1,NODE,9,U,Z
*GET,APLOAD,TIME
RX=ABS(UX1/24.97)
RY=ABS(UY1/47.31)
RZ=ABS(UZ1/68.09)
*DIM,VALUE,,3,2
*DIM,LABEL2,CHAR,3
*DIM,LABEL,CHAR,3
*DIM,LABEL3,CHAR,3
LABEL2(1) = 'UX','UY','UZ'
LABEL(1) = 'vmr029-','vmr029-','vmr029-'
LABEL3(1) = 't5-188','t5-188','t5-188'
*VFILL,VALUE(1,1),DATA,ABS(UX1),ABS(UY1),ABS(UZ1)
*VFILL,VALUE(1,2),DATA,RX,RY,RZ
/OUT,vmr029-t5-188,vrt
/COM
/COM,-------------- VMR029-T5 RESULTS COMPARISON ---------------
/COM,
/COM,         |    Mechanical APDL    |   RATIO   |      INPUT      |
/COM,
/COM,BEAM188
*VWRITE,LABEL2(1),VALUE(1,1),VALUE(1,2),LABEL(1),LABEL3(1)
(1X,'   ',A2,'       ',F12.4,'      ',F13.4,'      ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr029-t5-188,vrt