If you are running Mechanical APDL via the GUI, before you start building your model you should choose menu path Main Menu> Preferences. Then, on the dialog box that appears, select Magnetic-Nodal from the list of magnetic analysis types. Because the GUI filters the elements available to you based on the preference you choose, you must specify Magnetic-Nodal to ensure that you can use the elements needed for 3D static analysis.

Your model may have any or all of the following material regions: air, (free-space) permeable materials, current-conducting regions, and permanent magnets. Each type of material region has certain required material properties.

The material library contains definitions of several materials with magnetic properties. Instead of defining material properties from scratch, you can read these material properties into the database and, if necessary, modify them to match the materials in your analysis problem more closely.

Materials with magnetic properties defined in the Mechanical APDL material library are as follows:

The copper property presents temperature-dependent resistivity and relative permeability. All other properties are B-H curves.

The property definitions in the material library specify properties "typical" for the materials listed. Ansys, Inc. has extrapolated these properties to cover high saturation conditions. Your actual material values may differ from those supplied; therefore, you may need to modify the Mechanical APDL material library files you use.

The next few paragraphs provide some guidelines for setting up physics regions for your model. In addition, you may want to consult 2D Harmonic Magnetic (AC) Analysis; it pictures and describes the regions that can exist within a 2D model.

 

5.4.1.3.2. For Free-Space Permeable Material Regions:

Specify the B-H curve by reading from a material library or by creating your own B-H curve:

Command(s): MPREAD,filename, ...

GUI: Main Menu> Preprocessor> Material Props> Material Library> Import Library

Command(s): TB, TBPT

GUI: Main Menu> Preprocessor> Material Props> Material Models> Electromagnetics> BH Curve

If the material is linear, all you need is the relative permeability μ_r (which may be isotropic or orthotropic). If you specify a B-H curve, it should meet the following requirements for the material to be represented accurately:

• The B values must be unique for each H value, and must monotonically increase with H, as shown in Figure 2.1: B-H and Reluctivity vs. B Squared Curves(a). By default, the B-H curve will pass through the origin (that is, the 0.0 point is not to be explicitly defined). You can verify this by plotting B versus H using one of the methods shown below. (For more information, see the Element Reference.)

  Command(s): TBPLOT

  GUI: Main Menu> Preprocessor> Material Props> Material Models> Electromagnetics> BH Curve

• The μ-H curve that Mechanical APDL calculated internally (where μ is the permeability) should be smooth and continuous. You can verify this by plotting μ versus H using TBPLOT. (See Figure 5.1: Connected Domains(b)). The B-H curve should cover the complete operating range of the material. If a point beyond the end of the curve is required, the B-H curve is extrapolated at constant slope. The constant slope should be equal to or greater than μ_r. You can view values in the extrapolated region by adjusting the x-axis range of your B versus H plot. To adjust the x-axis range, use one of the following:

  Command(s): /XRANGE

  GUI: Utility Menu> PlotCtrls> Style> Graphs

Figure 5.2: B-H and mu-H Curves With Extrapolation

(a) B-H curve with extrapolation; (b) μ-H curve with extrapolation

For permanent magnets and nonlinear orthotropic materials, material input is the same as for 2D static analysis.

You can model current conduction regions with primitive sources, so they do not need material properties.

In a 3D scalar potential analysis, current sources are not modeled as an integral part of the geometry (as they are in a 2D analysis). Instead, you use a "dummy" finite element, SOURC36, to represent the shape and location of current sources. You can define coils, bars, or arcs at any location in the model. The amount of current and other current-source data are specified as element real constants. Figure 5.3: A Coil Source Represented by SOURC36 Elements shows an example of a coil current-source represented with SOURC36 primitives.

Figure 5.3: A Coil Source Represented by SOURC36 Elements

Because SOURC36 elements are not true finite elements, you can use only direct generation (not solid modeling) to define them. Direct generation uses the following menu paths or equivalent commands:

To display current source elements, use the commands or menu paths listed below (in the order shown):

The following is a command-based example of defining current sources.

/PREP7
ET,2, 36            ! Current source element
EMUNIT,MKS          ! MKS units
! Define convenient parameters:
I=0.025             ! Current (amps)
N=300               ! Turns
S=0.04              ! Solenoid length
R=0.01              ! Solenoid radius
THK=0.002           ! Solenoid thickness
!
R=2,1,N*1,THK,S         ! Real constant set 2:  coil type, current
                        ! thickness, length,
CSYS,1                  ! Global cylindrical system
N,1001,R                ! Nodes for the source element
N,1002,R,90                          
N,1003
TYPE,2              ! Attributes
REAL,2           
E,1001,1002,1003    ! Element definition
/ESHAPE,1
/VIEW,1,2,1,.5
/VUP,1,Z
/TRIAD, LBOT
/TYPE,1,HIDP
EPLOT

The following example demonstrates the use of SOURC36 current source elements using three arcs of 120°.

/title,,,full circle coils against 3x120 and 6x60 degree arcs
/com
/com This example demonstrates the usage of SOURC36 current source elements.
/com It compares results of a full circle coils with
/com 6 arcs of 60 degrees and 3 arcs of 120 degrees
/com
/nopr
!
coil=1
arc=3
cur=10
dr=0.1		! radius of source
dz=dr
eps=0.0005
ri=5		! radius of the coil R >> dr,dz
step=1		! step along Z
pi=3.1415926
n=21		! Z = -10 to +10 by 1

*dim,hhx,array,n,3
*dim,hhy,array,n,3
*dim,hhz,array,n,4	! to store targeted results in the center
*dim,hhs,array,n,3

/com ***** full coil (360 degrees) *****
/prep7
et,1,36
r,1,coil,cur,dr,dz,eps		! define the source
n,10001,ri, 0, 0
n,10002, 0,ri, 0
n,10003, 0, 0, 0
e,10001,10002,10003
et,2,96
mp,murx,1,1
n,1,0,0,-10*step		! define the calculated nodes
ngen,n,1,1,,,,,step
/solv
biot,new
/post1
*do,i,1,n
*get,hx,node,i,hs,x
*get,hy,node,i,hs,y
*get,hz,node,i,hs,z
hh=hx**2+hy**2+hz**2
hh=sqrt(hh)
hhx(i,1)=hx
hhy(i,1)=hy
hhz(i,1)=hz
hhs(i,1)=hh
*enddo
/com 		! to check if hx=hy=0
/com********************** 360-degree coil **********************
/com      Hx             Hy             Hz             Hsum
*vwrite,hhx(1,1),hhy(1,1),hhz(1,1),hhs(1,1)
('H=',4f15.6)
/com*************************************************************
fini


/com *** arcs ***
/prep7
et,1,36
r,1,arc,cur,dr,dz,eps		! define the source
edele,all
ndele,all
n,10001,ri ,  0, 0
n,10002, ri/2, ri*sqrt(3)/2, 0
n,10003,-ri/2, ri*sqrt(3)/2, 0
n,10004,-ri,  0, 0
n,10005, ri/2,-ri*sqrt(3)/2, 0
n,10006,-ri/2,-ri*sqrt(3)/2, 0
n,10007,  0,  0, 0
e,10001,10002,10007
e,10002,10003,10007
e,10003,10004,10007
e,10004,10005,10007
e,10005,10006,10007
e,10006,10001,10007
et,2,96
mp,murx,1,1
n,1,0,0,-10*step		! define the calculated nodes
ngen,n,1,1,,,,,step
/solv
biot,new
/post1
*do,i,1,n
*get,hx,node,i,hs,x
*get,hy,node,i,hs,y
*get,hz,node,i,hs,z
hh=hx**2+hy**2+hz**2
hh=sqrt(hh)
hhx(i,2)=hx
hhy(i,2)=hy
hhz(i,2)=hz
hhs(i,2)=hh
*enddo
/com 
/com ****************** 6 times 60-degree arc *******************
/com      Hx             Hy             Hz             Hsum
*vwrite,hhx(1,2),hhy(1,2),hhz(1,2),hhs(1,2)
('H=',4f15.6)
/com*************************************************************
fini


/com *** 3 times 120-degree arcs ***
/prep7
et,1,36
r,1,arc,cur,dr,dz,eps		! define the source
edele,all
ndele,all
n,10001,ri ,  0, 0
n,10002,-ri/2, ri*sqrt(3)/2, 0
n,10003,-ri/2,-ri*sqrt(3)/2, 0
n,10005,  0,  0, 0
e,10001,10002,10005
e,10002,10003,10005
e,10003,10001,10005
et,2,96
mp,murx,1,1
n,1,0,0,-10*step		! define the calculated nodes
ngen,n,1,1,,,,,step
/solv
biot,new
/post1
*do,i,1,n
*get,hx,node,i,hs,x
*get,hy,node,i,hs,y
*get,hz,node,i,hs,z
hh=hx**2+hy**2+hz**2
hh=sqrt(hh)
hhx(i,3)=hx
hhy(i,3)=hy
hhz(i,3)=hz
hhs(i,3)=hh
*enddo
/com 
/com ***************** 3 times 120-degree arc *******************
/com      Hx             Hy             Hz             Hsum
*vwrite,hhx(1,3),hhy(1,3),hhz(1,3),hhs(1,3)
('H=',4f15.6)
/com*************************************************************
fini

! target result with Biot-Savart law
*do,i,1,n,1
hhz(i,4) = cur/2*ri**2/(ri**2+(i-11)**2)**(3/2)
*enddo

/com 
/com ********************** Biot Savart *************************
/com
/com H(Z) = I/2*R^2/(R^2+Z^2)^(3/2)
/com
/com ************************************************************
/com ******************** 3 cases results ***********************
/com data
*vwrite,cur,dr,ri
(' current = ',f4.2,' Amp, radius section = ',f5.2,', coil radius = ',f5.2)
/com  z= -10 to +10 by 1
/com
/com      360-degree     6*60-degree    3*120-degree   target(B-S)
*vwrite,hhz(1,1),hhz(1,2),hhz(1,3),hhz(1,4)
('H=',4f15.6)
/com ************************************************************
/com
/com good approximation for radius section << coil radius
/com
/com ************************************************************
finish

For further information, see the descriptions of the following commands in the Command Reference: ET, EMUNIT, R, CSYS, N, TYPE, REAL, E, /ESHAPE, /VIEW, /VUP, /TRIAD, and /TYPE.

To help you build a 3D "racetrack" current source, Mechanical APDL provides the RACE command macro. To invoke this macro, use either of the following:

The RACE macro enables you to define a racetrack current source in the working plane coordinate system. The program generates the current source from bar and arc source primitives using the SOURC36 element (which is assigned the next available element type number). Current flows in a counterclockwise direction with respect to the working plane. See Electric and Magnetic Macros for additional details about this macro and a racetrack coil diagram.

To delete a racetrack coil, you delete individual SOURC36 elements using the EDELE command (Main Menu> Preprocessor> Modeling> Delete> Elements). Before doing so, you should first review the elements to choose the appropriate elements to delete. Review elements using one of the methods shown below:

In addition to applying boundary conditions and loads, you also will need to specify load step options if you opt to step through the analysis manually, See Alternative Analysis Options and Solution Methods for details. The next few topics explain how to perform the tasks involved in a routine analysis.

The scalar potential formulation uses different boundary conditions (BCs) and loads than those for the vector potential formulation. Following are the appropriate BCs and loads and the menu paths to define them. (See Alternative Analysis Options and Solution Methods for information on applying loads or BCs via APDL commands.)

You access all loading operations through a series of cascading menus. When you choose Main Menu> Solution> Define Loads> Magnetic, the program lists one BC category and three load categories. You then choose the appropriate category and the appropriate load or BC. The categories and BCs or loads you can choose for a 3D static analysis are as follows:

For example, to apply the flux-normal condition on an area, choose this GUI path:

Main Menu> Solution> Define Loads> Apply> Magnetic> Boundary> Flux Normal> On Areas

You may see other load types or BCs or loads listed on the menus. If they are grayed out, either they do not apply to 3D static analysis or the appropriate KEYOPT option on the element type has not been set. (However, the grayed-out items will be valid for other types of magnetic analysis; the Mechanical APDL GUI filters menu choices.)

You supply current excitation via the SOURC36 element as noted previously. Invoking the RACE macro simplifies application of this type of coil arrangement.

The DSP method is recommended only if the model has singly connected iron regions. The DSP method uses the same procedures for building the model and reviewing results as the RSP method uses. (To see descriptions of these procedures, refer to the discussion of the RSP method.) However, for the DSP method you use different procedures to apply loads and obtain a solution.

The DSP method requires a two-step solution sequence:

Follow the steps shown below to perform the solution sequence:

The GSP method is the best method to use if the model has current sources and a multiply connected iron region. The analysis procedures are the same, except for the procedure for solving the model. The GSP method requires a three-step solution sequence where:

To obtain a solution for a GSP analysis, perform these steps:

To review results in POST1, the database must contain the same model for which the solution was calculated. Also, the results file (Jobname.rmg) must be available.

To read the data from the results file into the database, use either of the following:

If the model is not in the database, restore it using the command or menu path listed below and then use the SET command to read in the desired set of results.

Flux lines are not readily available with the scalar potential formulation. Use vector displays of flux density to visualize flux paths.

Vector displays (not to be confused with vector mode) are an effective way to view vector quantities such as B, H, and FMAG. To produce vector displays, use either method shown below:

To produce vector listings, use one of the following:

You can contour almost any result item, including flux density and field intensity, using the following commands or menu paths:

You can find details on how to graphically display a charged particle traveling in a magnetic field in Charged Particle Traces and Controlling Charged Particle Trace Displays in the Basic Analysis Guide. See Electromagnetic Particle Tracing in the Mechanical APDL Theory Reference for more details.

You can produce tabular listings of results data, either unsorted or sorted by node or by element. To sort data before listing it, use any of the following:

To produce tabular listings, use any of the following:

To review Maxwell or virtual work forces, use the following approach:

In postprocessing, you can calculate many other items of interest from the data available in the database. The APDL command set supplies the following macros to perform calculations for you automatically:

See Electric and Magnetic Macros for details on these macros or the Command Reference.