/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr027-cr3a-281
/TITLE,vmr027-cr3a-281,2D PLANE STRESS-BIAXIAL LOAD SECONDARY CREEP
/COM, REFERENCE: TEST 3(A) FROM NAFEMS R0027.
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANT !(SECONDARY CREEP)***
*SET,C1,3.125E-14
*SET,C2,5
*SET,C3,0
*SET,C4,0
C*** TIME PARAMETER
*SET,HOUR,200
C*** ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,HOT
TOFF,1E-10
TB,CREEP,1,,,6
TBDATA,1,C1,C2,C3,C4
SAVE
N,1,0,0,0
N,2,100,0
N,3,100,50
N,4,0,50
N,5,100,100
N,6,0,100
N,7,50,0
N,8,100,25
N,9,50,50
N,10,0,25
N,11,100,75
N,12,50,100
N,13,0,75
ET,1,SHELL281,,,
R,1,1,1,1,1,
E,1,2,3,4,7,8,9,10
E,4,3,5,6,9,11,12,13
NSEL,S,LOC,X,
D,ALL,UX,
NSEL,ALL
NSEL,S,LOC,Y,
D,ALL,UY,
NSEL,ALL
D,ALL,UZ
D,ALL,ROTX
D,ALL,ROTY
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NSEL,ALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NSEL,ALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
/NOPR
SOLVE
RATE, ON
DELT,0.10,0.099,0.10
TIME, 0.10
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,1.0,0.99,1.0
TIME, 1.0
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,5.0,4.99,5.0
TIME, 5.0
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,10.0,9.99,10.0
TIME, 10.0
OUTRES,ALL,LAST
SOLVE
RATE, ON, ON
DELT,10,1,100
AUTOS,OFF
TIME,1000
OUTRES,ALL,ALL
SOLVE
FINISH
/GOPR
/OUT,
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
ESOL,4,1,,EPCR,EQV
PRVAR,2,3
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
/YRANGE,-160,160
/COLOR,CURVE,RED,1
PLVAR,2
/NOERASE
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
/YRANGE,-160,160
/COLOR,CURVE,BLUE,1
PLVAR,3
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
/YRANGE,-160,160
/COLOR,CURVE,GREEN,1
PLVAR,4
/SHOW,CLOSE
/POST1
SET,1,1
*GET,SH1,NODE,3,EPCR,X
*GET,SH11,NODE,3,EPCR,Y
R1=1.00
R11=1.00
SET,2,1
*GET,SH2,NODE,3,EPCR,X
*GET,SH12,NODE,3,EPCR,Y
R2=SH2/0.0135
R12=SH12/(-0.0135)
SET,3,1
*GET,SH3,NODE,3,EPCR,X
*GET,SH13,NODE,3,EPCR,Y
R3=SH3/(0.135)
R13=SH13/(-0.135)
SET,4,1
*GET,SH4,NODE,3,EPCR,X
*GET,SH14,NODE,3,EPCR,Y
R4=SH4/0.675
R14=SH14/(-0.675)
SET,,,,,,,5
*GET,SH5,NODE,3,EPCR,X
*GET,SH15,NODE,3,EPCR,Y
R5=SH5/(1.35)
R15=SH15/(-1.35)
SET,,,,,,,9
*GET,SH6,NODE,3,EPCR,X
*GET,SH16,NODE,3,EPCR,Y
R6=SH6/6.75
R16=SH16/(-6.75)
SET,,,,,,,14
*GET,SH7,NODE,3,EPCR,X
*GET,SH17,NODE,3,EPCR,Y
R7=SH7/13.5
R17=SH17/(-13.5)
SET,,,,,,,54
*GET,SH8,NODE,3,EPCR,X
*GET,SH18,NODE,3,EPCR,Y
R8=SH8/67.5
R18=SH18/(-67.5)
SET,,,,,,,104
*GET,SH9,NODE,3,EPCR,X
*GET,SH19,NODE,3,EPCR,Y
R9=SH9/135.0
R19=SH19/(-135.0)
*DIM,VALUE,,9,6
*DIM,LABEL,CHAR,10
LABEL(1) = '0','0.1', '1.0', '5.0', '10.0', '50.0','100.0','500.0','1000.0'
*VFILL,VALUE(1,1),DATA,0.0,0.0135,0.135,0.675,1.35,6.75,13.5,67.5,135.0
*VFILL,VALUE(1,2),DATA,SH1,SH2,SH3,SH4,SH5,SH6,SH7,SH8,SH9
*VFILL,VALUE(1,3),DATA,R1,R2,R3,R4,R5,R6,R7,R8,R9
*VFILL,VALUE(1,4),DATA,0.0,-0.0135,-0.135,-0.675,-1.35,-6.75,-13.5,-67.5,-135.0
*VFILL,VALUE(1,5),DATA,SH11,SH12,SH13,SH14,SH15,SH16,SH17,SH18,SH19
*VFILL,VALUE(1,6),DATA,R11,R12,R13,R14,R15,R16,R17,R18,R19
/COM
/COM
/COM,-------------------- vmr027-cr3a-281 RESULTS COMPARISON ----------------------
/COM,
/COM,| TIME | TARGETX | Mechanical APDL | RATIO | TARGETY | Mechanical APDL | RATIO
/COM,
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2), VALUE(1,3), VALUE(1,4),VALUE(1,5),VALUE(1,6)
(1X,A8,' ',F8.3,' ',F8.3,' ',1F13.3,' ',F13.3,' ',F8.3,' ',F13.3)
FINISH
/POST26
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ECR6X ',' ECR6Y '
*VFILL,VALUE1(1,1),DATA,SH9,SH19
*VFILL,VALUE1(1,2),DATA,R9,R19
*DIM,LABEL2,CHAR,2
LABEL2(1) = 'vmr027-','cr3a-281'
/OUT,vmr027-cr3a-281,vrt
/COM
/COM,----------------- vmr027-cr3a RESULTS COMPARISON -------------------
/COM,
/COM, | Mechanical APDL | RATIO | INPUT |
/COM,
/COM, SHELL281
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2)
(1X,A8,' ',F13.3,' ',F9.4,' ',A7,A8)
*VWRITE,LABEL1(2),VALUE1(2,1),VALUE1(2,2),LABEL2(1),LABEL2(2)
(1X,A8,' ',F13.3,' ',F9.4,' ',A7,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr027-cr3a-281,vrt
