This example demonstrates nonlinear sound propagation from an acoustic horn using FLUID244 elements with an axisymmetric approach.

The figure below depicts the 2D model of the fluid domain and horn geometry. At the throat section of the horn, a circular piston excites the air medium through fluid-solid interaction with PLANE183 elements. The cross-sectional area increases exponentially until reaching the mouth of the horn. The fluid domain is enclosed by an infinite radiation boundary condition, as illustrated in the figure.

Figure 13.20: 2D-axisymmetric Model of an Exponential Horn

The shape parameter of the exponential horn can be parametrized as shown in the following formulation. The radius of each section, depending on the axial distance from the throat, is given by,

where is flare constant and is throat radius. Additionally, represents axial distance from the throat section. The harmonic analysis is conducted at = 130 Hz, and harmonics are generated due to nonlinear acoustic features by using the material properties shown in the following table:

/batch
/prep7

!Shape parameter of Horn
m=4
r0=0.05
l0=1

!exit radius (mouth)
R_ex=r0*exp(0.5*m*l0)

un=0.02
rx1=R_ex*5
rx2=R_ex*6
ry1=rx1
ry2=rx2
rpy=0.04

FREQUENCY0= 130
MAT_DENS  = 1.2
MAT_SONC  = 343
MAT_BETA  = 1.2
!MAT_DIFF  = 3.764e-5 ! commented out to let compute this inside

WAVENUM   = 2*acos(-1)*FREQUENCY0/MAT_SONC
WAVELENG  = MAT_SONC/FREQUENCY0
DIM_ESIZE = WAVELENG/60

!keypoints
k,1,0,-l0
k,2,0,0
k,3,R_ex,0
k,4,rx1,0
k,6,0,ry1
k,7,0,ry2
k,11,rx2,0
k,12,0,-l0-rpy
k,13,r0,-l0-rpy

!LINES------
_NNOD=5
*DO,_i,1,(_NNOD)
   y0 =  (l0/_NNOD)*(_i-1)
   y1 = -l0 + y0
   rx = r0*exp(0.5*m*y0)
   k,20+(_i-1),rx,y1
*ENDDO
BSPLIN,20,21,22,23,24,3

l,2,1   !line2
l,2,6   !line3
l,4,3   !line4
l,1,20  !line5
l,1,12  !line6
l,12,13 !line7   ---> displacement
l,13,20 !line8

circle,2,rx1,,4,90 !line9--> line13 ---> INF
circle,2,rx2,,11,90 !line10
l,11,4 !line11 --> line14
l,6,7  !line12 --> line15
LGLUE,ALL

!AREAS---------
!area1:
al,1,2,3,4,5,13
!area2:
al,10,13,14,15
!area3:
al,6,7,8,5
!
!ELEMENTS---------
ET,1,244,,8,1,        ! coupled nonlinear axi acoustic element
ET,3,183,,,1

!Define material
mp,sonc,1,MAT_SONC
mp,dens,1,MAT_DENS
mp,betw,1,MAT_BETA
!mp,sdif,1,MAT_DIFF
mp,ex,2,1.44e11
mp,dens,2,7500
mp,nuxy,2,0.35
!
!Mesh parameters
!
asel,s,area,,2
esize,DIM_ESIZE
type,1
mat,1
! generate mesh
amesh,2
alls
!
asel,s,area,,1
esize,DIM_ESIZE
type,1
mat,1
! generate mesh
amesh,1
alls
!
!asel,s,area,,3
esize,DIM_ESIZE
type,3
mat,2
!generate mesh
amesh,3
alls

!BOUNDARY CONDITIONS------------
!Displacement
lsel,s,line,,7
nsll,s,7
d,all,uy,un
alls
!Robin
lsel,s,line,,10
nsll,s,10
sf,all,inf
alls

!SOLUTION-----------------------
/solution
antype,harmic
harfrq,FREQUENCY0
cnvtol,pres,1.0,1e-5       ! Tolerance value for convergence
hropt,HNLA,1,4             ! Number of harmonics = 4
solve
finish

!POST-PROCESSING----------------

/post26
PRCPLX,1
nsol,3,node(0,0,0),pres
/out
prvar,3
/out,scratch
finish

/post1
alls
plfar,pres,splp,0,360,60,90,90,1,10,2.e-5,,,,,all,all,
finish

Figure 13.21: Pressure values vs harmonic frequencies at mouth exit (x=0, y=0)

Figure 13.22: Far-field Sound Pressure Level for each harmonic is computed at a distance of 10 m from the center of the horn exit at various angles