This example problem demonstrates how to calculate the response of a simple tank structure to a horizontal seismic excitation using spectrum analysis.

The steel tank is 21 m tall with a radius of 7 m. It is meshed with SHELL281 and constrained at the base. It is filled with water, which is meshed with FLUID220 elements. The fluid has a free surface with zero pressure at the top and FSI interfaces on all other faces.

The unsymmetric eigensolver is used to extract the first 250 eigensolutions between 4.1 and 50 Hz. Both right and left eigensolutions are requested. The solutions are real by default.

Finally the spectrum analysis (SPRS) is run with horizontal (X-direction) excitation using the CQC combination method. This analysis can be post-processed in POST1 after the MCOM file is input.

/batch
/title, Response Spectrum Analysis of a Tank

Radius = 7
Height = 21
Thickness = 0.015
ElemSize = 0.5
Dens_Fluid = 1000
Sonc_Fluid = 1500
Ex_Solid = 1.95e11
PRXY_Solid = 0.3
Dens_Solid = 7850

/PREP7

LOCAL,12,0,0,0,0, ,-90, ,1,1,
CSYS,12
WPCSYS,-1
CSYS,0
CYLIND,Radius,0,0,Height,0,360,

ET,1,220,0,0
MP,DENS,1,Dens_Fluid
MP,SONC,1,Sonc_Fluid

ET,2,281
MP,EX,2,Ex_Solid
MP,DENS,2,Dens_Solid
MP,PRXY,2,PRXY_Solid
SECTYPE,2,SHELL
SECDATA,Thickness,2

ESIZE,ElemSize

TYPE,1
MAT,1
SECNUM,1
VSEL,,,,1
VSWEEP,ALL

TYPE,2
MAT,2
SECNUM,2
ASEL,S,,,1
ASEL,A,,,3
ASEL,A,,,4
NSLA,S,1
ESURF
! Boundary Conditions
DA,1,UX,0
DA,1,UY,0
DA,1,UZ,0

DA,2,PRES,0
SFA,1,,FSI
SFA,3,,FSI
SFA,4,,FSI

ALLSEL,ALL
FINISH

/solu
ANTYPE,MODAL
MODOPT,UNSYM,250, 4.1,50,,, BOTH    ! request BOTH left and right eigensolutions
MXPAND,250
SOLVE
FINI

/SOLU
ANTYPE,SPECTRUM
SPOPT,SPRS
SVTYP,2

DMPR,0.04
FREQ,  0.050,  0.106,  0.110,  0.113,  0.240,  0.310,  0.440,  0.785,  0.810
FREQ,  1.157,  1.430,  1.780,  1.795,  1.911,  2.035,  2.167,  2.307,  2.616
FREQ,  2.785,  2.966,  3.158,  3.363,  3.813,  4.060,  4.323,  7.605,  8.622
FREQ,  9.181,  9.776, 13.380, 15.170, 16.153, 17.199, 19.500, 23.541, 26.690
FREQ, 41.417, 44.101, 50.000, 100.000

SV,, 0.4074E-01, 0.9420E-01, 0.9420E-01, 0.9420E-01, 0.1640E+01, 0.3118E+01, 0.9190E+01, 0.9160E+01, 0.9160E+01
SV,, 0.5371E+01, 0.2420E+01, 0.1850E+01, 0.1210E+01, 0.1139E+01, 0.1139E+01, 0.9863E+00, 0.9863E+00, 0.9248E+00
SV,, 0.9248E+00, 0.9634E+00, 0.9634E+00, 0.9950E+00, 0.9950E+00, 0.9950E+00, 0.1169E+01, 0.1169E+01, 0.1150E+01
SV,, 0.1115E+01, 0.1076E+01, 0.1076E+01, 0.8974E+00, 0.8974E+00, 0.8948E+00, 0.8664E+00, 0.8565E+00, 0.8208E+00
SV,, 0.8200E+00, 0.8111E+00, 0.8089E+00, 0.8089E+00

CQC

SED,1,0,0        ! X-direction
SOLVE
FINI

/POST1
/INPUT,,MCOM
SELTOL,1E-5
NSEL,,LOC,X,RADIUS
NLIS
PRNSOL,U
PRNSOL,PRES
ALLSEL
/SHOW,PNG,REV
/VIEW,,1,1,1
ESEL,,TYPE,,2
PLNSOL,U,X
ESEL,,TYPE,,1
PLNSOL,PRES
FINISH