/TITLE,USER MATERIAL FOR RADIAL EXPANSION OF A THERMOPLASTIC CYLINDER
/COM,
/COM, REFERENCE: "THERMOMECHANICAL MODELING OF METALS AT FINITE STRAINS: 
/COM, FIRST AND MIXED ORDER FINITE ELEMENTS", LAURENT ADAM, JEAN-PHILIPPE PONTHOT,
/COM, INTERNATIONAL JOURNAL OF SOLIDS AND STRUCTURES 42 (2005) 5615-5655
/COM,
RI=0.1              	! INTERNAL RADIUS
RE=0.2              	! EXTERNAL RADIUS
DX=0.13             	! RADIAL DISPLACEMENT

TREF=293            	! REFERENCE TEMPERATURE, K

/UPF,usermat.F
/UPF,usermatth.F

/PREP7
ET,1,SOLID226,11          ! STRUCTRAL-THERMAL COUPLING
KEYOT,1,9,1               ! SUPPRESSED THERMOELASTIC DAMPING

MP,ALPX,1,23.8E-6         ! THERMAL EXPANSION COEFFICIENT
MP,DENS,1,2700            ! DENSITY
MP,QRATE,1,0.9            ! TAYLOR-QUINNEY FACTOR

TB,USER,1,6,4             ! USER-DEFINED STRUCTURAL MATERIAL
TBTEMP,293		
TBDATA,1,7.E10,0.3,70E6,210E6     ! E,NU,SIGY,ET
TBTEMP,313		
TBDATA,1,7.E10,0.3,69.58E6,210E6  ! E,NU,SIGY,ET
TBTEMP,333
TBDATA,1,7.E10,0.3,69.16E6,210E6  ! E,NU,SIGY,ET
TBTEMP,353
TBDATA,1,7.E10,0.3,68.74E6,210E6  ! E,NU,SIGY,ET
TBTEMP,373
TBDATA,1,7.E10,0.3,68.32E6,210E6  ! E,NU,SIGY,ET
TBTEMP,393
TBDATA,1,7.E10,0.3,67.9E6,210E6   ! E,NU,SIGY,ET

TB,USER,1,1,2,THERM      ! USER-DEFINED THERMAL MATERIAL
TBDATA,1,150,900         ! K,C

TB,STATE,1,,8            ! EPEQ,EPPL,SEQV

RECT,RI,RE,0,RE-RI
TYPE,1
MAT,1
LESIZE,1,,,10
LESIZE,2,,,1
LESIZE,3,,,10
LESIZE,4,,,1
K,100,0
K,101,0,1
VROT,1,,, ,,,100,101,10,1
VMESH,1
ALLSEL,ALL

CSYS,5
NROTATE,ALL
NSEL,S,LOC,z,0
NSEL,A,LOC,z,RE-RI
D,ALL,Uz,0              ! CONSTRAIN UY DOF AT TOP AND BOTTOM FACES TO
                        ! SIMULATE INFINITELY LONG CYLINDER
NSEL,S,LOC,X,RI
D,ALL,UX,DX		! APPLY RADIAL DISPLACEMENT ALONG INNER SURFACE OF CYLINDER

NSEL,S,LOC,Y,0
NSEL,A,LOC,Y,10
D,ALL,UY
ALLSEL,ALL
CSYS,0

TREF,TREF		 ! REFERENCE TEMPERATURE
IC,ALL,TEMP,TREF       ! INITIAL CONDITION
FINISH

/COM,
/COM, ***** SOLUTION TIME = 13 SEC (ADIABATIC PROCESS) *****
/COM,
/SOLUTION
ANTYPE,TRANSIENT       ! TRANSIENT ANALYSIS
NLGEOM,ON              ! LARGE DEFLECTION ON 
TINTP,,,,1.0           ! TRANSIENT INTEGRATION PARAMETER
KBC,0                  ! RAMPED LOADING
NSUB,20,100,5          ! NUMBER OF SUBSTEPS
OUTRES,ALL,ALL
CNVTOL,HEAT,1.E-2,1.E-2 ! CONVERGENCE TOLERANCE
TIME,13		   ! END TIME
SOLVE
FINISH

/POST26
NSEL,S,LOC,X,0.1
NSEL,R,LOC,Y,0.1
ND=NDNEXT(0)
NSOL,2,ND,TEMP          ! TEMPERATURE AT NODE =ND
FILLDATA,3,,,,-1
FILLDATA,4,,,,293.0
PROD,5,3,4
ADD,6,2,5
NSOL,7,ND,U,X,UX        ! UX AT NODE=ND

PRVAR,7,6
/GRID,1
/AXLAB,X,Displacement of inner surface[m]
/AXLAB,Y,Temperature variation [K]
/XRANGE,0,0.14
/GROPT,DIVX,14
/YRANGE,0,60
/GROPT,DIVY,6
XVAR,7
PLVAR,6
ALLSEL,ALL
FINISH

/POST1
SET,LAST,LAST
PLNSOL,TEMP
PLNSOL,EPPL,EQV
FINISH