/COM,ANSYS MEDIA REL. 2024R2 (05/10/2024) REF. VERIF. MANUAL: REL. 2024R2
/VERIFY,VM254
/TITLE, VM254, CAMPBELL DIAGRAMS AND CRITICAL SPEEDS USING SYMMETRIC ORTHOTROPIC BEARINGS
/COM,   REF: "THE DYNAMICS OF ROTOR-BEARING SYSTEMS USING FINITE ELEMENTS"
/COM,   JOURNAL OF ENG. FOR INDUSTRY - MAY 1976, PG: 598-600
C***    USING PIPE16
/COM
/OUT,SCRATCH
/PREP7
*DIM,SPIN,,6		                         ! SPIN VELOCITY (RPM)
SPIN(1) = 1000.
SPIN(2) = 20000.
SPIN(3) = 40000.
SPIN(4) = 60000.
SPIN(5) = 80000.
SPIN(6) = 100000.
RO = 7806                                        ! MATERIAL : STEEL
PEX = 2.078E+11
PGXY = 1.E+14 		                         ! NO SHEAR
MP,EX,1,PEX
MP,PRXY,1,0.3
MP,DENS,1,RO
MP,GXY,1,PGXY

ET,1,PIPE16                                      ! ELEMENT TYPE # 1: SHAFT
NBDIAM = 18                                      ! SHAFT SECTION PROPERTIES
*DIM,DIAM,ARRAY,NBDIAM
DIAM(1) = 1.02E-2
DIAM(2) = 2.04E-2
DIAM(3) = 1.52E-2
DIAM(4) = 4.06E-2
DIAM(5) = DIAM(4)
DIAM(6) = 6.6E-2
DIAM(7) = DIAM(6)
DIAM(8) = 5.08E-2
DIAM(9) = DIAM(8)
DIAM(10) = 2.54E-2
DIAM(11) = DIAM(10)
DIAM(12) = 3.04E-2
DIAM(13) = DIAM(12)
DIAM(14) = 2.54E-2
DIAM(15) = DIAM(14)
DIAM(16) = 7.62E-2
DIAM(17) = 4.06E-2
DIAM(18) = DIAM(17)
*DO,I,1,NBDIAM
   R,I,DIAM(I),DIAM(I)/2
*ENDDO
R,7,DIAM(7),(DIAM(7)-3.04E-2)/2
R,8,DIAM(8),(DIAM(8)-3.56E-2)/2
R,18,DIAM(18),(DIAM(18)-3.04E-2)/2

ET,2,MASS21                                    ! ELEMENT TYPE # 2: MASS
R,20,1.401,1.401,1.401,0.002,0.00136,0.00136

ET,3,COMBI214                                  ! ELEMENT TYPE # 3: BEARING ELEMENT
KEYOPT,3,2,1                                   ! YZ PLANE
KEYOPT,3,3,0                                   ! ELEMENT IS SYMMETRIC
R,30,3.503E+7,3.503E+7,-8.756E+6,-8.756E+6,,   ! REAL CONSTANTS ( K11,K22,K12,K21) NO DAMPING

ET,4,COMBI214
KEYOPT,4,2,1                                   ! YZ PLANE
KEYOPT,4,3,0                                   ! ELEMENT IS SYMMETRIC
R,40,3.503E+7,3.503E+7,-8.756E+6,-8.756E+6,,   ! REAL CONSTANTS ( K11,K22,K12,K21) NO DAMPING

/COM, NODES
N,1 ,0.
N,2 ,1.27E-2
N,3 ,5.08E-2
N,4 ,7.62E-2
N,5 ,8.89E-2
N,6 ,10.16E-2
N,7 ,10.67E-2
N,8 ,11.43E-2
N,9 ,12.7E-2
N,10,13.46E-2
N,11,16.51E-2
N,12,19.05E-2
N,13,22.86E-2
N,14,26.67E-2
N,15,28.7E-2
N,16,30.48E-2
N,17,31.5E-2
N,18,34.54E-2
N,19,35.5E-2

BRG = 0.1		                             ! BEARING "LENGTH" FOR VISUALISATION
N,20,16.51E-2,BRG
N,22,28.7E-2,BRG

/COM, ELEMENTS
/COM, SHAFT
TYPE,1
MAT,1
*DO,I,1,NBDIAM
REAL,I
   E,I,I+1
*ENDDO

/COM, DISK
TYPE,2
REAL,20
E,5

/COM, BEARINGS
TYPE,3
REAL,30
E,11,20
TYPE,4
REAL,40
E,15,22
ALLSEL,ALL
FINI
/SOLU
D,ALL,UX                                      ! NO TRACTION AND TORSION
D,ALL,ROTX
D,20,ALL                                      ! SECOND NODES OF BEARING
D,22,ALL

/COM, MODAL
RATIO = 4*ATAN(1)/30
ANTYPE,MODAL
CORIOLIS,ON,,,ON
NBF = 20
MODOPT,DAMP,NBF,,,ON
*DO,I,1,6
   OMEGA,SPIN(I)*RATIO                       ! UNIT FOR OMEGA IS RAD/SEC
   MXPAND,NBF
   SOLVE
*ENDDO
FINI

/POST1
/OUT,
PRCAMP,,1.,RPM
PLCAMP,,1.,RPM
*GET,F1,CAMP,1,FREQ,6
*GET,F2,CAMP,2,FREQ,6
*GET,F3,CAMP,3,FREQ,6
*GET,F4,CAMP,4,FREQ,6
*DIM,LABEL,CHAR,1,4
*DIM,VALUE,ARRAY,4,3

LABEL(1,1) = 'WHIRL BW'
LABEL(1,2) = 'WHIRL FW'
LABEL(1,3) = 'WHIRL BW'
LABEL(1,4) = 'WHIRL FW'
*VFILL,VALUE(1,1),DATA,10747
*VFILL,VALUE(1,2),DATA,F1*60
*VFILL,VALUE(1,3),DATA,ABS((F1*60)/10747)
*VFILL,VALUE(2,1),DATA,19665
*VFILL,VALUE(2,2),DATA,F2*60
*VFILL,VALUE(2,3),DATA,ABS((F2*60)/19665)
*VFILL,VALUE(3,1),DATA,39077
*VFILL,VALUE(3,2),DATA,F3*60
*VFILL,VALUE(3,3),DATA,ABS((F3*60)/39077)
*VFILL,VALUE(4,1),DATA,47549
*VFILL,VALUE(4,2),DATA,F4*60
*VFILL,VALUE(4,3),DATA,ABS((F4*60)/47549)
SAVE,TABLE_1
FINI
/CLEAR,NOSTART


!*********************************************************************


C***   	USING PIPE288
/OUT,SCRATCH
/PREP7
*DIM,SPIN,,6		                         ! SPIN VELOCITY (RPM)
SPIN(1) = 1000.
SPIN(2) = 20000.
SPIN(3) = 40000.
SPIN(4) = 60000.
SPIN(5) = 80000.
SPIN(6) = 100000.
RO = 7806                                        ! MATERIAL : STEEL
PEX = 2.078E+11
PGXY = 1.E+14 		                         ! NO SHEAR
MP,EX,1,PEX
MP,PRXY,1,0.3
MP,DENS,1,RO
MP,GXY,1,PGXY

ET,1,PIPE288                                      ! ELEMENT TYPE # 1: SHAFT
KEYOPT,1,3,3
KEYOPT,1,4,2
NBDIAM = 18                                      ! SHAFT SECTION PROPERTIES
*DIM,DIAM,ARRAY,NBDIAM
DIAM(1) = 1.02E-2
DIAM(2) = 2.04E-2
DIAM(3) = 1.52E-2
DIAM(4) = 4.06E-2
DIAM(5) = DIAM(4)
DIAM(6) = 6.6E-2
DIAM(7) = DIAM(6)
DIAM(8) = 5.08E-2
DIAM(9) = DIAM(8)
DIAM(10) = 2.54E-2
DIAM(11) = DIAM(10)
DIAM(12) = 3.04E-2
DIAM(13) = DIAM(12)
DIAM(14) = 2.54E-2
DIAM(15) = DIAM(14)
DIAM(16) = 7.62E-2
DIAM(17) = 4.06E-2
DIAM(18) = DIAM(17)
*DO,I,1,NBDIAM
SECTYPE,I,PIPE
   SECDATA,DIAM(I),DIAM(I)/2
*ENDDO
SLIST

SECTYPE,7,PIPE
SECDATA,DIAM(7),(DIAM(7)-3.04E-2)/2
SECTYPE,8,PIPE
SECDATA,DIAM(8),(DIAM(8)-3.56E-2)/2
SECTYPE,18,PIPE
SECDATA,DIAM(18),(DIAM(18)-3.04E-2)/2

ET,2,MASS21                                    ! ELEMENT TYPE # 2: MASS
R,20,1.401,1.401,1.401,0.002,0.00136,0.00136

ET,3,COMBI214                                  ! ELEMENT TYPE # 3: BEARING ELEMENT
KEYOPT,3,2,1                                   ! YZ PLANE
KEYOPT,3,3,0                                   ! ELEMENT IS SYMMETRIC
R,30,3.503E+7,3.503E+7,-8.756E+6,-8.756E+6,,   ! REAL CONSTANTS ( K11,K22,K12,K21) NO DAMPING

ET,4,COMBI214
KEYOPT,4,2,1                                   ! YZ PLANE
KEYOPT,4,3,0                                   ! ELEMENT IS SYMMETRIC
R,40,3.503E+7,3.503E+7,-8.756E+6,-8.756E+6,,   ! REAL CONSTANTS ( K11,K22,K12,K21) NO DAMPING

/COM, NODES
N,1 ,0.
N,2 ,1.27E-2
N,3 ,5.08E-2
N,4 ,7.62E-2
N,5 ,8.89E-2
N,6 ,10.16E-2
N,7 ,10.67E-2
N,8 ,11.43E-2
N,9 ,12.7E-2
N,10,13.46E-2
N,11,16.51E-2
N,12,19.05E-2
N,13,22.86E-2
N,14,26.67E-2
N,15,28.7E-2
N,16,30.48E-2
N,17,31.5E-2
N,18,34.54E-2
N,19,35.5E-2

BRG = 0.1		                             ! BEARING "LENGTH" FOR VISUALISATION
N,20,16.51E-2,BRG
N,22,28.7E-2,BRG

/COM, ELEMENTS
/COM, SHAFT
TYPE,1
MAT,1
*DO,I,1,NBDIAM
SECNUM,I
   E,I,I+1
*ENDDO

/COM, DISK
TYPE,2
REAL,20
E,5

/COM, BEARINGS
TYPE,3
REAL,30
E,11,20
TYPE,4
REAL,40
E,15,22
ALLSEL,ALL
FINI
/SOLU
D,ALL,UX                                      ! NO TRACTION AND TORSION
D,ALL,ROTX
D,20,ALL                                      ! SECOND NODES OF BEARING
D,22,ALL

/COM, MODAL
RATIO = 4*ATAN(1)/30
ANTYPE,MODAL
CORIOLIS,ON,,,ON
NBF = 10
MODOPT,QRDAMP,NBF,,,ON
*DO,I,1,6
   OMEGA,SPIN(I)*RATIO                       ! UNIT FOR OMEGA IS RAD/SEC
   MXPAND,NBF
   SOLVE
*ENDDO
FINI

/POST1
/OUT,
PRCAMP,,1.,RPM,,,,,
PLCAMP,,1.,RPM,,,,,
*GET,F1,CAMP,1,FREQ,6
*GET,F2,CAMP,2,FREQ,6
*GET,F3,CAMP,3,FREQ,6
*GET,F4,CAMP,4,FREQ,6
*DIM,LABEL,CHAR,1,4
*DIM,VALUE,ARRAY,4,3

LABEL(1,1) = 'WHIRL BW'
LABEL(1,2) = 'WHIRL FW'
LABEL(1,3) = 'WHIRL BW'
LABEL(1,4) = 'WHIRL FW'
*VFILL,VALUE(1,1),DATA,10747
*VFILL,VALUE(1,2),DATA,F1*60
*VFILL,VALUE(1,3),DATA,ABS((F1*60)/10747)
*VFILL,VALUE(2,1),DATA,19665
*VFILL,VALUE(2,2),DATA,F2*60
*VFILL,VALUE(2,3),DATA,ABS((F2*60)/19665)
*VFILL,VALUE(3,1),DATA,39077
*VFILL,VALUE(3,2),DATA,F3*60
*VFILL,VALUE(3,3),DATA,ABS((F3*60)/39077)
*VFILL,VALUE(4,1),DATA,47549
*VFILL,VALUE(4,2),DATA,F4*60
*VFILL,VALUE(4,3),DATA,ABS((F4*60)/47549)
SAVE,TABLE_2
FINI
/CLEAR,NOSTART



/NOPR
/COM
/OUT,vm254,vrt
/COM,------------ VM254 RESULTS COMPARISON --------------
/COM,
/COM,         |   TARGET   |   Mechanical APDL   |   RATIO
/COM,
RESUME,TABLE_1
/COM,USING PIPE16
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
*VWRITE,LABEL(1,2),VALUE(2,1),VALUE(2,2),VALUE(2,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
*VWRITE,LABEL(1,3),VALUE(3,1),VALUE(3,2),VALUE(3,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
*VWRITE,LABEL(1,4),VALUE(4,1),VALUE(4,2),VALUE(4,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
/COM,
RESUME,TABLE_2
/COM,USING PIPE288
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
*VWRITE,LABEL(1,2),VALUE(2,1),VALUE(2,2),VALUE(2,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
*VWRITE,LABEL(1,3),VALUE(3,1),VALUE(3,2),VALUE(3,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
*VWRITE,LABEL(1,4),VALUE(4,1),VALUE(4,2),VALUE(4,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
/COM,
/COM,----------------------------------------------------------
/OUT,
FINISH
*LIST,vm254,vrt