/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VM321
/COM,   REF: A HEAT TRANSFER TEXTBOOK (3RD EDITION)
/COM,        BY JOHN H. LIENHARD IV AND JOHN H. LIENHARD V
/COM,
/TITLE, VM321, 2-D THERMAL RADIATION BETWEEN A FIXED AND MOVING PLATE
/OUT,vm321_scratch

/COM, PARAMETER FOR CREATING THE CDB FILES TO STORE GEOMETRY AND MESH DATA
_GEOMGEN = 0   ! SET TO 1 TO WRITE CDB FILES IF ANY INPUT FILE MODIFICATIONS

*IF,_GEOMGEN,EQ,1,THEN

HEIGHT = 10
THICKNESS = 1
T_INF = 500                    ! SPACE TEMPERATURE OF ENCLOSURE 1
T1 = 1000                      ! TEMPERATURE OF PLATE 1 (C)
GAP = 5                        ! INITIAL SEPARATION BETWEEN THE 2 PLATES
OFFT = 273
DISP_X = 10                    ! TOTAL DISPLACEMENT OF PLATE 2 IN THE X-DIRECTION
TOT_TIME = 50                  ! TOTAL TIME
NUM_SBSTEPS = 10               ! NUMBER OF SUB STEPS
SB = 5.67E-8                   ! STEFAN BOLTZMANN CONSTANT (W/m^2/K^4)
EMIS = 1.0                     ! EMISSIVITY

/PREP7

! DEFINING COUPLED PHYSICS ELEMENT 222 WITH STRCTURAL-THERMAL DOFS
ET,1,222,11

! GEOMETRY CREATION OF PLATE 1 AND 2
RECTNG,0,THICKNESS,0,HEIGHT
RECTNG,THICKNESS+GAP,GAP+2*THICKNESS,0,HEIGHT

! MESHING OF PLATE 1 AND 2
LESIZE,all,,,10
AMESH,all

! DEFINING MATERIAL PROPERTIES

MP,EX,1,1e6                   ! ELASTIC MODULUS (Pa)
MP,PRXY,1,0                   ! POISSON'S RATIO
MP,KXX,1,8                    ! THERMAL CONDUCTIVITY ALONG X-DIRECTION (W/m K)
MP,C,1,3                      ! SPECIFIC HEAT (J Kg^-1 K^-1)
MP,DENS,1,50                  ! DENSITY (Kg m^-3)

! APPLY FIXED CONSTRAINT ON PLATE 1

ASEL,S,AREA,,1
NSLA,S,1
D,all,UX,0
D,all,UY,0
ALLSEL

! APPLY CONSTRAINTS TO MOVE PLATE 2 ALONG X DIRECTION AWAY FROM PLATE 1

*DIM,U1,TABLE,2,1,1,TIME
U1(1,0)=0, TOT_TIME
U1(1,1)=0, DISP_X

ASEL,S,AREA,,2
NSLA,S,1

D,ALL,UX,%U1%
D,ALL,UY,0
ALLSEL

! APPLY CONSTRAINT ON TEMPERATURE FOR PLATE 1

ASEL,S,AREA,,1
NSLA,S,1
D,ALL,TEMP,T1
ALLSEL

! APPLY RADIATION BETWEEN SURFACES OF PLATE 1 AND 2

NSEL,S,LOC,X,THICKNESS
SF,ALL,RDSF,EMIS,1
NSEL,ALL

NSEL,S,LOC,X,THICKNESS+GAP
SF,ALL,RDSF,EMIS,1
NSEL,ALL

! APPLY CONSTRAINT EQUATION ON ALL NODES OF PLATE 2

ASEL,S,AREA,,2
NSLA,S,1
NMAS = NDNEXT(0)
NSLAV = NDNEXT(NMAS)
*DOWHILE,NSLAV
 CE,NEXT,0,NMAS,TEMP,1.0,NSLAV,TEMP,-1.0     ! SETTING AN ISOTHERMAL CONDITION FOR ALL NODES OF PLATE 2
 NSLAV = NDNEXT(NSLAV)
*ENDDO
ALLSEL
CELIST

TOFFST,OFFT
FINISH

CDWRITE,DB,vm321,cdb
*ELSE
CDREAD,DB,vm321,cdb
*ENDIF

/AUX12

STEF,5.67E-8                ! SPECIFYING STEFAN BOLTZMANN CONSTANT (W/M^2/K^4)
SPCTEMP,1,T_INF             ! SPECIFYING SPACE TEMPERATURE FOR ENCLOSURE 1
VFSM,,1,3                   ! VIEW FACTOR SMOOTHING
MPRINT,1

RSURF                       ! GENERATE 251 ELEMENTS

ETLIST

/PREP7
KEYOPT,2,1,1                ! ACTIVATE DISPLACEMENT DOFS FOR SURF 251 ELEMENTS

/SOLU

ALLSEL
OUTRES,ALL,ALL
NLGEOM,ON                          ! LARGE DEFLECTION ON
AUTOTS,OFF
VFUP,DEFA                          ! VIEW FACTOR UPDATES SET TO DEFAULT
VFUP,DEFI,ON                       ! DEFINE VIEW FACTOR UPDATES
VFUP,DEFI,FRQU,1,-1                ! VIEW FACTOR UPDATES AT EVERY SUBSTEP DURING 1ST PASS
VFUP,STAT                          ! REQUEST STATUS OF VIEW FACTOR UPDATES
RADOPT,,1.E-12,2,1000,1.E-12,1.0   ! RADIOSITY SOLVER SET TO JACOBI ITERATIVE SOLVER
V2DOPT,0,,1,900                    ! SETTING PLANAR VIEW FACTOR CALCULATION OPTIONS
CNVTOL,TEMP,,1.E-9                 ! SETTING CONVERGENCE TOLERANCE ON TEMPERATURE
CNVTOL,HEAT,,1.E-9                 ! SETTING CONVERGENCE TOLERANCE ON HEAT
KBC,1                              ! STEPPED LOAD

TIME,TOT_TIME                      ! SETTING TIME FOR ANALYSIS
NSUB,NUM_SBSTEPS                   ! SETTING NUMBER OF SUBSTEPS
SOLVE

FINISH

/POST1

*DIM,T2,ARRAY,NUM_SBSTEPS,10,       ! CREATING A STORAGE ARRAY OF SIZE (NUM_SBSTEPS X 7)
*DO,I,1,NUM_SBSTEPS,1               ! LOOPING OVER THE NUMBER OF SUBSTEPS
SET,1,I
*GET,TEMP2,NODE,NMAS,TEMP
T2(I,1) = GAP+I/NUM_SBSTEPS*DISP_X

 N1 = NODE(GAP+2*THICKNESS,0,0)         ! SELECTING A NODE ON PLATE 2
 T2MAPDL = TEMP(N1)                     ! MAPDL RESULT OF TEMPERATURE OF PLATE 2
 RATIO = (GAP+UX(N1))/(HEIGHT)
 F12 = (1.+RATIO**2)**0.5 - RATIO       ! VIEW FACTOR CALCULATION
 T2ANAL = F12* ( (T1+OFFT)**4 - (T_INF+OFFT)**4 )
 T2ANAL = T2ANAL + (T_INF+OFFT)**4
 T2ANAL = T2ANAL**0.25
 T2ANAL = T2ANAL - OFFT                 ! ANALYTICAL TEMPERATURE OF PLATE 1
T2(I,2) = T2ANAL

T2(I,3) = TEMP2

T2(I,4) = T2(I,2)/T2(I,3)

ALLSEL
ESEL,S,TYPE,,2
ESEL,U,CENT,X,THICKNESS+GAP             ! SELECTING ONLY SURF 251 ELEMENTS ON PLATE 1
ETABLE,RADA,NMISC,4                     ! STORING RADIATION AREA OF ELEMENTS IN A TABLE
SSUM
*GET,AREA_SUM,SSUM,0,ITEM,RADA          ! STORING THE SUM OF RADIATION AREAS

ETABLE,RADNF,NMISC,7
SMULT,NET_FLUX,RADA,RADNF,1.0/AREA_SUM,1.0      ! MULTIPLYING AREA TIMES FLUX AND DIVING BY TOTAL AREA
SSUM

*GET,RAD_NET_FLUX,SSUM,0,ITEM,NET_FLUX          ! SUMMING UP THE RESULTS OF THE PREVIOUS RESULT TO GET AREA AVERAGE FLUX

Q1NET_MAPDL = RAD_NET_FLUX                      ! MAPDL HEAT FLUX RESULT

Q1NET_ANALYT = F12*((T2ANAL + OFFT)**4 - (T_INF + OFFT)**4)
Q1NET_ANALYT = Q1NET_ANALYT + (T_INF + OFFT)**4
Q1NET_ANALYT = (T1 + OFFT)**4 - Q1NET_ANALYT
Q1NET_ANALYT = SB*Q1NET_ANALYT                  ! ANALYTICAL HEAT FLUX RESULT

T2(I,5) = Q1NET_ANALYT

T2(I,6) = Q1NET_MAPDL

T2(I,7) = T2(I,5)/T2(I,6)

T2(I,8) = Q1NET_ANALYT*HEIGHT       ! MULTIPLYING HEAT FLUX BY AREA TO GET TOTAL HEAT

ALLSEL
ESEL,S,TYPE,,2                      ! SELECTING 251 SURF ELEMENTS
ETABLE,RADA,NMISC,4                 ! STORING RADIATION AREAS IN A TABLE
ETABLE,RADNF,NMISC,7                ! STORING RADIATION FLUXES IN A TABLE
SMULT,HEAT_ELEM,RADA,RADNF,1.0,1.0  ! MULTIPLYING AREAS AND FLUXES TO GET TOTAL HEAT
SSUM
*GET,TOT_HEAT,SSUM,0,ITEM,HEAT_ELEM ! SUMMING UP THE TOTAL HEAT FOR ALL SURF 251 ELEMENTS

T2(I,9) = TOT_HEAT                  ! MAPDL HEAT (LOST BY ENCLOSURE 1)

T2(I,10) = T2(I,8)/T2(I,9)

*ENDDO

/OUT,vm321,vrt

/COM, ==============================================================================
/COM,                         TEMPERATURE OF PLATE 2
/COM, ==============================================================================
/COM,
/COM,       DISTANCE       TARGET       MECHANICAL        RATIO
/COM,  BETWEEN PLATES(M)     (C)         APDL (C)
/COM,
/COM,
*VWRITE,T2(1,1),T2(1,2),T2(1,3),T2(1,4)
%14.2f %14.2f %14.2f %14.2f


/COM, ==============================================================================
/COM,                          HEAT FLUX FROM PLATE 1
/COM, ==============================================================================
/COM,
/COM,       DISTANCE       TARGET      MECHANICAL         RATIO
/COM,  BETWEEN PLATES(M)   (W/M^2)     APDL (W/M^2)
/COM,
/COM,
*VWRITE,T2(1,1),T2(1,5),T2(1,6),T2(1,7)
%14.2f %14.2f %14.2f %14.2f


/COM, ==============================================================================
/COM,                               HEAT BALANCE
/COM, ==============================================================================
/COM,
/COM,       DISTANCE       TARGET      MECHANICAL         RATIO
/COM,  BETWEEN PLATES(M)    (W)         APDL (W)
/COM,
/COM,
*VWRITE,T2(1,1),T2(1,8),T2(1,9),T2(1,10)
%14.2f %14.2f %14.2f %14.2f

FINISH
/OUT
*LIST,vm321,vrt