/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/verify,vmr020-t8b-183
/title,vmr020-t8b-183,V-notch crack plate: Uniform normal displacement
/com,
/com, Problem is taken from NAFEMS Publication
/com, "2D Test Cases in Linear Elastic Fracture Mechanics"
/com, Test case 8.2
/com,
/com, Reference: No rference available
/com,
/com,
/com, **********************************************************
/com, Stress Intensity Factor Calculation using Interaction
/com, Integral Approach
/prep7
e=207000000 !youngs modulus
nu=0.3 !poissons ratio
a=5 !crack length
sig=76700
pi=3.141593
et,1,plane183,,,2 !plane183 elements
mp,ex,1,e
mp,nuxy,1,nu
k,1,25,0
k,2,30,0
k,3,100,0
k,4,250,0
k,5,250,100
k,6,250,250
k,7,0,250
k,8,0,100
k,9,0,25
k,10,100,100
l,1,2
*rep,8,1,1
l,9,1
l,3,10
l,8,10
l,10,5
al,1,2,10,11,8,9
al,3,4,12,10
al,5,6,7,11,12
esize,25
amesh,3
amesh,2
kscon,2,1.4,1,4,0.75 !crack tip elements
amesh,1
fini
/solu
nlgeom,on
autots,on
nsubst,10
outres,all,all
nsel,s,loc,y,0,250
nsel,r,loc,x,250
d,all,ux,0
nsel,all
nsel,s,loc,x,30,250
nsel,r,loc,y,0
d,all,uy,0
nsel,all
nsel,s,loc,x,0,250
nsel,r,loc,y,250
d,all,uy,0.1
nsel,all
nsel,s,loc,x,30
nsel,r,loc,y,0
cm,crack1,node !define crack tip node component
cint,new,1
cint,type,sifs !calculate stress intensity values
cint,name,crack1 !crack ID
cint,ncon,4 !number of contours
cint,symm,on !symmetry on
cint,norm,0,2
cint,list
allsel,all
solve
fini
/out,scratch
/post1
prcint,1,,k1
*get,k1_1,cint,1,ctip,node(30,0,0),,1,dtype,k1
*get,k1_2,cint,1,ctip,node(30,0,0),,2,dtype,k1
*get,k1_3,cint,1,ctip,node(30,0,0),,3,dtype,k1
*get,k1_4,cint,1,ctip,node(30,0,0),,4,dtype,k1
con1 = ((pi*a)**0.5)
k1=(k1_1+k1_2+k1_3+k1_4)/4
k0=(sig*con1)
norm_sif=k1/k0
/out,
*stat,norm_sif
*DIM,LABEL,CHAR,1,5
*DIM,VALUE,,1,3
LABEL(1,1) = 'KI'
*VFILL,VALUE(1,1),DATA,3.226
*VFILL,VALUE(1,2),DATA,norm_sif
*VFILL,VALUE(1,3),DATA,ABS(norm_sif/3.226 )
SAVE,TABLE_1
FINI
/CLEAR,NOSTART
/com,*******************************************************************************************
/com, Using J Integral Approach
/prep7
e=207000000 !youngs modulus
nu=0.3 !poissons ratio
a=5 !crack length
sig=76700
pi=3.141593
et,1,plane183,,,2 !plane183 elements
mp,ex,1,e
mp,nuxy,1,nu
k,1,25,0
k,2,30,0
k,3,100,0
k,4,250,0
k,5,250,100
k,6,250,250
k,7,0,250
k,8,0,100
k,9,0,25
k,10,100,100
l,1,2
*rep,8,1,1
l,9,1
l,3,10
l,8,10
l,10,5
al,1,2,10,11,8,9
al,3,4,12,10
al,5,6,7,11,12
esize,25
amesh,3
amesh,2
kscon,2,1.25,1,4,0.75 !crack tip elements
amesh,1
fini
/solu
autots,on
nsubst,10
outres,all,all
nsel,s,loc,y,0,250
nsel,r,loc,x,250
d,all,ux,0
nsel,all
nsel,s,loc,x,30,250
nsel,r,loc,y,0
d,all,uy,0
nsel,all
nsel,s,loc,x,0,250
nsel,r,loc,y,250
d,all,uy,0.1
nsel,all
nsel,s,loc,x,30
nsel,r,loc,y,0
cm,crack1,node !define crack tip node component
cint,new,1
cint,name,crack1 !crack ID
cint,ncon,4 !number of contours
cint,symm,on !symmetry on
cint,norm,0,2
cint,list
allsel,all
solve
fini
/out,scratch
/post1
prcint,1
*get,j1,cint,1,ctip,node(30,0,0),,1,,
*get,j2,cint,1,ctip,node(30,0,0),,2,,
*get,j3,cint,1,ctip,node(30,0,0),,3,,
*get,j4,cint,1,ctip,node(30,0,0),,4,,
j_avg=(abs(j1)+abs(j2)+abs(j3)+abs(j4))/4
con1 = ((pi*a)**0.5)
con2 = E/(1-(nu*nu))
k1 = ((con2*j_avg)**0.5)
k0=(sig*con1)
norm_sif=k1/k0
/out,
*stat,norm_sif
*DIM,LABEL,CHAR,1,5
*DIM,VALUE,,1,3
LABEL(1,1) = 'KI'
*VFILL,VALUE(1,1),DATA,3.226
*VFILL,VALUE(1,2),DATA,norm_sif
*VFILL,VALUE(1,3),DATA,ABS(norm_sif/3.226 )
SAVE,TABLE_2
/NOPR
/COM
/OUT,vmr020-t8b-183,vrt
/COM,------------------- vmr020-t8b-183 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | MECHANICAL APDL | RATIO
/COM,
RESUME,TABLE_1
/COM,USING STRESS INTENSITY FACTOR CALCULATION
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F12.3,' ',1F14.3)
/COM,
/COM,
/COM,
RESUME,TABLE_2
/COM,USING J-INTEGRAL APPROACH
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F12.3,' ',1F14.3)
/COM,
/COM,
/COM,
/COM,-----------------------------------------------------------------
/OUT
FINISH
*list,vmr020-t8b-183,vrt
