This example uses FLUID244 elements to demonstrate how the nonlinear interactions of primary ultrasonic beams generated by a transducer result in the production of a highly directional low-frequency sound field.

The reference case [1] is simulated using axisymmetric elements with different velocity distributions as inputs for the transducer. The primary and secondary frequencies are 40 kHz and 39 kHz, respectively. Therefore, the generated low-frequency, also called the difference frequency, is 1 kHz. The fluid domain, along with the fluid element, is enclosed by a PML element. The velocity distribution for the input varies, such as constant, parabolic, and quadric. These options are described in the following input listing.

/batch
/prep7

!Shape and Input Parameters
R_TRA=0.02
L_FOC=0.062
FREQUENCY2= 40000
FREQUENCY1= 39000
!Air
MAT_DENS  = 1.204
MAT_SONC  = 343.2
MAT_BETA  = 1.2
MAT_SDIF  = 3.764e-5
!--------------------------
!
!WAVENUM   = 2*acos(-1)*FREQUENCY/MAT_SONC
WAVELENG  = MAT_SONC/FREQUENCY2
DIM_ESIZE = WAVELENG/12
DEPTH_TRA = L_FOC - sqrt((L_FOC*L_FOC)-(R_TRA*R_TRA))
rx1=R_TRA*5
rx2=R_TRA*8
ry1=R_TRA*12
ry2=R_TRA*15
!
!keypoints
k,2,0,0
k,3,R_TRA,0
k,4,rx1,0
k,5,rx1,ry1
k,6,0,ry1
k,7,0,ry2
k,8,rx1,ry2
k,9,rx2,ry2
k,10,rx2,ry1
k,11,rx2,0
k,12,0,(L_FOC-DEPTH_TRA)
k,13,0,(L_FOC-DEPTH_TRA),1
l,2,3   !l1
l,2,6   !l2
l,6,5   !l3
l,5,4   !l4
l,4,3   !l5
l,6,7   !l6
l,7,8   !l7
l,8,9   !l8
l,8,5   !l9
l,9,10  !l10
l,5,10  !l11
l,10,11 !l12
l,4,11  !l13
LGLUE,ALL

!areas
al,1,2,3,4,5
al,3,6,7,9
al,9,8,10,11
al,4,11,12,13

!Define element
et,1,244,,8,1            ! nonlinear axi acoustic element
et,2,244,,8,1,1          ! NL axisymmetric PML element

!Define material
mp,sonc,1,MAT_SONC
mp,dens,1,MAT_DENS
mp,betw,1,MAT_BETA
mp,sdif,1,MAT_SDIF
!
!Mesh parameters
!
asel,s,area,,1
esize,DIM_ESIZE
type,1
mat,1
! generate mesh
amesh,1
alls
!
asel,s,area,,2,4
esize,DIM_ESIZE
type,2
mat,1
! generate mesh
amesh,2,4
alls
!
!define outer BC
nsel,s,loc,x,rx2
nsel,a,loc,y,ry2
d,all,pres,0.0
alls

!----Velocity BCs
method=3
u0=1
*IF,method,eq,1,then
   !----uniform distribution
   lsel,s,line,,1
   nsll,s,1
   !sf,all,shld,u0
   bf,all,velo,,u0
   sf,all,port,1
   alls
*ELSEIF,method,eq,2,then
   !----quartic distribution
   lsel,s,line,,1
   nsll,s,1
   cm,_NGROUP,node
   *GET,_NNOD,NODE,0,COUNT
   *DIM,_UNNODE,TABLE,_NNOD,1,1,NODE
   NODE = 0
   *DO,_I,1,_NNOD
     NODE=NDNEXT(NODE)
     *GET,XL,NODE,NODE,LOC,X
     XLL=XL
     par1 = (1-((XLL*XLL)/(R_TRA*R_TRA)))
     _UNNODE(_I,0,1)= NODE
     _UNNODE(_I,1,1)= u0*par1*par1
   *ENDDO
   BF,ALL,VELO,,%_UNNODE%
   SF,ALL,PORT,1
   alls
*ELSEIF,method,eq,3,then
   !---parabolic distribution
   lsel,s,line,,1
   nsll,s,1
   cm,_NGROUP,node
   *GET,_NNOD,NODE,0,COUNT
   *DIM,_UNNODE,TABLE,_NNOD,1,1,NODE
   NODE = 0
   *DO,_I,1,_NNOD
     NODE=NDNEXT(NODE)
     *GET,XL,NODE,NODE,LOC,X
     XLL=XL
     par1 = (1-((XLL*XLL)/(R_TRA*R_TRA)))
     _UNNODE(_I,0,1)= NODE
     _UNNODE(_I,1,1)= u0*par1
   *ENDDO
   BF,ALL,VELO,,%_UNNODE%
   SF,ALL,PORT,1
   alls
*ENDIF

! Solve
/solution
antype,harmic                
harfrq,FREQUENCY1,FREQUENCY2
hropt,HNLA,2
solve
finish

/post26
nsol,2,node(0,0,0),pres
prvar,2
nsol,3,node(0,L_FOC-DEPTH_TRA,0),pres
prvar,3
finish

Figure 13.23: Pressure values at the difference-frequency along the vertical axis with different velocity distribution: (a) uniform, (b) quartic, and (c) parabolic ( = 40 kHz, = 39 kHz, and =1 kHz)

Figure 13.24: Pressure distribution on the fluid domain at difference-frequency, =1 kHz