This example problem demonstrates the use of FLUID220 to predict the one-way coupling from the structure to acoustics.

In one-way sequential coupling, the structural analysis is performed first. The structural results on the one-way coupling interface flagged on the structural model are stored in a file with the extension .asi, then used in the sequential acoustic analysis as the excitation.

A square infinite steel pipe with the wall thickness 0.125 m, containing air with the cross section 1 x 1 m², is simulated to demonstrate the process.

/batch,list
/title, one-way coupling via .asi file
/nopr
/prep7
                             ! define elements
et,1,186  
et,2,220,,1
et,11,200,7
                             ! define steel material properties                         
mp,ex,1,1.44e11
mp,dens,1,7700
mp,nuxy,1,0.35
                             ! define air material properties
mp,dens,2,1.21
mp,sonc,2,430	
                             ! create the mesh
h=0.0625
*dim,a,array,4
a(1)=0
a(2)=a(1)+2*h
a(3)=a(2)+1
a(4)=a(3)+2*h
*do,i,1,3
 *do,j,1,3
  rect,a(i),a(i+1),a(j),a(j+1)
 *enddo
*enddo
aglue,all
asel,s,loc,x,a(2),a(3)
asel,r,loc,y,a(2),a(3)
cm,a1,area
alls
type,11                       ! 2d mesh
esize,h
amesh,all
lz=h
n=1
type,2
mat,2
asel,s,,,a1
esize,,n
vext,all,,,0,0,lz            ! acoustic mesh
type,1
mat,1
asel,s,loc,z,0               ! structural area
asel,u,,,a1
esize,,n
vext,all,,,0,0,lz            ! structural mesh
alls
asel,s,loc,z,0               ! delete 2d mesh
aclear,all
etdel,11
alls
nummgr,all
                             ! define one-way coupling interface
esel,s,type,,1
nsle,s
nsel,s,loc,x,a(2)
nsel,a,loc,x,a(3)
nsel,a,loc,y,a(2)
nsel,a,loc,y,a(3)
sf,all,fsin,1                ! flag interface with fsin
alls
                             ! set boundary condition
nsel,s,loc,y,0               ! set displacement constraint
d,all,ux,0
d,all,uy,0
d,all,uz,0
alls
nsel,all
d,all,uz,0
                             ! set loads on the structure
nsel,s,loc,x,0
f,all,fx,1                   ! apply force 
alls
esel,u,type,,2               ! unselect acoustic element in structure
asifile,write                ! store interface structural results
fini 
                             ! perform a structural solution
/solu
antype,harm
hropt,auto
kbc,1
harf,58,68                   ! frequency range
nsub,3                       ! solving at 3 frequencies
solve
fini
                             ! start an acoustic analysis
/prep7
alls
esel,u,type,,1               ! unselect structural element in acoustics
asifile,read                 ! read stored structural results
fini
                             ! perform an acoustic solution
/solu
antype,harm
hropt,auto
kbc,1
harf,58,68                   ! frequency range
nsub,3                       ! solving at 3 frequencies
solve
fini
                             ! post-processing
/post26
nn1 = node(0.125,0.125,0)
nsol,2,nn1,pres
fini