/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMR029-T1-188
/TITLE,VMR029-T1-188,ELASTIC LARGE DEFLECTION RESPONSE OF A Z-SHAPED CANTILEVER UNDER END LOAD
/COM, REFERENCE: NAFEMS GEOMETRIC NONLINEAR BEHAVIOUR OF 3D BEAMS AND SHELLS
/COM, MANUAL TEST 3DNLG-1

/PREP7
SECN,1
SECT,1,BEAM,RECT
SECD,20,1.7
N,1,0.0
N,7,60.0
N,13,120.0,30.0
N,19,180.0,30.0
FILL,1,7
FILL,7,13
FILL,13,19
N,101,30,30
N,102,120,60
N,103,160,160
ET,1,188
E,1,2,101
E,2,3,101
E,3,4,101
E,4,5,101
E,5,6,101
E,6,7,101
E,7,8,102
E,8,9,102
E,9,10,102
E,10,11,102
E,11,12,102
E,12,13,102
E,13,14,103
E,14,15,103
E,15,16,103
E,16,17,103
E,17,18,103
E,18,19,103
MP,EX,1,2.0E5
MP,NUXY,1,0.3
FINISH

/SOLU
ANTYPE,0
NLGEOM,ON
NSUBST,100
D,1,ALL
F,19,FY,4000
OUTRES,ALL,ALL
/OUT,SCRATCH
SOLVE
FINISH

/POST26
/GOLIST
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/AXLAB,X,TIP DEFLECTION
/AXLAB,Y,LOAD
/GTHK,AXIS,1
/GRTYP,0
/GROPT,ASCAL,ON
/GROPT,LOGX,OFF
/GROPT,LOGY,OFF
/GROPT,AXDV,1
/GROPT,AXNM,ON
/GROPT,AXNSC,1,
/GROPT,DIG1,4,
/GROPT,DIG2,3,
/XRANGE,0,150
/YRANGE,0,4000
/GOPR
/OUT,
NSOL,2,19,U,Y,
RFORCE,3,1,F,Y,
PROD,4,3, , , , , ,-1,1,1,
XVAR,2
/SHOW,,jpeg
PLVAR,4
PRVAR,4,2
FINISH

/POST1
SET,1,LAST
*GET,UY1,NODE,19,U,Y
HF1=UY1/143.43
*DIM,VALUE,,1,3
*DIM,LABEL,CHAR,2
LABEL(1) = 'vmr029-','t1-188'
*VFILL,VALUE(1,1),DATA,4000.0
*VFILL,VALUE(1,2),DATA,UY1
*VFILL,VALUE(1,3),DATA,HF1
/OUT,vmr029-t1-188,vrt
/COM
/COM,-------------- VMR029-T1 RESULTS COMPARISON--------------
/COM,
/COM,|  LOAD  |      Mechanical APDL      |   RATIO   |      TEST      |
/COM,
/COM,BEAM188
*VWRITE,VALUE(1,1), VALUE(1,2), VALUE(1,3), LABEL(1),LABEL(2)
(1X,F8.2,'     ',F12.2,'      ',F12.2,'      ',A7,A8)
/COM,
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,vmr029-t1-188,vrt