/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,vmr027-cr10a-281
/TITLE,vmr027-cr10a-281,2D PLANE STRESS-BIAXIAL LOAD PRIMARY CREEP
/COM, REFERENCE: TEST 10(A) FROM NAFEMS R0027.
/PREP7
C*** PARAMETRIC INPUT FOR CREEP CONSTANTS (PRIMARY CREEP)!***
*SET,C1,1.5625E-14
*SET,C2,5.0
*SET,C3,-0.5
*SET,C4,0
C***  TIME PARAMETER
*SET,HOUR,1000
C***   ELASTIC CONSTANT
MP,EX,1,200E3
MP,NUXY,1,0.3
TUNIF,HOT
TOFF,OFFS
TB,CREEP,1,,,6
TBDATA,1,C1,C2,C3,C4
SAVE
N,1,0,0,0
N,2,100,0
N,3,100,50
N,4,0,50
N,5,100,100
N,6,0,100
N,7,50,0
N,8,100,25
N,9,50,50
N,10,0,25
N,11,100,75
N,12,50,100
N,13,0,75
ET,1,SHELL281,,,
R,1,1,1,1,1,
E,1,2,3,4,7,8,9,10
E,4,3,5,6,9,11,12,13
NSEL,ALL
NSEL,S,LOC,X
D,ALL,UX
NSEL,S,LOC,Y
D,ALL,UY
NSEL,ALL
/SOLU
NSEL,S,LOC,X,100
SF,ALL,PRES,-200
NSEL,ALL
NSEL,S,LOC,Y,100
SF,ALL,PRES,200
NSEL,ALL
D,ALL,UZ
D,ALL,ROTZ
FINISH
/SOLU
RATE, OFF
DELT,1.0E-8,1.0E-9,1.0E-8
TIME, 1.0E-8
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,0.10,0.099,0.10
TIME, 0.10
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,1.0,0.99,1.0
TIME, 1.0
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,5.0,4.99,5.0
TIME, 5.0
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON
DELT,10.0,9.99,10.0
TIME, 10.0
OUTRES,ALL,LAST
/OUTPUT,SCRATCH
SOLVE
/OUT
RATE, ON, ON
DELT,10,1,100
AUTOS,OFF
TIME,1000
OUTRES,ALL,ALL
/OUTPUT,SCRATCH
SOLVE
/OUT
FINISH
/POST26
ESOL,2,1,,EPCR,X
ESOL,3,1,,EPCR,Y
ESOL,4,1,,EPCR,EQV
PRVAR,2,3,4
/AXLAB,X,TIME
/AXLAB,Y,CREEP STRAIN
PLVAR,2,3,4
/POST1
SET,1,1
*GET,SH1,NODE,3,EPCR,X
R1=1.0
SET,2,1
*GET,SH2,NODE,3,EPCR,X
R2=SH2/0.0427
SET,3,1
*GET,SH3,NODE,3,EPCR,X
R3=SH3/0.135
SET,4,1
*GET,SH4,NODE,3,EPCR,X
R4=SH4/0.3019
SET,,,,,,,5
*GET,SH5,NODE,3,EPCR,X
R5=SH5/0.4269
SET,,,,,,,9
*GET,SH6,NODE,3,EPCR,X
R6=SH6/0.9546
SET,,,,,,,14
*GET,SH7,NODE,3,EPCR,X
R7=SH7/1.35
SET,,,,,,,54
*GET,SH8,NODE,3,EPCR,X
R8=SH8/3.019
SET,,,,,,,104
*GET,SH9,NODE,3,EPCR,X
R9=SH9/4.2691
*DIM,VALUE,,9,3
*DIM,LABEL,CHAR,10
LABEL(1) = '0','0.1', '1.0', '5.0', '10.0', '50.0','100.0','500.0','1000.0'
*VFILL,VALUE(1,1),DATA,0.0000,0.0427,0.1350,0.3019,0.4269,0.9546,1.3500,3.0190,4.2691
*VFILL,VALUE(1,2),DATA,SH1,SH2,SH3,SH4,SH5,SH6,SH7,SH8,SH9
*VFILL,VALUE(1,3),DATA,R1,R2,R3,R4,R5,R6,R7,R8,R9
/POST1
SET,1,1
*GET,SH11,NODE,3,EPCR,EQV
R11=1.0
SET,2,1
*GET,SH21,NODE,3,EPCR,EQV
R21=SH21/(0.0493)
SET,3,1
*GET,SH31,NODE,3,EPCR,EQV
R31=SH31/(0.1559)
SET,4,1
*GET,SH41,NODE,3,EPCR,EQV
R41=SH41/(0.3486)
SET,,,,,,,5
*GET,SH51,NODE,3,EPCR,EQV
R51=SH51/(0.4930)
SET,,,,,,,9
*GET,SH61,NODE,3,EPCR,EQV
R61=SH61/(1.1024)
SET,,,,,,,14
*GET,SH71,NODE,3,EPCR,EQV
R71=SH71/(1.5590)
SET,,,,,,,54
*GET,SH81,NODE,3,EPCR,EQV
R81=SH81/(3.4861)
SET,,,,,,,104
*GET,SH91,NODE,3,EPCR,EQV
R91=SH91/(4.9300)
*DIM,VALUE1,,9,3
*DIM,LABEL1,CHAR,10
LABEL1(1) = '0','0.1', '1.0', '5.0', '10.0', '50.0','100.0','500.0','1000.0'
*VFILL,VALUE1(1,1),DATA,0.0000,0.0493,0.1559,0.3486,0.4930,1.1024,1.5590,3.4861,4.9300
*VFILL,VALUE1(1,2),DATA,SH11,SH21,SH31,SH41,SH51,SH61,SH71,SH81,SH91
*VFILL,VALUE1(1,3),DATA,R11,R21,R31,R41,R51,R61,R71,R81,R91
/COM
/COM
/COM,------------ vmr027-cr10a-281 RESULTS COMPARISON ---------------
/COM,
/COM, vmr027-cr10a-281.jpeg RESULTS SHOULD MATCH R0027 NAFEMS MANUAL
/COM, GRAPH AND NUMERICAL RESULTS IN TEST 10(A).
/COM,
/COM,--------- CREEP STRAIN RESULTS IN X DIRECTION ----------
/COM,
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL(1), VALUE(1,1), VALUE(1,2), VALUE(1,3)
(1X,A8,'   ',F8.3,'   ',F13.3,'   ',1F5.3)
/COM
/COM,----------- CREEP EFFECTIVE STRAIN RESULTS -------------
/COM,
/COM,|   TIME   | TARGET |   Mechanical APDL  |   RATIO
/COM,
*VWRITE,LABEL1(1), VALUE1(1,1), VALUE1(1,2), VALUE1(1,3)
(1X,A8,'   ',F8.3,'   ',F13.3,'   ',1F5.3)
FINISH
/POST26
*DIM,LABEL3,CHAR,2
*DIM,VALUE2,,2,3
LABEL3(1) = ' ECR6X ',' EFFCR '
*VFILL,VALUE2(1,1),DATA,SH9,SH91
*VFILL,VALUE2(1,2),DATA,R9,R91
*DIM,LABEL2,CHAR,3
LABEL2(1) = 'vmr027-','cr10a-28','1'
/OUT,vmr027-cr10a-281,vrt
/COM
/COM,------------------- vmr027-cr10a RESULTS COMPARISON ---------------------
/COM,
/COM,            |   Mechanical APDL   |   RATIO  |         INPUT         |
/COM,
/COM, SHELL281
*VWRITE,LABEL3(1),VALUE2(1,1),VALUE2(1,2),LABEL2(1),LABEL2(2),LABEL2(3)
(1X,A8,'      ',F13.3,'      ',F9.4,'     ',A7,A8,A8)
*VWRITE,LABEL3(2),VALUE2(2,1),VALUE2(2,2),LABEL2(1),LABEL2(2),LABEL2(3)
(1X,A8,'      ',F13.3,'      ',F9.4,'     ',A7,A8,A8)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmr027-cr10a-281,vrt