/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr027-cr12b-281
/TITLE,vmr027-cr12b-281,2D PLANE STRESS-UNIAXIAL DISPLACEMENT PRIMARY-SECONDARY CREEP
/COM,THE COMPARISON IS MADE GRAPHICALLY AND QUANTITATIVELY WITH THE
/COM,RESULTS OF THE TEST 12(B)FROM NAFEMS REPORT R0027.
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANT !(PRIMARY AND SECONDARY CREEP)***
*SET,C1,0.5E-14
*SET,C2,5
*SET,C3,-0.5
*SET,C4,0
*SET,C5,1E-16
*SET,C6,5
*SET,C7,0
C*** TIME PARAMETER
*SET,HOUR,200
C*** ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,HOT
TOFF,1E-10
TB,CREEP,1,,,11
TBDATA,1,C1,C2,C3,C4,C5,C6
TBDATA,7,C7
N,1,0,0,0
N,2,100,0
N,3,100,100
N,4,0,100
N,5,50,0
N,6,100,50
N,7,50,100
N,8,0,50
N,9,50,50
N,10,25,0,0
N,11,75,0,0
N,12,0,25,0
N,13,50,25,0
N,14,100,25,0
N,15,25,50,0
N,16,75,50,0
N,17,0,75,0
N,18,50,75,0
N,19,100,75,0
N,20,25,100,0
N,21,75,100,0
ET,1,SHELL281,,,
R,1,1,1,1,1,
E,1,5,9,8,10,13,15,12
E,5,2,6,9,11,14,16,13
E,9,6,3,7,16,19,21,18
E,8,9,7,4,15,18,20,17
NSEL,S,LOC,X,0
D,ALL,UX,
NSEL,ALL
NSEL,S,LOC,Y,50
NSEL,R,LOC,X,0
D,ALL,UY,
NSEL,ALL
D,ALL,UZ
/SOLU
NSEL,S,LOC,X,100
D,ALL,UX,0.1
NSEL,ALL
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
/OUTPUT,SCRATCH
/NOPR
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,0.10,0.099,0.10
TIME, 0.10
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,1.0,0.99,1.0
TIME, 1.0
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,5.0,4.99,5.0
TIME, 5.0
OUTRES,ALL,LAST
SOLVE
RATE, ON
DELT,10.0,9.99,10.0
TIME, 10.0
OUTRES,ALL,LAST
SOLVE
RATE, ON, ON
DELT,10,1,100
AUTOS,OFF
TIME,1000
OUTRES,ALL,ALL
SOLVE
FINISH
/GOPR
/OUT,

/POST26
/GROPT,VIEW,0
/GTHK,CURVE,1
/GROPT,FILL,OFF
/GRID,1
/GTHK,GRID,1
/GROPT,CGRID,1
/AXLAB,X,TIME
/AXLAB,Y,STRESS
/GTHK,AXIS,1
/GRTYP,0
/GROPT,DIG1,5
/GROPT,DIG2,3
/GROPT,DIVX,5
/GROPT,DIVY,9
/XRANGE,0,1000
/YRANGE,0,225
ESOL,2,1,,S,X
PLVAR,2
PRVAR,2
/POST1
SET,1,1
*GET,SH1,NODE,3,S,X
R1=SH1/200.0
SET,,,,,,,9
*GET,SH6,NODE,3,S,X
R6=SH6/63.58
SET,,,,,,,14
*GET,SH7,NODE,3,S,X
R7=SH7/57.96
SET,,,,,,,54
*GET,SH8,NODE,3,S,X
R8=SH8/46.20
SET,,,,,,,104
*GET,SH9,NODE,3,S,X
R9=SH9/41.61
*DIM,VALUE,,5,3
*DIM,LABEL,CHAR,10
LABEL(1) = '0','50.0','100.0','500.0','1000.0'
*VFILL,VALUE(1,1),DATA,200.00,63.58,57.96,46.20,41.61
*VFILL,VALUE(1,2),DATA,SH1,SH6,SH7,SH8,SH9
*VFILL,VALUE(1,3),DATA,R1,R6,R7,R8,R9
/COM
/COM
/COM,--------- vmr027-cr12b-281 RESULTS COMPARISON-----------
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2), VALUE(1,3)
(1X,A8,'   ',F8.3,'   ',F13.3,'   ',1F13.3)
FINISH
/POST26
*DIM,LABEL1,CHAR,2
*DIM,VALUE1,,2,3
LABEL1(1) = ' ECR11X ',' ECR11Y '
*VFILL,VALUE1(1,1),DATA,SH9
*VFILL,VALUE1(1,2),DATA,R9
*DIM,LABEL2,CHAR,3
LABEL2(1) = 'vmr027-','cr12b-28','1'
/OUT,vmr027-cr12b-281,vrt
/COM
/COM,---------------- vmr027-cr12b RESULTS COMPARISON ------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SHELL281
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL2(2),LABEL2(3)
(1X,A8,'      ',F13.3,'      ',F9.4,'     ',A7,A8,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr027-cr12b-281,vrt