/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMR029-T4-181
/TITLE,VMR029-T4-181,LATERAL-TORSIONAL BUCKLING OF AN ELASTIC CANTILEVER SUBJECTED TO TRANSVERSE END LOAD
/COM,REFERENCE NAFEMS 3D BEAMS AND SHELLS MANUAL TEST 3DNLG-4
/FILNAME,vmr029-t4-181
/PREP7
ET, 1,SHELL181,,,2
R,1,0.2,0.2,0.2,0.2
MP,EX,1,1E4
MP,NUXY,1,0
MP,GXY,1,5000
BLOCK,0,100,0,5,0,5
LSEL,S,LINE,,9,10
LESIZE,ALL, , ,6
LSEL,S,LINE,,4,5
LESIZE,ALL, , ,10
TYPE,1
REAL,1
MAT,1
AMESH,3
NSEL,S,LOC,X,0
D,ALL,ALL
NSEL,S,LOC,X,100
NSEL,R,LOC,Z,2.5
*GET,NTIP,NODE,0,NUM,MAX
NSEL,S,LOC,X,100
NSEL,R,LOC,Z,0
*GET,ND1,NODE,0,NUM,MAX
NSEL,S,LOC,X,100
NSEL,R,LOC,Z,5
*GET,ND2,NODE,0,NUM,MAX
ALLSEL,ALL
F,NTIP,FZ,-1
ALLSEL,ALL
FINISH
/SOLU
ANTYPE,STATIC
RESCONTROL,LINEAR,ALL,1 ! RESTART FILES FOR SUBSEQUENT LINEAR PERTURBATION
EQSLV,SPARSE
/OUT,SCRATCH
SOLVE
FINISH
/SOLU
ANTYPE,STATIC,RESTART,,,PERTURB ! PERFORM A PERTURBATION ANALYSIS
PERTURB,BUCKLE,,,ALLKEEP ! PERTURBED BUCKLING SOLVE
SOLVE,ELFORM ! REFORM ELEMENT MATRICES
OUTRES,ALL,ALL
bucopt,SUBSP,4,,,range
MXPAND,4,,,YES
SOLVE
FINISH
/PREP7
UPGEOM,0.001/4,1,1,vmr029-t4-181,rstp
NSEL,S,NODE,,ND1
NSEL,A,NODE,,ND2
NLIST
NSEL,ALL
FINISH
/SOLU
ANTYPE,STATIC
OUTRES,ALL,ALL
NLGEOM,ON
ARCLEN,ON,1,0.0001
ARCTRM,U,1.0,NTIP,UY
NSUBST,1000
SOLVE
FINISH
/POST26
NSOL,2,NTIP,U,Y,TIPDISP
ADD,3,1,,,APLOAD,,,1,
/XRANGE,0,0.06
/YRANGE,0,0.02
/GROPT,DIVX,6
/AXLAB,X,TIP LATERAL DISP
/AXLAB,Y,LOAD
/COLOR,CURVE,YGRE
XVAR,2
PLVAR,3
/OUT,
PRVAR,2,4
/POST1
SET,1,19
*GET,APLOAD,TIME
R=APLOAD/0.01892
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,3
LABEL(1) = 'PCR','vmr029-','t4-181'
*VFILL,VALUE(1,1),DATA,APLOAD
*VFILL,VALUE(1,2),DATA,R
/OUT,vmr029-t4-181,vrt
/COM
/COM,-------------- VMR029-T4 RESULTS COMPARISON ---------------
/COM,
/COM, | Mechanical APDL | RATIO | TEST |
/COM,
/COM,SHELL181
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2),LABEL(2),LABEL(3)
(1X,' ',A4,' ',F10.5,' ',F12.4,' ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr029-t4-181,vrt
