/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/verify,vmr020-t6a-183
/title,vmr020-t6a-183,Compact tension specimen
/com,
/com, Problem is taken from NAFEMS Publication
/com, "2D Test Cases in Linear Elastic Fracture Mechanics"
/com, Test case 6.0
/com,
/com, Reference: Murakami Y: Stress intensity factor handbook
/com, Pergamon Press (1987)
/com,
/com, **********************************************************
/com, Stress Intensity Factor Calculation using Interaction
/com, Integral Approach
/prep7
e=207000 !youngs modulus
nu=.3 !poissons ratio
P=1000 !point load
t=1 !thickness
w=50 !width
et,1,plane183,,,2 !plane183 elements, plane strain
mp,ex,1,e
mp,nuxy,1,nu
k,1,,
k,2,25,
k,3,25,6.875
k,4,25,13.75
k,5,25,30
k,6,-37.5,30
k,7,-37.5,13.75
k,8,-37.5,6.875
k,9,-25,6.875
k,10,-25,2
k,11,-18,2
k,12,-18,0
k,13,-25,13.75
l,1,2
*rep,11,1,1
l,12,1
l,9,3
l,7,13
l,13,4
al,1,2,13,9,10,11,12
al,3,15,14,7,8,13
al,4,5,6,14,15
esize,12.5
amesh,2
amesh,3
kscon,1,2,1,4,0.75 !crack tip elements
esize,12.5
amesh,1
fini
/solu
autots,on
nsubst,10
outres,all,all
nsel,s,loc,y,0
nsel,r,loc,x,0,25
d,all,uy,0
nsel,r,loc,x,25
d,all,ux,0
nsel,all
fk,13,fy,P
nsel,s,loc,x,0
nsel,r,loc,y,0
cm,crack1,node !define crack tip node components
cint,new,1
cint,type,sifs ! calculate stress intensity factors
cint,name,crack1 !crack ID
cint,ncon,4 !number of contours
cint,symm,on !symmetry on
cint,norm,0,2
cint,list
allsel,all
solve
fini
/out,scratch
/post1
prcint,1
*get,k1_1,cint,1,ctip,node(0,0,0),,1,dtype,k1
*get,k1_2,cint,1,ctip,node(0,0,0),,2,dtype,k1
*get,k1_3,cint,1,ctip,node(0,0,0),,3,dtype,k1
*get,k1_4,cint,1,ctip,node(0,0,0),,4,dtype,k1
k1_avg=(k1_1+k1_2+k1_3+k1_4)/4
k0=P/(t*(w)**0.5)
norm_sif=k1_avg/k0
/out,
*stat,norm_sif
*DIM,LABEL,CHAR,1,5
*DIM,VALUE,,1,3
LABEL(1,1) = 'KI'
*VFILL,VALUE(1,1),DATA,9.659
*VFILL,VALUE(1,2),DATA,norm_sif
*VFILL,VALUE(1,3),DATA,ABS(norm_sif/9.659 )
SAVE,TABLE_1
FINI
/CLEAR,NOSTART
/com,*************************************************************
/com, Using J integral Calculation
/prep7
e=207000 !youngs modulus
nu=.3 !poissons ratio
P=1000 !point load
t=1 !thickness
w=50 !width
et,1,plane183,,,2 !plane183 elements, plane strain
mp,ex,1,e
mp,nuxy,1,nu
k,1,,
k,2,25,
k,3,25,6.875
k,4,25,13.75
k,5,25,30
k,6,-37.5,30
k,7,-37.5,13.75
k,8,-37.5,6.875
k,9,-25,6.875
k,10,-25,2
k,11,-18,2
k,12,-18,0
k,13,-25,13.75
l,1,2
*rep,11,1,1
l,12,1
l,9,3
l,7,13
l,13,4
al,1,2,13,9,10,11,12
al,3,15,14,7,8,13
al,4,5,6,14,15
esize,12.5
amesh,2
amesh,3
kscon,1,2,1,4,0.75 !crack tip elements
esize,12.5
amesh,1
fini
/solu
autots,on
nsubst,10
outres,all,all
nsel,s,loc,y,0
nsel,r,loc,x,0,25
d,all,uy,0
nsel,r,loc,x,25
d,all,ux,0
nsel,all
fk,13,fy,P
nsel,s,loc,x,0
nsel,r,loc,y,0
cm,crack1,node !define crack tip node components
cint,new,1
cint,ctnc,crack1 !crack ID
cint,ncon,4 !number of contours
cint,symm,on !symmetry on
cint,norm,0,2
cint,list
allsel,all
solve
fini
/out,scratch
/post1
prcint,1
*get,j1,cint,1,ctip,node(0,0,0),,1,,
*get,j2,cint,1,ctip,node(0,0,0),,2,,
*get,j3,cint,1,ctip,node(0,0,0),,3,,
*get,j4,cint,1,ctip,node(0,0,0),,4,,
j_avg=(abs(j1)+abs(j2)+abs(j3)+abs(j4))/4
con2 = E/(1-(nu*nu))
k1 = ((con2*j_avg)**0.5)
k0=P/(t*(w)**0.5)
norm_sif=k1/k0
/out,
*stat,norm_sif
*DIM,LABEL,CHAR,1,5
*DIM,VALUE,,1,3
LABEL(1,1) = 'KI'
*VFILL,VALUE(1,1),DATA,9.659
*VFILL,VALUE(1,2),DATA,norm_sif
*VFILL,VALUE(1,3),DATA,ABS(norm_sif/9.659 )
SAVE,TABLE_2
/NOPR
/COM
/OUT,vmr020-t6a-183,vrt
/COM,------------------- vmr020-t6a-183 RESULTS COMPARISON ---------------------
/COM,
/COM, | TARGET | MECHANICAL APDL | RATIO
/COM,
RESUME,TABLE_1
/COM,USING STRESS INTENSITY FACTOR CALCULATION
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F12.3,' ',1F16.3)
/COM,
/COM,
/COM,
RESUME,TABLE_2
/COM,USING J-INTEGRAL APPROACH
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,' ',F10.3,' ',F12.3,' ',1F16.3)
/COM,
/COM,
/COM,
/COM,-------------------------------------------------------------------------------
/OUT
FINISH
*list,vmr020-t6a-183,vrt
