/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VMP09-T12-181
/TITLE,VMP09-T12-181,FREE THIN SQUARE PLATE
/COM,REFERENCE: NAFEMS FVB MANUAL TEST 12
/NOPR
/PREP7
ET,1,181
SECTYPE,1,SHELL
SECDATA,0.05,1,0,3
MP,EX,1,200E9
MP,NUXY,1,0.3
MP,DENS,1,8000
K,1
K,2,10
K,3,10,10
K,4,,10
A,1,2,3,4
ESIZE,,8
AMESH,1
D,ALL,UX,0,0,,,UY,ROTZ
FINISH
/SOLU
ANTYPE,MODAL,NEW
MODOPT,LANB,10
MXPAND,10,0,0,0
/OUT,SCRATCH
SOLVE
/OUT
FINISH
/POST1
*DIM,FREQ,ARRAY,7
*GET,FREQ(1,1),MODE,4,FREQ
*GET,FREQ(2,1),MODE,5,FREQ
*GET,FREQ(3,1),MODE,6,FREQ
*GET,FREQ(4,1),MODE,7,FREQ
*GET,FREQ(5,1),MODE,8,FREQ
*GET,FREQ(6,1),MODE,9,FREQ
*GET,FREQ(7,1),MODE,10,FREQ
R1=FREQ(1,1)/1.622
R2=FREQ(2,1)/2.36
R3=FREQ(3,1)/2.922
R4=FREQ(4,1)/4.233
R5=FREQ(5,1)/4.233
R6=FREQ(6,1)/7.416
R7=FREQ(7,1)/8.027
*DIM,VALUE,,7,2
*DIM,LABEL,CHAR,10
*DIM,RATIO,,7,1
LABEL(1) = 'FREQ 4','FREQ 5','FREQ 6','FREQ 7','FREQ 8','FREQ 9','FREQ 10'
*VFILL,VALUE(1,1),DATA,1.622,2.36,2.922,4.233,4.233,7.416,8.027
*VFILL,VALUE(1,2),DATA,FREQ(1,1),FREQ(2,1),FREQ(3,1),FREQ(4,1),FREQ(5,1),FREQ(6,1),FREQ(7,1)
*VFILL,RATIO(1,1),DATA,R1,R2,R3,R4,R5,R6,R7
/COM
/COM,------------- VMP09-T12-181 RESULTS COMPARISON ------------------
/COM,
/COM, | TARGET | Mechanical APDL | RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),RATIO(1,1)
(1X,A8,' ',F10.3,' ',F14.3,' ',1F13.3)
FINISH
/POST26
*DIM,LABEL1,CHAR,6
*DIM,VALUE1,,6,2
LABEL1(1) = ' MODE4',' MODE5',' MODE6',' MODE7,8',' MODE9',' MODE10'
*VFILL,VALUE1(1,1),DATA,FREQ(1,1),FREQ(2,1),FREQ(3,1),FREQ(5,1),FREQ(6,1),FREQ(7,1)
*VFILL,VALUE1(1,2),DATA,R1,R2,R3,R5,R6,R7
*DIM,LABEL2,CHAR,6
*DIM,LABEL3,CHAR,6
LABEL2(1) = 'vmp09-t1','vmp09-t1','vmp09-t1','vmp09-t1','vmp09-t1','vmp09-t1'
LABEL3(1) = '2-181','2-181','2-181','2-181','2-181','2-181'
/OUT,vmp09-t12-181,vrt
/COM
/COM,------------------- VMP09-T12 RESULTS COMPARISON ---------------------
/COM,
/COM, | Mechanical APDL | RATIO | INPUT |
/COM,
/COM, SHELL181
*VWRITE,LABEL1(1),VALUE1(1,1),VALUE1(1,2),LABEL2(1),LABEL3(1)
(1X,A8,' ',F13.3,' ',F9.4,' ',A8,A5)
/COM,
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,vmp09-t12-181,vrt
