This section describes how to do a steady-state thermal radiation analysis of two parallel planes using decimation and symmetry by issuing a sequence of commands, either while running in batch mode or by issuing the commands manually during an interactive session.
In this example, two parallel planes are considered for radiation. The underlying regions are meshed using PLANE55 elements. The first plane has a temperature of 1000°C and an emissivity of .5, and the second plane has a temperature of 500°C and an emissivity of .25.
The following sequence of commands builds and solves the finite element model. Text preceded by an exclamation mark (!) is comment text.
/title,Radiation Problem Using Radiosity Surface Elements
/prep7
w = 1
thick = 1
h = 0.06
!
tempoff = 273 ! Conversion to absolute temp
sbc = 5.67e-8 ! Stefan-Boltzman constant
T1 = 1000
T2 = 500
emiss1 = 0.5
emiss2 = 0.25
!
rectng,-0.5*w,,0.5*h,0.5*h+thick
rectng,-0.5*w,,-0.5*h,-0.5*h-thick
!
et,1,55
mp,kxx,1,1
mshape,0,2D
mshkey,1
esize,0.125
lesize,all,,,,-1.5
amesh,all
!
! Specify temp/emissivity/rdsf on plane 1
!
nsel,s,loc,y,0.5*h
sf,all,rdsf,emiss1,1
d,all,temp,T1
!
! Specify temp/emissivity/rdsf on plane 2
!
nsel,s,loc,y,-0.5*h
sf,all,rdsf,emiss2,1
d,all,temp,T2
nsel,all
allsel ! Select PLANE55 nodes/elements for RSURF command
!
! Specify radiation options
!
toffst,tempoff
stef,sbc
radopt,,1.0e-5,0,10000,,0.9
v2dopt,0,0,0,400
spctemp,1,0
vfopt,new,,,,asci
finish
/solu
rdec,,0.5 ! Set decimation to 50 percent reduction
rsymm,,0,x ! Specify reflection about the x-axis
rsurf ! Generate SURF251 elements and store in database
nlist ! Includes SURF251 nodes
elist ! Includes SURF251 elements
save
time,1
deltim,1
solve
finish
/post1
set,last
nsel,s,loc,y,0.5*h ! Select nodes of plane 1 and get nodal reaction
prrsol
nsel,s,loc,y,-0.5*h ! Select nodes of plane 2 and get nodal reaction
prrsol
nsel,all
*get,radnh,RAD,1,nethf ! Get the net outgoing radiant heat flux
! This should equal reaction 1 + reaction 2
*stat
!using nmisc element records to get net heat rate/emissivity/temp/
!enclosure/area/etc.
esel,s,type,,2 !select surf251
etable,elmarea,nmisc,4 ! Get element areas
etable,elmradnf,nmisc,7 ! Get element net outgoing radiant heat flux
smult,elmradnh,elmarea,elmradnf ! Multiply area*flux, store as heats
etable,elmradnf,erase
ssum ! Get net area net heats.
! Net heat should = reaction 1 + reaction 2
!report element centroid & enclosure
etable,elmcenx,nmisc,1 ! Get element centroid x-coord
etable,elmceny,nmisc,2 ! Get element centroid y-coord
etable,elmcenz,nmisc,3 ! Get element centroid z-coord
etable,elmencl,nmisc,18 ! Get element enclosure number
pretab,elmencl,elmcenx,elmceny,elmcenz
!report element avg temp, emiss
etable,elmtemp,nmisc,5 ! Get element average temp
etable,elmemiss,nmisc,6 ! Get element average emissivity
pretab,elmtemp,elmemiss
!report netheatflux = emit+refl-inci
etable,elmradnf,nmisc,7 ! Get element net outgoing radiant heat flux
etable,elmradem,nmisc,8 ! Get element emitted heat flux
etable,elmradre,nmisc,9 ! Get element reflected heat flux
etable,elmradin,nmisc,10 ! Get element radiant heat flux
pretab,elmradnf,elmradem,elmradre,elmradin
finish